Pageframe tab switching using keyboard 1

[ITSmwong]

Hello,

I was just wondering if anyone knew how to switch between tabs on a pageframe in FoxPro. I know in Windows (eg. Display Properties Pageframe), you can hit Ctrl+PageDown or Ctrl+PageUp to move from one tab to the other but that doesn't work in my FoxPro application.

Any ideas on how to make it work like this or other alternatives? I have a client that does not want to use the mouse at all and this was one situation I could not get around without using the mouse.

Thanks in advance guys!

Mike

 

[craigsboyd]

Arrow keys work for me.

Slighthaze = NULL
[sub]craig1442@mchsi.com[/sub][sup]

"Whom computers would destroy, they must first drive mad." - Anon​

[/sup]

 

[Nifrabar]

Hi:

Captions of e.g. 2 pages :
\<First Page
\<Second page

During program execution The 'F' of First page is underlined
Same with 'S'of second page

You can tab using Alt+F or Alt+S key

-Bart

 

[craigsboyd]

If you don't like either of these suggestions and you want it to work the way the Display Properties dialog works as you explained it (CTRL+PGDN and CTRL+PGUP) you could use something like the following. Cut-N-Paste the code into a prg and run it from within VFP.

PUBLIC oForm
oForm = CREATEOBJECT("clsKeyTabs")
oForm.show()

DEFINE CLASS clskeytabs AS form

	DoCreate = .T.
	Caption = "TAB NAVIGATION"
	Name = "Form1"

	ADD OBJECT pageframe1 AS pageframe WITH ;
		ErasePage = .T., ;
		PageCount = 5, ;
		Top = 36, ;
		Left = 60, ;
		Width = 241, ;
		Height = 169, ;
		Name = "Pageframe1", ;
		Page1.Caption = "Page1", ;
		Page1.Name = "Page1", ;
		Page2.Caption = "Page2", ;
		Page2.Name = "Page2", ;
		Page3.Caption = "Page3", ;
		Page3.Name = "Page3", ;
		Page4.Caption = "Page4", ;
		Page4.Name = "Page4", ;
		Page5.Caption = "Page5", ;
		Page5.Name = "Page5"

	PROCEDURE pageframe1.Destroy
		ON KEY LABEL CTRL+PGDN
		ON KEY LABEL CTRL+PGUP
	ENDPROC

	PROCEDURE pageframe1.Init
		ON KEY LABEL CTRL+PGDN ;
			_screen.activeform.pageframe1.ActivePage = ;
			IIF(_screen.activeform.pageframe1.ActivePage = 1, ;
			_screen.activeform.pageframe1.pagecount, ;
			_screen.activeform.pageframe1.ActivePage - 1)

		ON KEY LABEL CTRL+PGUP ;
			_screen.activeform.pageframe1.ActivePage = ;
			IIF(_screen.activeform.pageframe1.ActivePage = _screen.activeform.pageframe1.pagecount, ;
			1, _screen.activeform.pageframe1.ActivePage + 1)
	ENDPROC

ENDDEFINE

Slighthaze = NULL
[sub]craig1442@mchsi.com[/sub][sup]

&quot;Whom computers would destroy, they must first drive mad.&quot; - Anon​

[/sup]