Quick way to rename buttons on 4610sw

[polska1979]

Evening all,

This is my first time posting on Tek-tips, but have been browsing the forums for a while now. It has been really helpful. Unfortunately I havent been able to find any posts that can help me with my query.

I have been asked to create aux work shortcuts on over 235 4610sw's set up as ACD handsets. Whilst the programing of the phones, CMS dictionary and Aux reason codes in CM5 has been easy. What Is really going to do my head in is having to go round and manually label each feature button.

Whilst the overtime is quite nice, I really would like to find a quicker way of doing it. I have managed to set up approx 20 of the handsets and the aux work buttons are working perfectly and the CC manager is happy for the rollout to continue as he can now see the results in his agent reports in CRM. But I dont want to get RSI!!!! ;-)

Can anyone help or suggest an alternative way?

Wea re relabeling the buttons as
Personal
Outbound
Training
Lunch

etc etc.

 

[phoneguy55]

Look at 'cha abb sys'. But there are only 100 slots.

 

[polska1979]

Can you specify different aux reason codes in abb sys? or would having multiple aux work entries conflict with each other?

 

[theblackbag]

Use this DOS batch script to create the necessary files on your FTP server. Call it create.bat.

:: File to create or alter individual phone files
:: Needs a 'master' file called master_xxxx.txt to use a template to alter or create the files
:: xxxx is the type of phone, i.e. 4610 or 4620
:: example create 4610 40000 40100 would create 101 files between 40000_4610data.txt and
:: 40100_4610data.txt, using master_4610.txt as a template
:: use the additional write flag to unprotect the effected files and then write protect them again
:: after
:: Ian Petchey 6/3/08 ian.petchey@vodafone.com scubaian@gmail.com

echo off

if %1 == 4610 goto validphone
if %1 == 4620 goto validphone
goto invalidphone

:validphone

if %2 lss 1000 goto invalidextn
if %3 leq %2 goto invalidextn

if not exist master_%1.txt goto nomaster

if %4a == writea FOR /L %%G IN (%2,1,%3) DO attrib -r %%G_%1data.txt
FOR /L %%G IN (%2,1,%3) DO copy master_%1.txt %%G_%1data.txt
if %4a == writea FOR /L %%G IN (%2,1,%3) DO attrib +r %%G_%1data.txt

goto success

:invalidphone

echo INVALID PHONE TYPE
echo COMMAND USAGE create X Y Z [write] , Zhone type, Y:starting extn and Z:end extn
echo USE OPTIONAL write FLAG TO RELEASE AND REPLACE WRITE PROTECTION ON FILES

goto end

:invalidextn

echo INVALID EXTN SELECTION
echo COMMAND USAGE create X Y Z [write] , Zhone type, Y:starting extn and Z:end extn
echo USE OPTIONAL write FLAG TO RELEASE AND REPLACE WRITE PROTECTION ON FILES

goto end

:nomaster

echo THE REQUIRED MASTER FILE FOR THIS PHONE TYPE DOES NOT EXIST HERE
echo COMMAND USAGE create X Y Z [write] , Zhone type, Y:starting extn and Z:end extn
echo USE OPTIONAL write FLAG TO RELEASE AND REPLACE WRITE PROTECTION ON FILES
goto end

:success
echo DONE!

:end

 

[polska1979]

Cheers, unfortunately I have approx 600 other 4610's in the building that arent being used as ACD handsets, these phones need to remain the same. Would this solution change all. The ACD range is set at 275-#### the others are 274-####. Can a command be run to just change the 275 acd range?

 

[theblackbag]

Change the looped for copy command in the script to

FOR /L %%G IN (%2,1,%3) DO copy master_%1.txt 275%%G_%1data.txt

And then use the syntax, 'create 4610 1000 2000' and it will create 1000 files from 2751000_4610data.txt to 2752000_4610data.txt using master_4610.txt as the template. You just need to change the parameters to suit.

 

[theblackbag]

Thinking about it, you could run the orginal script using the starting extn 2750000 (or whatever) and ending extn 2759999 (or whatever), it should still work.

After you create the batch file the command line to ruin it should look somthing like,

create 4610 2750000 2759999

This would create 10,000 files, from 275000_4610data.txt to 2759999_4610data.txt using your template file. Then you need to put them in the correct directory on the FTP server and either reset the handsets or do a restore on them.

 

[polska1979]

theblackbag, thats awesome. I will give it a whirl this weekend.

bang goes my overtime, I will tell the wife its your fault ;-)

 

[victor5908]

Using this theory could you manipulate existing backup files?
These are DOS commands are run fron the FTP server itself?
Is there a doc somewhere explaining the capabilities of such commands?
Very interesting stuff-

 

[theblackbag]

Straght forward ms-dos commands. There are plenty of web sites that document them. I wrote this script to help with rolling out new handsets, but I suppose you could write somthing to work with existing files. Let me know what you have in mind and I'll see if I can help.