MSFLEXGRID 1

[Normally]

I populated flexgrid with data. I can hilight a row when mouse goes over the grid. How can i get hilighted row turned off when i leave the flexgrid?

 

[Andrzejek]

With MSFLEXGRID
  For r = 1 To .Rows - 1
    .Row = r
    For c = 1 To .Cols - 1
      .Col = c
      .CellBackColor = vbWhite
    Next c
  Next r
End With

Have fun.

---- Andy

 

[Normally]

As the mouse leaves the flegrid the hilighted row shuold be like all other rows.

 

[Andrzejek]

I can hilight a row when mouse goes over the grid.

Show the code where you do it.

Have fun.

---- Andy

 

[Normally]

here is my code

Private Sub Grid_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Grid.MouseRow <> RowActual Then
ChangeGridColor RowActual, 0
RowActual = Grid.MouseRow
HiRow = Grid.MouseRow
ChangeGridColor RowActual, 1
Text1 = "I'm over row " & RowActual
End If
End Sub

Private Sub ChangeGridColor(RowNum As Integer, Num As Integer)
Grid.Row = RowNum
Grid.Redraw = False
Select Case Num
Case 0
For c = 0 To Grid.Cols - 1
Grid.Col = c
Grid.CellBackColor = Grid.BackColorFixed
Grid.CellForeColor = Grid.ForeColorFixed
Next c
Case 1
For c = 0 To Grid.Cols - 1
Grid.Col = c
Grid.CellBackColor = Grid.BackColorSel
Grid.CellForeColor = Grid.ForeColorSel
Next c
End Select
Grid.Redraw = True
End Sub

As Grid looses focus I want hilighted row to return to normal.

 

[memememememememe]

The grid is not getting focus with the MouseMove event, so using the LostFocus event won't work either.

Here's one work around leaving a small border of the form around the flexgrid

Note the use of Option Explicit (very good coding practise to get into)

Option Explicit

Private ChangedGrid  As Boolean
Private RowActual    As Integer
Private HiRow        As Integer

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim r As Integer
Dim c As Integer

If ChangedGrid Then
   ChangedGrid = False
   
   With Grid
        For r = 1 To .Rows - 1
           .Row = r
            For c = 1 To .Cols - 1
               .Col = c
               .CellBackColor = vbWhite
            Next c
        Next r
   End With
End If
End Sub

Private Sub Grid_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
   If Grid.MouseRow <> RowActual Then
      ChangeGridColor RowActual, 0
      RowActual = Grid.MouseRow
      HiRow = Grid.MouseRow
      ChangeGridColor RowActual, 1
      Text1 = "I'm over row " & RowActual
      [COLOR=red]ChangedGrid = True[/color]
   End If
End Sub

Private Sub ChangeGridColor(RowNum As Integer, Num As Integer)
Dim c As Integer

   Grid.Row = RowNum
   Grid.Redraw = False
   Select Case Num
      Case 0
         For c = 0 To Grid.Cols - 1
            Grid.Col = c
            Grid.CellBackColor = Grid.BackColorFixed
            Grid.CellForeColor = Grid.ForeColorFixed
         Next c
      Case 1
         For c = 0 To Grid.Cols - 1
            Grid.Col = c
            Grid.CellBackColor = Grid.BackColorSel
            Grid.CellForeColor = Grid.ForeColorSel
         Next c
   End Select
   Grid.Redraw = True
End Sub

 

[Andrzejek]

How about this:
(modified code, not tested)

Option Explicit

Private ChangedGrid  As Boolean
Private RowActual    As Integer
Private HiRow        As Integer

Private Sub Form_MouseMove(Button As Integer, _
Shift As Integer, X As Single, Y As Single)

If ChangedGrid Then
   ChangedGrid = False
   [blue]ChangeGridColor RowActual, 0[/blue]
End If

End Sub

Private Sub Grid_MouseMove(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
   If Grid.MouseRow <> RowActual Then
      ChangeGridColor RowActual, 0
      RowActual = Grid.MouseRow
      HiRow = Grid.MouseRow
      ChangeGridColor RowActual, 1
      Text1 = "I'm over row " & RowActual
      ChangedGrid = True
   End If
End Sub

Private Sub ChangeGridColor(RowNum As Integer, Num As Integer)
Dim c As Integer

[blue]With Grid[/blue]
   .Row = RowNum
   .Redraw = False
   Select Case Num
      Case 0
         For c = 0 To .Cols - 1
            .Col = c
            .CellBackColor = .BackColorFixed
            .CellForeColor = .ForeColorFixed
         Next c
      Case 1
         For c = 0 To .Cols - 1
            .Col = c
            .CellBackColor = .BackColorSel
            .CellForeColor = .ForeColorSel
         Next c
   End Select
   .Redraw = True
[blue]End With[/blue]

End Sub

And I totally agree with using Option Explicit


Have fun.

---- Andy