Form to be placed in the lower right

[fcjm]

Does anyone know how could I place my form in the lower right of the window without covering the taskbar? Even if user changes the display settings, the same thing will happen. Any ideas? Thanks.

 

[LazyMe]

I don't know if there's an easier method, but you get all you need to know about the size, visibility and location of the taskbar:

Check out this link:

http://msdn.microsoft.com/archive/default.asp?url=/archive/en-us/dnarvbtips/html/msdn_msdn143.asp

Greetings,
Rick

 

[strongm]

Add a SysInfo control to your form, and then something like this should work:

Private Sub Form_Load()
Reposition Me
End Sub

Private Sub SysInfo1_DisplayChanged()
Reposition Me

End Sub

Private Sub Reposition(frmTarget As Form)
frmTarget.Top = SysInfo1.WorkAreaHeight + SysInfo1.WorkAreaTop - frmTarget.Height
frmTarget.Left = SysInfo1.WorkAreaWidth + SysInfo1.WorkAreaLeft - frmTarget.Width
End Sub

 

[fcjm]

Thanks for the suggestions.

The suggestion of strongm is correct. But is there another way where I don't need to use control like using API?

 

[strongm]

The link that LazyMe provides contains API code.

Having said that, why is an API solution your preference?

 

[LazyMe]

Yeah, I'm also wondering about that. Why going through all the "trouble" with API calls when it's as easy as strongm suggests? Since it's all about positioning a Form, you already have a container for the control....
Greetings,
Rick

 

[fcjm]

The program I'm creating will be given install in other computers. It's easier to install a program if it's less control and it's size is lesser compare to an application with so many controls. Thanks for your answers, I found a code which solve my problem. Here it is:

Option Explicit

Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Private Declare Function SystemParametersInfo Lib "user32" Alias _
"SystemParametersInfoA" (ByVal uAction As Long, _
ByVal uParam As Long, ByRef lpvParam As RECT, _
ByVal fuWinIni As Long) As Long

Private Const SPI_GETWORKAREA = 48

Private Sub Form_Load()

Dim r As RECT

SystemParametersInfo SPI_GETWORKAREA, 0, r, 0

With Me
.Move r.Right * Screen.TwipsPerPixelX - .Width, _
r.Bottom * Screen.TwipsPerPixelY - .Height
End With

End Sub