Remove some features from adobe acrobat

[JaneJantz]

Is there a way to view a pdf file in vfp where the user cannot see a "File" button or "Internet" button. I want to display a pdf file inside my app, but dont want the user to have any access to the rest of the computer or network. How can I disable those features where they can browse the network drives or go to a web site? Is there any way to do this?

 

[baltman]

Does this work for you?

A quick form to show your PDF files within VFP.
faq184-4267

 

[DSummZZZ]

You can drop a PDF viewer OLE control on your form.
By default, as far as I can tell there is no file open ability. Something you have to add yourself.


-Dave Summers-

Even more Fox stuff at:

http://www.davesummers.net/foxprolinks.htm

 

[JaneJantz]

The FAQ is just what I needed, but do you know of any way to take of the "Create Adobe PDF Online" button? It will let the user get into the internet and possibly bring in a virus. I want them to just see the pdf file... nothing else. Is this possible? Thanks for your help.

 

[DSummZZZ]

Sounds more like an Adobe question, but there is one setting I found:

MyForm.oPDFcontrol.setShowToolbar(.f.)

That disables ALL toolbars. You may be able to use it to select individual ones, but I didn't get that deep into it.


-Dave Summers-

Even more Fox stuff at:

http://www.davesummers.net/foxprolinks.htm

 

[darrellblackhawk]

Example:
( Note: Command2's click() method references a pdf file
location on my system )

Darrell

**************************************************
*-- Class Library:  c:\dev\tektip answers\pdfexample.vcx
**************************************************


**************************************************
*-- Class:        pdfexample (c:\dev\tektip answers\pdfexample.vcx)
*-- ParentClass:  form
*-- BaseClass:    form
*-- Time Stamp:   05/02/04 07:55:10 PM
*-- Example of toggling a pdf control's toolbars
*
LOCAL o
o = CREATEOBJECT("pdfExample")
o.SHOW()
READ EVENTS

*
DEFINE CLASS pdfexample AS FORM


  HEIGHT = 500
  WIDTH = 800
  DOCREATE = .T.
  AUTOCENTER = .T.
  BORDERSTYLE = 2
  CAPTION = "Acrobat Example"
  NAME = "Form1"
  bshowtoolbars = .F.


  ADD OBJECT pdf AS OLECONTROL WITH ;
    OLECLASS = "PDF.PdfCtrl.5", ;
    TOP = 35, ;
    LEFT = 8, ;
    HEIGHT = 457, ;
    WIDTH = 784, ;
    NAME = "pdf"


  ADD OBJECT command1 AS COMMANDBUTTON WITH ;
    AUTOSIZE = .T., ;
    TOP = 5, ;
    LEFT = 106, ;
    HEIGHT = 27, ;
    WIDTH = 112, ;
    CAPTION = "Toggle Tool Bars", ;
    NAME = "Command1"


  ADD OBJECT command2 AS COMMANDBUTTON WITH ;
    TOP = 5, ;
    LEFT = 10, ;
    HEIGHT = 27, ;
    WIDTH = 84, ;
    CAPTION = "Load File", ;
    NAME = "Command2"


  PROCEDURE toggletoolbars
    WITH THIS
      .bShowToolBars = !.bShowToolBars
      .pdf.setShowToolbar(.bShowToolBars)
      .REFRESH()
    ENDWITH
  ENDPROC


  PROCEDURE loadpdf
    LPARAM pdfFile
    WITH THIS
      .pdf.LoadFile(pdfFile)
      .bShowToolBars = .T.
      .REFRESH()
    ENDWITH
  ENDPROC


  PROCEDURE INIT
    THIS.ToggleToolBars()
  ENDPROC

  PROCEDURE DESTROY
    CLEAR EVENTS
  ENDPROC

  PROCEDURE command1.REFRESH
    THIS.CAPTION = "Toggle toolbars "+IIF(THISFORM.bShowToolBars,"off","on")
  ENDPROC


  PROCEDURE command1.CLICK
    THISFORM.ToggleToolBars()
  ENDPROC


  PROCEDURE command2.CLICK
    THISFORM.LoadPdf("C:\Program Files\Adobe\Acrobat 5.0\Help\ENU\MiniReader.pdf")
  ENDPROC


ENDDEFINE
*
*-- EndDefine: pdfexample
**************************************************