Group Policy for moving users 1

[MahVincent]

Hi all,

I have a group of users using laptops with wireless network cards, and these users belong to Domain users group only (as standard at my company, I mean they don't have Local Adminstrator right).
Because they need to change their network connection when stay in and out of office. So I intend to create a group named NETCONFIG containing all moving users (users with laptops) and create group policy to permit this group can change their network connections (Ex: disabe, enable, change IP add, etc). However, until now I don't know to do that. Pls help me to setup a group policy like that (as more details as possiable).

Thanks so much for your kind assistance.

Mah Vincent

 

[markdmac]

I don't believe you can assign those rights individually at the desktop level. I believe you will need to make them local admins.

You could however give this a try. little script I wrote for XP machines that stores network profiles (IP settings) and allows the use to switch based on a location name. I wrote this for laptop users, but believe that they had admin rights. This was created to keep them from actually messing with their settings.

'==========================================================================
'
' NAME: IPSwitcher.vbs
'
' AUTHOR: Mark D. MacLachlan , The Spider's Parlor
' URL: [URL unfurl="true"]http://www.thespidersparlor.com[/URL]
' DATE  : 3/23/2004
'
' COMMENT: <comment>
'
'==========================================================================


Dim fso,WSHShell
 
 
Set fso = CreateObject("Scripting.FileSystemObject")
Set WSHSHell = CreateObject("Wscript.Shell")
Path = "C:\IPCONFIGS"
 
'Create Storage location if not already there
If Not fso.FolderExists(Path) Then
 fso.CreateFolder(Path)
End If
 
'Prompt to activate, create or delete a config
Action = InputBox("Do you want to ACTIVATE, SAVE or DELETE an IP Configuration","What should I do?")
Action = UCase(Action)
 
Call ConfigList
 
Select Case Action
 
Case "ACTIVATE"
     If Len(ConfigList) >0 Then
  What = InputBox("Existing configurations are:" & vbCrLf & vbCrLf & ConfigList & vbCrLf & "Enter config name to activate.","Activate Which Configuration")
 FileName = Path & "\" & What & ".txt"
 WSHShell.Run ("cmd /c netsh -f " & FileName)
 Else
  MsgBox "Sorry there are no configurations to activate"
 End If
 
Case "SAVE"
 If Len(ConfigList) >0 Then
  What = InputBox("Existing configurations are:" & vbCrLf & vbCrLf & ConfigList & vbCrLf & "Enter new config name to save, enter existing name to overwrite.","Save Configuration")
 Else
  What = InputBox("Enter new config name to save.","Save Configuration")
 End If 
 FileName = Path & "\" & What & ".txt"
 'MsgBox Filename
 WSHShell.Run ("cmd /c netsh -c interface dump >" & FileName)
 
Case "DELETE"
 If Len(ConfigList) >0 Then
  What = InputBox("Existing configurations are:" & vbCrLf & vbCrLf & ConfigList & vbCrLf & "Enter config name to delete.","Delete Configuration")
  FileName = Path & "\" & What & ".txt"
  fso.DeleteFile(FileName)
 Else
  MsgBox "No configurations saved to delete."
 End If
 
End Select
MsgBox "Done"
 
Function ConfigList
'Read the existing configs
Set oFolder = fso.GetFolder(Path)
 
ThisList = ""  
For Each oFile In oFolder.files
 ThisConfigLength = (Len(oFile.Name)-4)
 ThisConfig = Left(oFile.Name,ThisConfigLength)
 ThisList = ThisList & ThisConfig & vbCrLf
Next
ConfigList = UCase(ThisList)
 
End Function

I hope you find this post helpful.

Regards,

Mark

 

[MahVincent]

I'll try and it's great.
Thanks so much for your help.
Mah Vicent