simple but annoying problem

[tujchl]

Hi everyone:

my trouble is like this:
for example:
some words like below in my text file:

NM * * NM *
.......

and I want to caculate the sum of NM and *, and find the position of last right NM(both NM and * were taken into count), I write code like this:
$read="NM * * NM * ";
while($read=~/(NM)|(\s\*\s)/g){
$target=$1;
}
but () can only capture NM not *, please tell me how to modify it.

PS: I come from china, and my English is not very good, but I practise it, if you consider some sentence which I write is unsuitable, could you please help me and write down the correct expression?

thanks

 

[sycoogtit]

You just need to get rid of some parentheses.

while($read=~/(NM|\s\*\s)/g){

The way you have it, 'NM' will be saved in $1 and '*' will be saved in $2.

--

http://MyUniversityTutor.com

 

[mikrom]

To find the position of the most right 'NM' you can use the function rindex(), e.g.:

  my $last_NM_column = rindex($line,'NM') + 1;
  if ($last_NM_column > 0) {
    print ".... the most right 'NM' is in Column $last_NM_column\n";
  }
  else{
    print ".... 'NM' not in line !\n";
  }

counting words in Perl is simple, e.g.:

# counting words in Text file.
# Usage:
# perl wordcount.pl myfile.txt
use strict;

my %word_count=(); #hash of counts

while ( my $line = <> ) {
  chomp($line);
  #print " $line\n";
  # split line into words (delimited by /\s+/
  my @line_list=split(/\s+/,$line);

  # process each line
  foreach my $word (@line_list){
    #print "'$word'\n";
    if ($word_count{$word}){
      $word_count{$word} += 1;
    }
    else {
      $word_count{$word} = 1;	    
    } 
  }
}

# print statistics
foreach my $word (keys(%word_count)){
  print "Count of '$word' = $word_count{$word}\n";
}

 

[mikrom]

I tried the sycoogtit's idea:

# counting ' NM ' and ' * ' in Text file.
# Usage:
# perl NM_count.pl myfile.txt
use strict;

my $NM_count = 0;
my $asterisk_count = 0;
while ( my $line = <> ) {
  chomp($line);
  #print " $line\n";
  # split line into words (delimited by /\s+/
  my @line_list=split(/\s+/,$line);

  # process each line
  while($line=~/(NM|\s\*\s)/g){
    my $word = $1;
    #print "'$word'\n";
    if ($word eq 'NM') {
      $NM_count += 1;
    }
    elsif ($word eq ' * ')
    {
      $asterisk_count += 1;	    
    }
  }
}

# print statistics
print "Count of 'NM'   = $NM_count\n";
print "Count of ' * '  = $asterisk_count\n";

 

[KevinADC]

There is no need for the if/else block. All you need is:

  foreach my $word (@line_list){
      $word_count{$word}++;        
  }

------------------------------------------
- Kevin, perl coder unexceptional!

 

[mikrom]

Good remark KevinADC, very interesting .. I tried it and it's true

But I don't understand this Perl's behaviour:
If I try

my $myvar='xaz';
print "\$myvar = $myvar\n";
$myvar += 1;
print "\$myvar = $myvar\n";

I get this

$myvar = xaz
$myvar = 1

It's OK, but if I use ++ instead of += 1, i.e I modify the above code so:

my $myvar='xaz';
print "\$myvar = $myvar\n";
$myvar ++;
print "\$myvar = $myvar\n";

I would expect the same result, but what a surprise .. I get this

$myvar = xaz
$myvar = xba

Could you explain why it is so???

 

[KevinADC]

I think this will explain it:

http://perldoc.perl.org/perlop.html#Auto-increment-and-Auto-decrement

------------------------------------------
- Kevin, perl coder unexceptional!

 

[tujchl]

special thanks to everyone , resolved!!!!

Hi everyone:

my trouble is like this:
for example:
some words like below in my text file:

NM * * NM *
.......

and I want to caculate the sum of NM and *, and find the position of last right NM(both NM and * were taken into count), I write code like this:
$read="NM * * NM * ";
while($read=~/(NM)|(\s\*\s)/g){
$target=$1;
}
but () ca

 

[mikrom]

Great! thanks a lot KevinADC