Reverse of PROCEDURE InstallSystemFont() (by agoeddeke) ????

[Ivanq]

I am using the PROCEDURE InstallSystemFont() posted by agoeddeke on 21 Oct 04. It does exactly what I needed (thank you very much). Now I need a procedure that will do just the reverse - remove the font from AddFontResource from within VFP. I allow a user to view non-installed fonts and give them the option of installing or not. To do this I copy the font ttf file, which is in a table, to a temp folder and call InstallSystemFont(). If they choose not to install I need to ERASE that font file from the temp folder. Problem is the font file in in use by windows and can not be erased from the temp folder untill a reboot.

Would appreciate any help.

 

[agoeddeke]

This is untested, but maybe try the RemoveFontResource API:

llSuccess = RemoveSystemFont("path\filename.ttf")
** erase file now ***


PROCEDURE RemoveSystemFont()
   LPARAMETERS lcFontLocFile
   LOCAL lnNumFontsRemoved

   DECLARE INTEGER RemoveFontResource IN GDI32.DLL ;
      STRING @ lpszFileName
   DECLARE INTEGER SendMessage IN USER32.DLL ;
      INTEGER hWnd, ;
      INTEGER Msg, ;
      INTEGER wParameter, ;
      INTEGER lParameter
   #DEFINE HWND_BROADCAST 0xFFFF
   #DEFINE WM_FONTCHANGE  0x001D

   lnNumFontsRemoved=RemoveFontResource(lcFontLocFile)
   IF lnNumFontsRemoved > 0
      *\\Font removed sucessfully, send notification to Windows so apps get updated
      =SendMessage(HWND_BROADCAST,WM_FONTCHANGE,0,0)
      RETURN .T.
      ELSE
      *\\Unable to remove font
      RETURN .F.
   ENDIF   
ENDPROC

Andy

 

[Ivanq]

Thank you for your help but it doesn't seem to work. Always returns .f.. Maybe I'm doing something wrong - I just pass the full font name such as =RemoveSystemFont("easygo.tff") - is this correct?

As far as using RemoveFontResource API I haven't a clue on how to do it but would like to learn.

Do appreciate your time - - -

 

[agoeddeke]

Maybe I'm doing something wrong - I just pass the full font name such as =RemoveSystemFont("easygo.tff") - is this correct?

I guess I might try fully qualifying the path to the TTF file. As in:

=RemoveSystemFont(GETENV("SYSTEMROOT")+"\FONTS\easygo.ttf")

Just a guess.

Andy

 

[Ivanq]

I tried the above suggestion but still returns .f. (or 0 in the procedure). I did find this:

http://msdn.microsoft.com/library/default.asp?url=/library/en-us/gdi/fontext_1m3p.asp

But again I'm not savy enough on api's to understand - -

CGP - - -

 

[agoeddeke]

I tried the above suggestion but still returns .f.

Regardless of what value the procedure returns, are you able to erase the TTF file after you call the procedure? That's the overall goal isn't it?

Andy

 

[Ivanq]

I think I've solved this problem. At least this procedure is working for me now. I can now erase the temp font file.

*************************************************************
* adds/removes temp fonts
* found basis of code ( I have modified) at:
*

http://www.foxite.com/archives/fonts_problem_0000034457.htm

* and
*

http://msdn.microsoft.com/library/default.asp?url=/library/en-us/gdi/fontext_9r51.asp

* and lots of code/help from agoeddeke on Tek=Tips
* para:
* whichaction = 'add', 'remove'
* processfontname = full font name
*
* NOTE!!!
* the parameter processfontname must also incude the
* file path if the font is NOT
* in the default windows/font folder - this applies
* for add or remove
* IE:
* do AddRemoveFont with "add',"t\baxter.ttf"
* where 't\' is a subdir that has the font file
* under some circumstances you must use
* CLEAR RESOURCES 'fontname' before calling this
* procedure to remove a font
*************************************************************
Procedure AddRemoveFont
Lparameters whichaction,processfontname
failed=.F.
* add the font
Do Case
Case whichaction="add"
Declare AddFontResource In GDi32.Dll String
If AddFontResource(processfontname)
Wait Window Nowait "Font Installed..."
Else
Wait Window "Addition Failed..." Nowait
failed=.T.
Endif
* not sure if this is correct
Clear Dlls "AddFontResource"
* Removing the resource file is done with
* RemoveFontResource which resides
* in the same DLL and has the same parameter
Case whichaction="remove"
Declare RemoveFontResource In GDi32.Dll String
If RemoveFontResource(processfontname)
Wait Window Nowait "Font Removed..."
Else
Wait Window "Removal Failed..." Nowait
failed=.T.
Endif
* not sure if this is correct
Clear Dlls "RemoveFontResource"
Endcase
* message to other win apps of the modified
* font selections
If Not failed
Declare Integer SendMessage In USER32.Dll ;
INTEGER HWnd, ;
INTEGER Msg, ;
INTEGER wParameter, ;
INTEGER Lparameter
#Define HWND_BROADCAST 0xFFFF
#Define WM_FONTCHANGE 0x001D
=SendMessage(HWND_BROADCAST,WM_FONTCHANGE,0,0)
Endi
Return .T.

 

[agoeddeke]

I'm glad you were able to work it out.

Andy

 

[Ivanq]

agoeddeke, thanks for all your help

Cliff - - -