W2K3 Server - Long Time to Shut Down After Moving Exchange Database 2

[sarahleehill]

I have a W2K3 Server with Exchange 2003. Everything seemed to be working correctly until I moved the Exchange Database and Logs to seperate drives.
I then went to install Etrust Antivirus 7.0 and it is not recognising that Exchange is installed and therefore not checking the Exchange option.
Once I installed Etrust I rebooted and the Server took about 10minutes to shut down. I tried shutting down the Exchange Services as Microsoft recognises the problem but this did not help. REF 555025
I uninstalled Etrust and this did not help.
Should I move the Database & Logs back to C:/ or completely uninstall & reinstall Exchange or is there another solution?

 

[Mshen]

e2k3 on w2k3 takes very long to shutdown.

here is a link:

http://www.msexchange.org/tutorials/Accelerating_Exchange_Shut_Down.html

but the trick didn't work on my machine. yet figure it out.

cheers

 

[sarahleehill]

Yes I had already tried those tricks - still did not work.
I even moved the database and logs back to the original location. Still no luck.

 

[trasher133]

Try this... This helps me to shutdown my server (w2k3,ex2003)

just make a .cmd file out of it.

(Not made by me, found it on the internet)
----------------------

@ECHO OFF
REM This is a batch file to shutdown an Exchange 2003 server on Windows 2003
REM The idea is to control the order of the shutdown process.
REM The main issue is to stop Exchange before Active Directory is stopping.

ECHO Stopper ver 1.00 by Yizhar Hurwitz
ECHO.
ECHO 1. Shut Down the server (shutdown /s).
ECHO 2. Reboot the server (shutdown /r).
ECHO 3. Abort shutdown (shutdown /a).
ECHO 0. Do nothing.
ECHO.
CHOICE /C 1230

IF ERRORLEVEL 4 GOTO END
IF ERRORLEVEL 3 GOTO ABORT
IF ERRORLEVEL 2 GOTO REBOOT
IF ERRORLEVEL 1 GOTO SHUTDOWN
IF ERRORLEVEL 0 GOTO END
GOTO END

:ABORT
shutdown /a
GOTO END

:REBOOT
SET PARAMETERS=/r /c "Stopper - Rebooting server"
GOTO STOPSERVICES

:SHUTDOWN
SET PARAMETERS=/s /c "Stopper - Shutting down the server"
GOTO STOPSERVICES


:STOPSERVICES
ECHO ON
REM - While we are waiting for the main Exchange services to stop,
REM - Some peripheral services will be closed in the background.
start /min net stop MSExchangeMGMT /yes
start /min net stop RESvc /yes
start /min net stop POP3Svc /yes
start /min net stop IMAP4Svc /yes
start /min net stop NntpSvc /yes
start /min net stop SMTPSVC /yes

REM - Stop Exchange main services before shutdown to avoid timing conflicts.

net stop MSExchangeES /yes
net stop MSExchangeIS /yes
net stop MSExchangeMTA /yes
net stop MSExchangeSA /yes

REM - Well, why not stop other services in the background just for fun?
REM - Stopping IISADMIN will stop other dependant services like W3SVC, and HTTPFilter (SSL).
start /min net stop IISADMIN /yes
start /min net stop MSSEARCH /yes
start /min net stop Spooler /yes

REM - Now it's time to reboot or shutdown the server.
shutdown %PARAMETERS% /t 10

REM To abort, type:
REM shutdown /a
:END

 

[Mshen]

hey there,

your shutdwn.cmd script worked for me. system downtime dropped from 10 minutes to 4 minutes. what a performance.

many thanks for the tip.

cheers,

mike

 

[trasher133]

Good to hear!!!