Finally I found information to get user permissions for a particulary object - using user groups permissions and specifics user permissions.
===========
Source from "Frequently Asked Questions About Microsoft Access Security for Microsoft Access versions 2.0 through 2000"
URL =>
Content => 17. How can I retrieve the "most restrictive" permissions for attached tables?
===========
Usage:
If GetPermission(CurrentUser(), poTables, "MyTable"

And dbSecDeleteData Then
Debug.Print "User can delete data"
End If
Public Enum PermissionObject
poDatabases
poForms
poModules
poReports
poTables
End Enum
Public Function GetPermission(UserName As String, ObjectType As PermissionObject, ObjectName As String) As Long
Dim db As Database
Dim doc As Document
Dim group As group
Set db = CurrentDb()
'Get document
Set doc = GetDocument(db, ObjectType, ObjectName)
If doc Is Nothing Then
GetPermission = 0
Exit Function
End If
'Get explicit permissions for document
doc.UserName = UserName
GetPermission = doc.Permissions
'Add permissions for each group where user is a member
For Each group In DBEngine(0).Users(UserName).Groups
doc.UserName = group.name
GetPermission = GetPermission Or doc.Permissions
Next group
End Function
Private Function GetDocument(db As Database, ObjectType As PermissionObject, ObjectName As String) As Document
Dim con As Container
Set GetDocument = Nothing
Set con = GetContainer(db, ObjectType)
If Not con Is Nothing Then
On Error Resume Next 'if Object doesn't exists
Set GetDocument = con.Documents(ObjectName)
End If
End Function
Private Function GetContainer(db As Database, ObjectType As PermissionObject) As Container
Select Case ObjectType
Case poDatabases
Set GetContainer = db.Containers!Databases
Case poForms
Set GetContainer = db.Containers!Forms
Case poModules
Set GetContainer = db.Containers!Modules
Case poReports
Set GetContainer = db.Containers!Reports
Case poTables
Set GetContainer = db.Containers!Tables
Case Else
Set GetContainer = Nothing
End Select
End Function
===========
Object Microsoft Access permission Microsoft Jet permission constant (Source MSDN)
Database
Open/Run dbSecDBOpen
Open Exclusive dbSecDBOpenExclusive
Administer dbSecDBAdmin
Tables and queries
Read Design dbSecReadDef
Modify Design dbSecWriteDef
Administer dbSecFullAccess
Read Data dbSecRetrieveData
Update Data dbSecReplaceData
Insert Data dbSecInsertData
Delete Data dbSecDeleteData
Forms and reports
Open/Run acSecFrmRptExecute
Read Design acSecFrmRptReadDef
Modify Design acSecFrmRptWriteDef
Administer dbSecFullAccess
Macros Open/Run acSecMacExecute
Read Design acSecMacReadDef
Modify Design acSecMacWriteDef
Administer dbSecFullAccess
Modules
Read Design acSecModReadDef
Modify Design acSecModWriteDef
Administer dbSecFullAccess