Grid Problem

[FoxKid]

I am having a grid on a form where I am getting data through sql and I have written recordsource as :

SELECT constructi,width,SPACE(12) as code,SPACE(50) as fabricname,sum(order) as order,sum(issqty) as issqty,000000.000 as quantity FROM xpono WHERE ok=.t. into CURSOR xorder order by constructi,width group by constructi,width readwrite

Here in grid for column 7&8 I have assigned its width as 75.
But when this query run and data comes in the grid then these columns collapse and only 0 is seen in it. Why it is doing so. These column get resized to the width of the value of this field
please help


Thanks

 

[Mike Gagnon]

FoxKid

Take a look at faq184-1813 "How to avoid grid reconstruction".


Mike Gagnon

If you want to get the best response to a question, please check out FAQ184-2483 first.

 

[FoxKid]

Mike,
Its not working.

Please help

Thanks

 

[Mike Gagnon]

FoxKid

Its not working.

As the suggestion in the faq is a well known work around to the problem you describe, reponding "Its not working." is not really a very detailed response. When you set your record source to '' (no space) and do your sql and reset it to your cursor what do you get?



Mike Gagnon

If you want to get the best response to a question, please check out FAQ184-2483 first.

 

[FoxKid]

Mike,
In the refresh property of grid1 I have written :

this.recordsource=""
SELECT constructi,width,SPACE(12) as code,SPACE(50) as fabricname,sum(order) as order,sum(issqty) as issqty,000000.000 as quantity FROM xpono WHERE ok=.t. into CURSOR xorder order by constructi,width group by constructi,width readwrite
this.parent.parent.page2.grid1.recordsource="xorder"
DODEFAULT()

In grid1.recordsourcetype I have written 1-Alias.

But again when I run the form the last 2 columns i.e. column6 & 7 get collapsed. It doesn't show any error.

Thanks

 

[FoxDevil]

HI,
In my opinion
----------------------------------------------
thisform.grdDetails.RecordSource="xorder"
thisform.grdDetails.RecordSourceType = 1
thisform.grdDetails.column1.ControlSource='xorder.<desired_field>'
thisform.grdDetails.column2.ControlSource='xorder.<desired_field>'
thisform.grdDetails.column3.ControlSource='xorder.<desired_field>'
thisform.grdDetails.Refresh
thisform.grdDetails.SetFocus

------------
i have done this and it is working. here u can mention the controlsource property of all the columns. 1 thing will help u more, which is, add a Method in form. and name it
like &quot;GrdRefresh&quot; then any time u need to construct the grid, u can use that method of the form.

 

[FoxKid]

FoxDevil,
I have tried the way you have suggested, but again the problem resists as it was earlier.

Please help

Thanks

 

[Mike Gagnon]

FoxKid

SELECT constructi,width,SPACE(12) as code,SPACE(50) as fabricname,sum(order) as order,sum(issqty) as issqty,000000.000 as quantity FROM xpono WHERE ok=.t. into CURSOR xorder order by constructi,width group by constructi,width readwrite

First, you say &quot;Here in grid for column 7&8 I have assigned its width as 75.&quot;, but yet your sql only contains 7 fields?



Mike Gagnon

If you want to get the best response to a question, please check out FAQ184-2483 first.

 

[FoxKid]

Sorry mike it was my typing error. Actually it is 6 & 7th column.

 

[Mike Gagnon]

FoxKid

Sorry I cannot duplicate your problem. Here is an example by code, copy it in a program and run it. If you click on the reset grid button, it recreates a new cursor and resets the grid, but the grid does not loose its original state.:

Create Cursor myCursor (Name c(20),address c(20))
Insert Into myCursor (Name, address) Values ("Mike","123")
Insert Into myCursor (Name, address) Values ("Paul","321")
Insert Into myCursor (Name, address) Values ("John","345")
Insert Into myCursor (Name, address) Values ("Ringo","567")
Insert Into myCursor (Name, address) Values ("Georges","987")
Go Top
Select *,00000000.00 As Number From myCursor Into Cursor myCursor2
Public oForm
oForm = Createobject("form")
oForm.Width = 450
oForm.AddObject("grid1","grid")
oForm.AddObject("command1","command1")
oForm.Grid1.Width =420
oForm.Grid1.Visible = .T.
oForm.Show()
Define Class command1 As CommandButton
	Visible = .T.
	top = 220
	left =200
	caption = "Reset grid"
	Procedure Click
	Thisform.Grid1.RecordSource=''
	Select * From myCursor WHERE VAL(address)>300 Into Cursor myCursor3
	Thisform.Grid1.RecordSource = "myCursor3"
	endproc
Enddefine

Mike Gagnon

If you want to get the best response to a question, please check out FAQ184-2483 first.

 

[FoxKid]

Thanks to all of you.
Now its working well. I just deleted my previous grid and again recreated it, and now it works well.

Thank you once again

 

[MarciaAkins]

Hello.

As Mike has told you, grid reconstruction is a very common phenomenon.

One way to avoid having the grid turn into a blank grey blob is to set its RecordSource to an empty string before running the SELECT and then resetting it afterward. Although this will work in the simplest of cases, it is not a solution I recommend. While it will keep your grid from losing its mind, the grid's columns still lose their ControlSources and any embedded controls. So, this works if your grid uses base class headers, base class text boxes, and displays the fields from the cursor in exactly the same order as they are SELECTed. Otherwise, you have to write a lot more code to restore all the things that get lost when the grid is re-initialized.

What I like to do is what I call a &quot;safe select&quot;. Use code like this to do the select into a temporary cursor, ZAP the grid's RecordSOurce, and then append from the temporary cursor. This works because ZAPing the grid's RecordSOurce does not close it.

WITH Thisform.Grid1
SELECT ( .RecordSource )
ZAP
SELECT Yada, Nada, Blah FROm SomeTable WHERE SomeCondition INTO CURSOR junk NOFILTER
SELECT ( .RecordSource )
APPEND FROM DBF( 'junk' )
USE IN junk
GO TOP IN ( .RecordSOurce )
.Refresh()
ENDWITH

-- Marcia G. Akins