Why the 2 - Top level form is not on focus... 2

[fredgmain]

Hi all,

I create a simple form (2- Top level) but the form is not in focus until I click on the form (any area or title).

I believed the settings in the form properties is wrong but I cannot figure out why.

Or any command that I can put in the form "Init" or "Activate" section so that the cursor will stop at the fist text field?

Thanks for your help.
Fred

 

[cbasoz]

You can use this (I have been using successfully), in activate call BringAppInFront( thisform.hwnd ):

Procedure BringAppInFront(tnHWND)
	Declare Integer GetForegroundWindow In win32API
	Declare Integer GetCurrentThreadId In win32API
	Declare Integer GetWindowThreadProcessId In win32API ;
		integer HWnd, Integer @lpdwProcessId
	Declare short SetForegroundWindow In win32API Integer lnHWnd
	Declare short AttachThreadInput In win32API ;
		integer idAttach, Integer idAttachTo,  short fAttach

	Declare Integer SetActiveWindow In WIN32API Integer HWnd   && handle to window

	Local lpdwProcessId, lnThreadID1, lnThreadID2
	lpdwProcessId = 0
	lnThreadID1 = GetCurrentThreadId()

	lnThreadID2 = GetWindowThreadProcessId( m.tnHWND, @lpdwProcessId)

	AttachThreadInput(m.lnThreadID1, m.lnThreadID2, 1)
	SetForegroundWindow(m.tnHWND)
	SetActiveWindow(m.tnHWND)
	AttachThreadInput(m.lnThreadID1, m.lnThreadID2, 0)
Endproc

Cetin Basoz
MS Foxpro MVP, MCP

 

[Mike Lewis]

Fred,

You are not doing anything wrong. You have simply come up against a long-standing quirk (bug?) in VFP.

A simple way of fixing it is to put this code in the form's Init:

THISFORM.AlwaysOnTop = .T.
THISFORM.AlwaysOnTop = .F.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro tips, advice, training, consultancy
Custom software for your business

 

[fredgmain]

Dear Cetin Basoz

Thank you for your help. It solved my forms' problem.

Regards,
Fred