msxml3.dll error '800c0008' - The download of the specified resource h

[Gert74]

Hello,

I have a question and googling didn't help me. I'm trying to get/read an rss-feed over http, but it gives the following error:

msxml3.dll error '800c0008'
The download of the specified resource has failed.
/testpaginas/Kopie van testeventlog.asp, line 24


I'm using this code:

<%
	Dim objXML
	Set ObjXML 		= Server.CreateObject("MSXML2.DOMDOCUMENT")
	With ObjXML
	   	.async = False
	   
		.LoadXML GetXMLFile("[URL unfurl="true"]http://www.minvws.nl/nieuws/rss.asp")[/URL]
	    If .parseError.errorCode <> 0 Then
			Response.Write ="<font face=verdana size=1>Data Error Occured:<BR>" & _
						"Reason: " & .parseError.reason & "<BR>" & _
						"Line: " & .parseError.line & " Position: " & .parseError.linepos & "<BR>" & _
						"Text: " & .parseError.srctext
		Else
			Response.Write .SelectSingleNode("//title").Text 
	    End If
	End With
	Set ObjXML 		= Nothing

Function GetXMLFile(StrFile)
	Dim ObjHttp
	Set ObjHttp = Server.CreateObject("MSXML2.XMLHTTP")
	With ObjHttp
		.Open "GET", StrFile, False
		.Send
		GetXMLFile = .responseText
	End With
	Set ObjHttp = Nothing
End Function
%>

.Send is line 24.
When I replace the url with a url on my own webserver it goed fine. My Server uses Windows 2003 with the latest version of IIS. I can surf the internet on the server with Internet Explorer. I was thinking maybe something is wrong in my IIS-settings. Hopefully someone can help me.

Cheers,

Gert

 

[Gert74]

Stop, don't look any further, I've found the solution myself. I had to use another ServerObject, "MSXML2.ServerXMLHTTP.4.0" instead of "MSXML2.XMLHTTP".

Function GetXMLFile(StrFile)
	Dim ObjHttp
	Set ObjHttp = Server.CreateObject("MSXML2.ServerXMLHTTP.4.0")
    'Old Code: Set ObjHttp = Server.CreateObject("MSXML2.XMLHTTP")
	With ObjHttp
		.Open "GET", StrFile, False
		.Send
		GetXMLFile = .responseText
	End With
	Set ObjHttp = Nothing
End Function

Gert