SCCS Scripting Question

[TWNphoneguy]

Can someone assist with creating a script that would route calls by NPA to a secondary script. Tried adding the following to my primary script after the usual holiday and time of day checks but its still not routing correctly. Both global variables have been created.

IF (NPA = Ohio_NPA_List_gv) THEN
EXECUTE SCRIPT i_Migration_sc
END IF

IF (NPA = Tenn_NPA_List_gv) THEN
EXECUTE SCRIPT i_Migration_sc
END IF

EXECUTE Start


Any help would be greatly appreciated.

Thanks

 

[cgilmer]

Try using it in a where statement like this... it will save you some space and some logic.

Where NPA Equals

Value Ohio_NPA_List_gv: Execute Script i_Migration_sc

Value Tenn_NPA_List_gv: Execute Script i_Migration_sc

END Where


I don't think you need the () in the If statement for it to work. Not sure if its causing the problem or not. In any event you should find it easier to maintain and cut down on script size by using the where statement.

 

[TWNphoneguy]

Thanks for helping out cglimer. I tried it the way you recommended but my test call still routed to a skillset in the primary script instead of i_migration_sc. Here is my Primary script, could the problem be the EXECUTE Closed? Should I put my Where statment before that?


IF DATE = ag_sCall_Ctr_Holidays /*Holiday Check First */
THEN EXECUTE Holiday_Menu
END IF

IF TIME OF DAY = ag_sCall_Ctr_Hours /*8AM - 11PM */
AND DAY OF WEEK = ag_sWeekday
THEN EXECUTE Start
END IF


IF TIME OF DAY = ag_sSaturday_Hours /*8:30AM - 5PM */
AND DAY OF WEEK = SATURDAY
THEN EXECUTE Start
END IF


EXECUTE Closed_Menu /*After hours and all day Sunday */

WHERE NPA EQUALS

Value Ohio_NPA_List_gv: Execute Script i_Migration_sc

Value Tenn_NPA_List_gv: Execute Script i_Migration_sc

END WHERE


EXECUTE Start


SECTION Start /*This begins call queueing */

IF OUT OF SERVICE i_CS_sk
THEN EXECUTE First_Overflow
END IF

QUEUE TO SKILLSET i_CS_sk
WAIT 2
GIVE RAN 24 /*Transfer Announcement */
GIVE MUSIC 10
WAIT 58
GIVE RAN 26 /*All Reps are Busy */

IF NOT QUEUED
THEN QUEUE TO SKILLSET i_CS_sk
WAIT 2
END IF

SECTION First_Loop

WAIT 15
IF AGE OF CALL >= ag_siFirst_ovf_Timer /*90 */
THEN EXECUTE First_Overflow
END IF

WAIT 15
IF AGE OF CALL >= ag_siFirst_ovf_Timer /*90 */
THEN EXECUTE First_Overflow
END IF

WAIT 15
IF AGE OF CALL >= ag_siFirst_ovf_Timer /*90 */
THEN EXECUTE First_Overflow
END IF

WAIT 15
IF AGE OF CALL >= ag_siFirst_ovf_Timer /*90 */
THEN EXECUTE First_Overflow
END IF

GIVE RAN 26 /*All Reps are Busy */



EXECUTE First_Loop

SECTION First_Overflow /*The call is older than ag_siFirst_ovf_Timer (180)*/

IF OUT OF SERVICE i_csr_ovf_sk
THEN EXECUTE Second_Overflow
END IF

QUEUE TO SKILLSET i_csr_ovf_sk
WAIT 30
GIVE RAN 26 /*All Reps are Busy */

SECTION Second_Loop


WAIT 20
IF AGE OF CALL >= ag_siSecond_ovf_Timer /*180 */
THEN EXECUTE Second_Overflow
END IF

WAIT 20
IF AGE OF CALL >= ag_siSecond_ovf_Timer /*180 */
THEN EXECUTE Second_Overflow
END IF

