What extension am I calling from? – Call a VDN for playback 1

[Mick61C]

Ever needed to know what extension is attached to a non-display phone or questioned that the displayed extension was correct? Here is a way to call a VDN and have your system use announcements to speak back your current extension that you’re calling from.

System Specs:
Avaya 8730 server
VAL board TN2501AP
Communication manager 5.1.1
Call Center 5.0

1. Record an announcement for each number. This can be accomplished by Feature Access Code or Voice Announcement Manager (VAM). I also added a few others for esthetic purposes.
Announcement 8641: “The extension you are calling from is.”
Announcement 8642: “To repeat the extension, please press one.”
Announcement 8640: “zero”
Announcement 8631: “one”
Announcement 8632: “two”
Announcement 8633: “three”
Announcement 8634: “four”
Announcement 8635: “five”
Announcement 8636: “six”
Announcement 8637: “seven”
Announcement 8638: “eight”
Announcement 8639: “nine”

2. Next create some vectors that will be doing the routing to the announcements. I have 2 but they can certainly be separated into multiple vectors depending on your needs. Also be aware that some of the vectoring below may not work depending on your software level. I think that this would still be a good starting point for someone if that happens to be the case.

Add Vector 405 -- ANI_SPEAK_BACK_2
01 announcement 8640
02 return
03 announcement 8631
04 return
05 announcement 8632
06 return
07 announcement 8633
08 return
09 announcement 8634
10 return
11 announcement 8635
12 return
13 announcement 8636
14 return
15 announcement 8637
16 return
17 announcement 8638
18 return
19 announcement 8639
20 return
21 stop

Add Vector 400 -- ANI_SPEAK_BACK_1
01 announcement 8641
02 goto vector 405 @step 3 if ani = 1+
03 goto vector 405 @step 5 if ani = 2+
04 goto vector 405 @step 7 if ani = 3+
05 goto vector 405 @step 9 if ani = 4+
06 goto vector 405 @step 11 if ani = 5+
07 goto vector 405 @step 13 if ani = 6+
08 goto vector 405 @step 15 if ani = 7+
09 goto vector 405 @step 17 if ani = 8+
10 goto vector 405 @step 1 if ani = ?0+
11 goto vector 405 @step 3 if ani = ?1+
12 goto vector 405 @step 5 if ani = ?2+
13 goto vector 405 @step 7 if ani = ?3+
14 goto vector 405 @step 9 if ani = ?4+
15 goto vector 405 @step 11 if ani = ?5+
16 goto vector 405 @step 13 if ani = ?6+
17 goto vector 405 @step 15 if ani = ?7+
18 goto vector 405 @step 17 if ani = ?8+
19 goto vector 405 @step 19 if ani = ?9+
20 goto vector 405 @step 1 if ani = ??0+
21 goto vector 405 @step 3 if ani = ??1+
22 goto vector 405 @step 5 if ani = ??2+
23 goto vector 405 @step 7 if ani = ??3+
24 goto vector 405 @step 9 if ani = ??4+
25 goto vector 405 @step 11 if ani = ??5+
26 goto vector 405 @step 13 if ani = ??6+
27 goto vector 405 @step 15 if ani = ??7+
28 goto vector 405 @step 17 if ani = ??8+
29 goto vector 405 @step 19 if ani = ??9+
30 goto vector 405 @step 1 if ani = ???0
31 goto vector 405 @step 3 if ani = ???1
32 goto vector 405 @step 5 if ani = ???2
33 goto vector 405 @step 7 if ani = ???3
34 goto vector 405 @step 9 if ani = ???4
35 goto vector 405 @step 11 if ani = ???5
36 goto vector 405 @step 13 if ani = ???6
37 goto vector 405 @step 15 if ani = ???7
38 goto vector 405 @step 17 if ani = ???8
39 goto vector 405 @step 19 if ani = ???9
40 collect 1 digits after announcement 8642 for none
41 goto step 1 if digits = 1
42 stop

3. Last but not lease, add a new VDN to the party and give it a try…
Add VDN
8840: vector 400

From a callers experience, when ext. 8840 is called they will receive the announcement “The extension that you are calling from is”. Next the system will look at the first digit of the ani and go corresponding announcement in vector 405. The Return statement in vector 405 sends the caller back into vector 400 where they left off and the process is repeated. Once all four digits have been played back the caller gets the option to repeat the extension “To repeat the extension press 1” which sends the call back to the top of vector 400.
One thing that I’ve noticed is that there is a bit of a lag between announcements. For example, if the extension you are calling from is 1000 the vectoring will pick up the first digit “1” rather quickly and play the announcement; however for the next digit “0” the call has to hit each step after the “1” in the vector and check to see if the step is valid. So, between the announcement 1 and announcement 0 the call has to pass by 18 steps before the next valid step is reached! The “lag” isn’t a big deal especially when this is just used by technicians however the lag is just long enough to make you think “uh, is the next digit coming?” Again, not a big deal if you’re aware of it…

Cool huh?

 

[phoneguy55]

this has been in the faq section since 2003.

 

[SF0751]

Yes, see faq690-4624 from phoneman2.

Susan
"An education isn't how much you have committed to memory, or even how much you know. It's being able to differentiate between what you do know and what you don't."
- Anatole France

 

[mikeydidit]

Still cool. Thanks for the effort of posting it. BTW their are a lot of other cool things you can do in the FAQ section. You may want to glance through there.

"A people that values its privileges above its principles soon loses both."
- Dwight D. Eisenhower (1890-1969), Inaugural Address, January 20, 1953

For the best response to a question, read faq690-6594

 

[Mick61C]

Sorry, I didn't see that in there.

Thanks guys!

 

[thejkro]

This is cool but I have a long delay between each number that's announced. I assume that's because it's jumping vectors to get the announcement. Is there any way to lessen the delay?