Front End

[accessewbie]

Okay I have split my database into FE and BE (after several attempts before getting it right). I have the FE on the server but am told that it WILL become corrupt. There are several locations and several hundred people so I can't possibly put a shortcut on each persons pc. What do I do? I have heard about Auto FE Updater - which will ensure each user has the latest FE - how do I do this? Please keep in mind I new to this so any step by step instructions available would greatly be appreciated. Thanks in advance for your patience as I am sure I will have more questions.

 

[PHV]

This topic has been covered many times already.
Have you searched the access fora ?

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ222-2244

 

[accessewbie]

Reply - I've done a search and found tid bits but nothing in full. Is there a site you could recommend? Looking through these posts related to FE/BE some people have more access experience and a few steps ahead of where I am. If not thanks anyways - I'll keep on searching.

 

[LarryDeLaruelle]

This may not be the solution you are looking for, but the method I use to push new front ends out to the users is a DOS batch file and a text file.

The name of the text file is changed (incremented) each time a new revision is available. The batch file compares the name of the text file on the user's system and, if different than the text file name in the batch file, copies both the new front end and text file to the users system.

My apologies to the originator of this process; I got this from a post here at Tek-Tips and am sorry to say I don't remember the name of the person who posted it. In any case, if this works for you, the credit goes to the earlier poster:

Here is the batch file (my file name is TCCAdmits2K.bat which merely identifies the agency unit, database name and Access version):

::Echo Off
::
:: This batch file is intended to push the Database Frontend for TCCAdmits2K
:: out to the user's local machine.
:: The batch file compares the local copy of the revision history (text file) to
:: the the copy on the server. If the file names match, the application starts;
:: if the file names do not match, the new version of the database is copied
:: to the user's local machine, older versions of the revision history are deleted
:: and a copy of the latest revision history is copied to the local machine.
::
:: PROCESS: After completion of modifications to a database, the revision
:: history text file is updated to identify the changes and the revision history
:: file name is changed to reflect a new version number.
::
:: In the 'if exist' line below, change the file name to match the new version
:: number on the revision history (i.e., TCCAdmits2K.1.4.txt is changed to
:: TCCAdmits2K.1.5.txt).
::
:: This writes an entry to a simple text file that identifies the Database, User and date/time the app was started.
xecho Admit2K.bat %USERNAME% #j:#i #n/#x/#y>> G:\Database\Logs\bat.txt

:: Will create the necessary directories on the user system if needed (i.e., the first time they run the batch file).
C:
CD\
MkDir FrontEnds
CD FrontEnds
MkDir TCCAdmits
CD TCCAdmits

::====
:: Copy the New Front End if necessary

if exist "TCCAdmit2K.05.03.txt" goto RUNIT

ECHO Copying new version of database. Please wait.
copy "G:\Database\TCC Admit Database\Admit2K.mdb"
del /q *.txt
Copy "G:\Database\TCC Admit Database\*.txt"

::====
:: Start the application


:RUNIT
if exist "C:\Program Files\Microsoft Office\Office\MSAccess.exe" goto RUNIT-C

if exist "D:\Program Files\Microsoft Office\Office\MSAccess.exe" goto RUNIT-D

if exist "E:\Program Files\Microsoft Office\Office\MSAccess.exe" goto RUNIT-E

:RUNIT-C
"C:\Program Files\Microsoft Office\Office\MSAccess.exe" "C:\FrontEnds\TCCAdmits\Admit2K.mdb" /wrkgrp "G:\Database\KidCare\FCC007.mdw"
goto EXITBAT

:RUNIT-D

"D:\Program Files\Microsoft Office\Office\MSAccess.exe" "C:\FrontEnds\TCCAdmits\Admit2K.mdb" /wrkgrp "G:\Database\KidCare\FCC007.mdw"
goto EXITBAT

:RUNIT-E

"E:\Program Files\Microsoft Office\Office\MSAccess.exe" "C:\FrontEnds\TCCAdmits\Admit2K.mdb" /wrkgrp "G:\Database\KidCare\FCC007.mdw"
goto EXITBAT

:EXITBAT

Couple of points.

The way I use it, the batch file is in the same directory/folder on the server as the database app. I put a shortcut on the user's system pointing to the batch file.

When I have made mods to the app and am ready to send it out to the users, I change the name of the text file by incrementing the second number by one (I also enter any appropriate modification notes in that file) and then I open the batch file in Edit and change the referenced text file name to what I just changed the actual text file name to. This may sound confusing but it really is just a one-two step process. The next time the user runs the batch file, the new version will be downloaded to their local machine.

The RUNIT code was necessary for us since different users will have the Access app stored on different drives; this code accomodates for those differences.

The text file can be used to maintain a modification history which can be useful information.

The line starting with 'xecho' is simply a command to write an entry to a text file that identifies who is running the app, what the app is (the text file is used to track all users on all apps) and the date/time they start the app. If you do not want/need this, simply delete the line.

If this is what you are looking for and need any help with implementation, feel free to e-mail me direct.

Larry De Laruelle