WAIT 20
IF AGE OF CALL >= ag_siSecond_ovf_Timer /*180 */
THEN EXECUTE Second_Overflow
END IF

WAIT 20
IF AGE OF CALL >= ag_siSecond_ovf_Timer /*180 */
THEN EXECUTE Second_Overflow
END IF

GIVE RAN 26 /*All Reps are Busy */

EXECUTE Second_Loop

SECTION Second_Overflow /*The call is older than ag_siSecond_ovf_Timer (300)*/

IF OUT OF SERVICE i_CS_sk, i_csr_ovf_sk, i_CS_ovf_sk, i_gen_ovf_sk
THEN EXECUTE Emergency
END IF

QUEUE TO SKILLSET i_CS_ovf_sk
WAIT 60
GIVE RAN 26 /*All Reps are Busy */
QUEUE TO SKILLSET i_gen_ovf_sk
WAIT 60
GIVE RAN 26 /*All Reps are Busy */

SECTION Third_Loop


WAIT 15
IF AGE OF CALL >= ag_siBail_Timer /*600*/
THEN EXECUTE Bail
END IF

WAIT 15
IF AGE OF CALL >= ag_siBail_Timer /*600*/
THEN EXECUTE Bail
END IF

WAIT 15
IF AGE OF CALL >= ag_siBail_Timer /*600*/
THEN EXECUTE Bail
END IF

WAIT 15
IF AGE OF CALL >= ag_siBail_Timer /*600*/
THEN EXECUTE Bail
END IF


GIVE RAN 26 /*All Reps are Busy */

EXECUTE Third_Loop




Section Bail /*loops through bail out menu every 6 minutes */
/*Call is 10 minutes old by the time it gets here! */


IF OUT OF SERVICE i_CS_sk, i_csr_ovf_sk, i_CS_ovf_sk, i_gen_ovf_sk
THEN EXECUTE Emergency
END IF

IF NOT QUEUED
THEN QUEUE TO SKILLSET i_CS_sk with Priority 1
WAIT 2
END IF


GIVE IVR INTERRUPTIBLE 5295 WITH TREATMENT 10001 /*Press 1 for Mailbox, or hold Menu */

WAIT 90
GIVE RAN 26 /*All Reps are Busy */

WAIT 90
GIVE RAN 26 /*All Reps are Busy */

WAIT 90
GIVE RAN 26 /*All Reps are Busy */

WAIT 90
GIVE RAN 26 /*All Reps are Busy */

EXECUTE Bail



SECTION Emergency /*no agents logged in during business hours*/
GIVE IVR 5295 WITH TREATMENT 800 /*After Hours Menu */
DISCONNECT

SECTION Closed_Menu
GIVE IVR 5295 WITH TREATMENT 800 /*After Hours Menu */
DISCONNECT

SECTION Holiday_Menu
GIVE IVR 5295 WITH TREATMENT 10800 /*Generic Holiday Menu*/
DISCONNECT

 

[Nortellian]

If your call fits the if statements it's going to go to the Holiday section or the start section. If it doesn't fit then it will execute closed. Try the npa part right after the SECTION START line. However If you want all calls to certain npa's to go to a differnt script regardless of date or time put it as the first line of the script. Best guess and reading quick.

 

[TWNphoneguy]

Thanks Nortellian. Moved the statement like you said and it works now. Appreciate the both you guys helping out.

 

[DancingDave]

Why not reverse your date and time checks?

i.e. if time is outwith opening hours, send call to a closed section or closed script, otherwise let it drop through. The same method can be applied to other checks e.g. emergency, Remembrance day. It's a good idea to keep the logic the same throughout the script i.e. if test result = TRUE sned call elsewhere, if FALSE let it drop down to the next check.

DD

 

[TWNphoneguy]

Good point. Also just wondering if there is anyway to view the secondary application i_migration_sc in the realtime display. I can't seem to figure out how to do that and am wondering if only Primary scripts can be viewed?

Thx

 

[sandyml]

By definition, applications are derived from the primary script. Any secondary script stats are pegged against the primary script from which it came.