how to get the information of the software installed with .exe

[hartlen]

if i want to get the information of a software installed in my computer,which is installed by setup.exe file
such as get the software's version and serial

i use the win32_product but can get, it only get the software installed by .msi

my friends tell me to search the registry but i dont know how to do

thanks

 

[tsuji]

Hello hartlen,

Try this.

const hklm=&h80000002
const skey="Software\Microsoft\Windows\CurrentVersion\Uninstall"

set odic=createobject("scripting.dictionary")
set svcreg=getobject("winmgmts:root\default:stdregprov")
iret=svcreg.enumkey(hklm,skey,asubkey)
for i=0 to ubound(asubkey)
    iret=svcreg.getstringvalue(hklm,skey & "\" & asubkey(i),"displayname",sinfo)
    if not isnull(sinfo) then
        'echo is for testing 
        wscript.echo skey & "\" & asubkey(i) & vbcrlf & sinfo
        odic.add skey & "\" & asubkey(i), sinfo
    end if
next
wscript.echo "Installed software displayed : " & odic.count
set svcreg=nothing
'info is stored in odic, make further use or save as needed

regards - tsuji

 

[hartlen]

thank you very much

you make me known how to get the information