Response.BinaryWrite file name Question.

[PSFMIS]

I'm using Response.BinaryWrite to display some files that are outside of my webfolder and do not have Read permissions with IIS.

My question is about the code below. When I open or save files using this code the files are always named BinDoc.asp which is the name of this file.

Is there a way I can specify the name of the file?


BinDoc.asp

   	   	Response.buffer = TRUE

   	Dim vntStream
   	Dim oMyObject
	Dim FileName
	Dim StoreFolder

	FileName = Request.QueryString("FileName")
	StoreFolder = Request.QueryString("StoreFolder")

	Dim CaseFileType

	CaseFileType = UCASE(Right(Request.QueryString("FileName"),3))

	Select Case CaseFileType

		Case "PDF" 'Adobe PDF
			Response.ContentType = "application/pdf"
		Case "DOC" 'Microsoft Word
			Response.ContentType = "application/msword"
		Case "XLS" 'Microsoft Excel
			Response.ContentType = "application/vnd.ms-excel"
		Case "PPT" 'Microsoft PowerPoint
			Response.ContentType = "application/ms-powerpoint"
		Case "GIF" 'GIF Image
			Response.ContentType = "image/gif"
		Case "JPG" 'JPEG Image
			Response.ContentType = "image/jpeg"
								
	End Select
			
   	Set oMyObject = Server.CreateObject("ASPBinFile.clsASPBinFile")
   	vntStream = oMyObject.readBinFile("c:\datastore\documents\"& StoreFolder &"\"& FileName)
  	Response.BinaryWrite(vntStream)
	
   	Set oMyObject = Nothing

   	Response.End

 

[DotNetGnat]

something like this:

Select Case CaseFileType

        Case "PDF" 'Adobe PDF
            Response.ContentType = "application/pdf"
[red]Response.AddHeader("Content-Disposition", attachment;filename="myfilename.pdf")[/red]
        Case "DOC" 'Microsoft Word
            Response.ContentType = "application/msword"
        Case "XLS" 'Microsoft Excel
            Response.ContentType = "application/vnd.ms-excel"
        Case "PPT" 'Microsoft PowerPoint
            Response.ContentType = "application/ms-powerpoint"
        Case "GIF" 'GIF Image
            Response.ContentType = "image/gif"
        Case "JPG" 'JPEG Image
            Response.ContentType = "image/jpeg"
                                
    End Select

similarly add the red line for others with the correct extension...

-DNG

 

[PSFMIS]

Wow.. Thats pretty simple. I pass the filename through the link already so I just put that variable at the end of the red text.

Response.Addheader "Content-Disposition", "inline; filename=" & FileName

I left out the parentheses because I would get the error below with them in when right clicking and choosing open in new window.


Microsoft VBScript compilation error '800a0414'

Cannot use parentheses when calling a Sub

/folder/BinDocs.asp, line 53

Response.Addheader ("Content-Disposition", "inline; filename=" & FileName)
--------------------------------------------------------------------------------------^


Thanks,
-Aaron

 

[DotNetGnat]

you dont need the parentheses...just do

Response.Addheader "Content-Disposition", "inline; filename=" & FileName

and NOT

Response.Addheader ("Content-Disposition", "inline; filename=" & FileName)

-DNG