ListView only displays the first 259 characters of each item 3

[DotNetter]

When you add long strings to a ListView control, all of the string is added to the items collection, but the control only displays the first 259 characters of each item. I've seen the KB article at

http://support.microsoft.com/default.aspx?scid=kb;en-us;321104

- but their brilliant "resolution" is to use a textbox, instead. Well that's lovely if you want to use a textbox!

Does anyone have any workarounds how to get a ListView to display longer values?

Thanks much,
Dot

 

[RiverGuy]

Why not use a tool tip to display the whole string on mouse over?

 

[DotNetter]

That's a good idea, RiverGuy, honestly hadn't thought of it...

But how can I have that ToolTip display only for that subitem (or at least only for that row in the listview)?

Thanks!
Dot

 

[ca8msm]

Use a ToolTip control...


____________________________________________________________

Need help finding an answer?

Try the Search Facility or read FAQ222-2244 on how to get better results.

 

[DotNetter]

I know that - but the ToolTipControl.SetToolTip takes a Control as an argument - how can I just have it work on that one subitem of the ListView?

Thanks,
Dot

 

[RiverGuy]

Re-set the tool-tip text when the mouse moves. Look at ListView.GetItemAt(), which allows to you to find the item the mouse would be over.

 

[earthandfire]

I've tested the Glacial ListView control with well over three hundred characters and it seems to work fine.

Have a look:

http://www.codeproject.com/cs/miscctrl/aa_listview.asp

Hope this helps.

 

[earthandfire]

I forgot to add that it also has item word wrap capabilities so that large amounts of text can be wrapped.


Hope this helps.

 

[DotNetter]

Earth, thanks, but I'd like to stick (for this) with the native ListView...

RiverGuy, would you suggest using the "MouseHover" event? How do I get the X/Y coordinates?

Thanks,
Dot

 

[mkohl]

Private Sub ListBox1_MouseHover(ByVal sender As Object, ByVal e As System.EventArgs) Handles ListBox1.MouseHover

ToolTip1.SetToolTip(ListBox1, listBox1.SelectedItem)

End Sub

Im not for sure the capabilities of a listbox, but you can always create a custom control to fit your needs.

-mike

 

[stravis]

Here is an easy way.

1. Set the the ListView.ShowItemToolTip = True
2. Set the tooltip text of each ListViewItem using the following property ListViewItem.ToolTipText = "My List Item ToolTip"

 

[ca8msm]

stravis - Is the ToolTipText a property in version 1.1 of the framework as I don't see it?

DotNetter,

What I had in mind was using the Tooltip control along with the mousemove event of the ListView. e.g.

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim lvi As ListViewItem
        For i As Integer = 1 To 10
            lvi = New ListViewItem
            lvi.Tag = "This is the tooltip for Item" & i
            lvi.Text = "Item" & i
            ListView1.Items.Add(lvi)
            lvi = Nothing
        Next
    End Sub

    Private Sub listView1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ListView1.MouseMove
        Dim lvitem As ListViewItem = CType(ListView1.GetItemAt(e.X, e.Y), ListViewItem)
        If (Not (lvitem Is Nothing)) Then
            If Not (lvitem.Tag Is Nothing) Then
                If Not (lvitem.Tag.ToString = Me.ToolTip1.GetToolTip(Me.ListView1)) Then
                    Me.ToolTip1.SetToolTip(Me.ListView1, lvitem.Tag.ToString)
                End If
            Else
                Me.ToolTip1.SetToolTip(Me.ListView1, "")
            End If
        Else
            Me.ToolTip1.SetToolTip(Me.ListView1, "")
        End If
    End Sub

____________________________________________________________

Need help finding an answer?

Try the Search Facility or read FAQ222-2244 on how to get better results.

 

[DotNetter]

Stravis, I don't see that property for a ListViewItem.

Ca8msm, I need to associate the ToolTip with a SubItem of a ListViewItem - how do I do that?

Thanks very much for your replies!!!
D.

 

[stravis]

Sorry, I was wrong. ToolTipText is in the .Net 2.0 framework. I guess I shouldn't be so hasty to answer a question.

 

[RiverGuy]

I think you want to associate it with the whole ListView. However, you want the text of it to be in relation to the subitem you are working with. You should be able to use the .GetItemAt() function to reurn the ListViewItem. Then, depending on where the mouse is, you should be able to figure out which subitem it is over because you have defined the column widths.

 

[earthandfire]

I don't know whether or not you've got a working ToolTip solution (I still think that using the Glacial ListView is the easiest solution), however:

  Private Sub ListView1_MouseHover(ByVal sender As Object, ByVal e As System.EventArgs) Handles ListView1.MouseHover

    Dim x As Integer = Cursor.Position.X - (Me.Left + ListView1.Left)
    Dim hdrsize As Integer = ListView1.Items(0).Bounds.Top
    Dim y As Integer = Cursor.Position.Y - (Me.Top + ListView1.Top + hdrsize)
    Dim accumulatedwidth As Integer = 0
    Try
      Dim currentitem As Integer = ListView1.GetItemAt(2, y).Index
      For a As Integer = 0 To ListView1.Columns.Count - 1
        accumulatedwidth += ListView1.Columns(a).Width
        If x <= accumulatedwidth Then
          'MessageBox.Show(ListView1.Items(currentitem).SubItems(a).Text)
          ToolTip1.SetToolTip(ListView1, ListView1.Items(currentitem).SubItems(a).Text)
          Exit For
        End If
      Next
    Catch
    End Try
 
  End Sub

I've not commented it, I think that most of it should be self-explanatory, except possibly:

ListView1.GetItemAt(2, y)

I picked 2 as an arbitrary value to be at or very near the left of the first column.

Hope it helps.

 

[earthandfire]

Having experimented a bit further, my code sample works on entry into the list box (that is to say that when the mouse moves from outside the list box to inside it and then hovers.

Moving my code to the MouseMove event handler enables the ToolTip to follow the mouse as it moves within the list box.

I've also modified the Catch clause as follows:

Catch
'ToolTip1.SetToolTip(ListView1, "The mouse is not over an item")
ToolTip1.SetToolTip(ListView1, "")
End Try

Hope this helps.

 

[earthandfire]

I'd forgotten that MouseMove has MouseEventArgs so:

 Private Sub ListView1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles ListView1.MouseMove

    Dim accumulatedwidth As Integer = 0
    Try
      Dim currentitem As Integer = ListView1.GetItemAt(2, e.Y).Index
      For a As Integer = 0 To ListView1.Columns.Count - 1
        accumulatedwidth += ListView1.Columns(a).Width
        If e.X <= accumulatedwidth Then
          ToolTip1.SetToolTip(ListView1, ListView1.Items(currentitem).SubItems(a).Text)
          Exit For
        End If
      Next
    Catch
      ToolTip1.SetToolTip(ListView1, "")
    End Try

  End Sub

is a bit neater

Hope this helps.

 

[DotNetter]

Thank you Earth/Fire, ca8sm, and stravis! (stars)
Dot