Outputting results to a text file 1

[randallJ]

Hi

I have a program which evaluates a database and changes the value in a field if an expression is true. Everytime the expression is true I would like to send the record number and other information from various fields to a text file. What is the best way of doing this?

 

[Mike Lewis]

Create a cursor containing the record number and other required fields. Then COPY TO a text file. Something like this:

SELECT RECNO(), SomeField, AnotherField ;
  FROM MyTable ;
  INTO CURSOR csrTemp
SELECT csrTemp
COPY TO MyTextFile.TXT TYPE DELIMITED

The above is just to give you a general idea. The TYPE clause will need adjusting to suit the type of text file that you need.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

My Visual FoxPro site: www.ml-consult.co.uk

 

[Zografski]

May be

lcVar = TRANSFORM(RECNO())+[;]+YourFld1+[;]+YourFld2 &&& ...
STRTOFILE(lcVar,PUTFILE("where to save"))

 

[dgrewe]

Zografski,
In case they are exporting numbers or logicals, shoould it be
lcVar = TRANSFORM(RECNO())+[;]+ transform(YourFld1)+[;]+transform(YourFld2) &&& ...
STRTOFILE(lcVar,PUTFILE("where to save"))

David W. Grewe Dave

 

[Zografski]

Hi David,
I agree with you, but this is only a simple example.

 

[randallJ]

Thank you all for your repies. David I have used your solution as it allows me to append to a text file after each record has been evaluated. However is there a way to force a carriage return after a line of text has been appended? Basically I am recording the details of those records that have been changed, but would like the details of each record to start on a new line.

 

[randallJ]

oops sorry it was Zografski's solution.

 

[Zografski]

Hi randallJ,

#define CRLF CHR(13)+CHR(10)
LOCAL lcVar
lcVar = []
SCAN
    ...
    lcVar = lcvar + TRANSFORM(RECNO())+[;]+YourFld1+[;]+YourFld2+CRLF
    ...
ENDSCAN
...
STRTOFILE(lcVar,PUTFILE("where to save"))

 

[dgrewe]

If the file you scan has many records to export the lcVar in the Sample by Zografski will over flow. May want to expand Z's idea with.

#define CRLF CHR(13)+CHR(10)
LOCAL lcVar, pcFile, lnHandle
lcVar = []
pcFile = "C:\MyDirectory\Myfilename"

IF FILE(pcFile)
lnHandle=FOPEN(pcFile,2)
ELSE
=FCREATE(pcFile)
lnHandle=FOPEN(pcFile,2)
ENDIF
IF lnHandle > 0
SCAN
...
lcVar = TRANSFORM(RECNO())+[;]+YourFld1+[;]+YourFld2+CRLF
=FPUTS(lnHandle,lcVar)
...
ENDSCAN
=FCLOSE(lnHandle)
ENDIF

David W. Grewe Dave

 

[Zografski]

Other way ;~)

#define CRLF CHR(13)+CHR(10)
LOCAL lcVar
lcSaveFile = PUTFILE("where to save")
IF EMPTY(lcSaveFile)
   MESSAGEBOX("No File selected ?")
   RETURN
ENDIF

SCAN
    IF yourcondition = .t.
       lcVar = TRANSFORM(RECNO())+[;]+YourFld1+[;]+YourFld2+CRLF
       STRTOFILE(lcVar,lcSaveFile,1)
    ENDIF
ENDSCAN

 

[randallJ]

Thanks both solutions are great.