Scripting Problem

[steel451]

Am struggling to trouble shoot an issue with a piece of script I have written for a new line. The problem is that the Open Voice Session seems to only kick in when agents are in Standby and not when the go into Not Ready, this doesn't make sense. Anyone able to shed any light on it?

*******************************************

SECTION wait_loop

GIVE MUSIC music_ch

WAIT 30

IF NOT LOGGED OUT AGENT 911911 THEN

GIVE CONTROLLED BROADCAST ANNOUNCEMENT cpilot_access

PLAY PROMPT

VOICE SEGMENT emergency_vs

WAIT 2

DISCONNECT

END IF

IF NOT QUEUED THEN

IF NOT OUT OF SERVICE btd THEN

QUEUE TO SKILLSET btd

WAIT 2

END IF

OPEN VOICE SESSION cpilot_access

PLAY PROMPT

VOICE SEGMENT btd_sec_wait_vs

COLLECT 1 DIGITS INTO collect_digits_dn_cv

INTER DIGIT TIMER 5

END VOICE SESSION

WHERE collect_digits_dn_cv EQUALS

VALUE 1: GIVE IVR cpilot_ivr WITH TREATMENT 1025

DEFAULT: EXECUTE wait_loop

END WHERE

EXECUTE wait_loop

END IF
**********************************************

Steel

 

[sandyml]

Steel, what's that last "END IF" at the end of your script? It looks like the section you posted is dependent on some other condition. Can you post the whole script?

 

[captaingadget]

It's the END IF at the bottom. It's in the wrong place. Put it here:
IF NOT QUEUED THEN

IF NOT OUT OF SERVICE btd THEN

QUEUE TO SKILLSET btd

WAIT 2
END IF
END IF

If the call WAS queued, then the script would have sent it to the END IF at the bottom so the wait loop_loop would not be executed.

 

[steel451]

Hi

Thanks for the help so far;

This is the whole script
*************************************
/* Check for Emergency Agent */

IF NOT LOGGED OUT AGENT 911911 THEN
GIVE CONTROLLED BROADCAST ANNOUNCEMENT cpilot_access
PLAY PROMPT
VOICE SEGMENT emergency_vs
WAIT 2
DISCONNECT
END IF

/* Give forced announcement at start */

GIVE CONTROLLED BROADCAST ANNOUNCEMENT cpilot_access
PLAY PROMPT
VOICE SEGMENT btd_opening_greeting

/*Force to Queue if agents logged in out of hours*/

IF NOT OUT OF SERVICE btd THEN
EXECUTE agent_login
END IF

/*Check for holidays where closed*/

IF DATE = ce_pd_bankhols_gv THEN

GIVE IVR cpilot_ivr

WITH TREATMENT 1025
END IF

/*Check for Opening Hours*/

IF (DAY OF WEEK = weekends_gv)

OR (DAY OF WEEK = weekdays_gv) AND (TIME OF DAY <> btd_open_hours_gv)

THEN

GIVE IVR cpilot_ivr

WITH TREATMENT 1025

END IF

SECTION agent_login

/* Skillset in service check */

IF NOT OUT OF SERVICE btd THEN
QUEUE TO SKILLSET btd
WAIT 2

END IF

WAIT 2

SECTION wait_loop

GIVE MUSIC music_ch

WAIT 30

IF NOT LOGGED OUT AGENT 911911 THEN

GIVE CONTROLLED BROADCAST ANNOUNCEMENT cpilot_access

PLAY PROMPT

VOICE SEGMENT emergency_vs

WAIT 2

DISCONNECT

END IF

IF NOT QUEUED THEN

IF NOT OUT OF SERVICE btd THEN

QUEUE TO SKILLSET btd

WAIT 2

END IF

OPEN VOICE SESSION cpilot_access

PLAY PROMPT

VOICE SEGMENT btd_sec_wait_vs

COLLECT 1 DIGITS INTO collect_digits_dn_cv

INTER DIGIT TIMER 5

END VOICE SESSION

WHERE collect_digits_dn_cv EQUALS

VALUE 1: GIVE IVR cpilot_ivr WITH TREATMENT 1025

DEFAULT: EXECUTE wait_loop

END WHERE

EXECUTE wait_loop

END IF

 

[sandyml]

captaingadget is right about the misplaced END IF. The way the script is written, the voice session will only kick in if the call is not queued. Move the END IF as he directed, so that your nested IF statements conclude before you move to the voice session. Right now, your call won't even loop.

 

[captaingadget]

It's definitely the END IF as mentioned above. The call will never get to the voice session unless it was NOT QUEUED i.e. no agents logged in (or in standby)since the END IF command associated with the IF NOT QUEUED command is at the end of the script after the execute wait_loop command, so the open voice session command is completely bypassed.

 

[steel451]

Thanks all, it looks like that was what was causing the problem.

Really grateful for the help captain (and everyone else).

Steel