DataView RowFilter issue

[Ruffnekk]

I'm quit unfamiliar with ASP.NET applications and I've been struggling for some time to get something done:

I have a webform with a TextBox, CommandButton and a DataGrid. When I type a search term into the textbox and click the commandbutton, I want the DataGrid to show me the results.

Here's what I coded, but doesn't seem to work properly:

Private Sub Page_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
  If Not Page.IsPostBack Then
    'plDB is a web service that handles database interaction
    'I verified that the dataset DsTotal1 is properly filled
    plDB.FillDataset(DsTotal1)
    DataView1 = DsTotal1.Tables(0).DefaultView
    DataView1.RowFilter = "TypeNr = 'SV3111'"
    dtList.DataBind()
    'So far so good, the DataView1 has a count of 2, 
    'corresponding to the number of matches and the
    'DataGrid displays the data properly
  End If
End Sub

'Now for the event fired when I click the button
Private Sub btnSearchType_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSearchType.Click
  'Exit when nothing is entered
  If txtTypeNumber.Text.Length = 0 Then Exit Sub
  'Specify a new filtered selection
  '(to be replaced by the text in the textbox)
  DataView1.RowFilter = "TypeNr = 'SV3115'"
  'Bind the data to the grid again
  dtList.DataBind()
End Sub

After clicking the button, the headers show, but the datagrid shows no records. I put a break before the DataBind call and the dataview appeared to be empty, count of 0 and the DataViewManager object is Nothing.

Obviously I'm doing something wrong with the DataView, but what?

Thanks a lot for your response!

Regards, Ruffnekk
---
Is it my imagination or do buffalo wings taste just like chicken?

 

[ca8msm]

Where do you set the DataSource for dtList (I'm guessing you've only posted parts of your code to try and highlight the problem, but it may be useful to see it all if it isn't too large)?


____________________________________________________________

Need help finding an answer?

Try the Search Facility or read FAQ222-2244 on how to get better results.

 

[Ruffnekk]

I set the datasource at designtime to DataView1, so that really was all the code I have so far to try it out.

In the meantime I have a working version, I created the dataset and dataview at runtime instead of design time:

Protected plDB As New PrijslijstDB.PrijslijstDB
Protected DsTotal1 As DataSet
Protected DataView1 As DataView

Private Sub Page_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
  DsTotal1 = New DataSet
  plDB.FillDataset(DsTotal1)
  DataView1 = New DataView(DsTotal1.Tables(0))
  dtList.DataSource = DataView1
  dtList.DataKeyField = "ID"

  If Not Page.IsPostBack Then
    DataView1.RowFilter = "TypeNr = 'SV3111'"
    dtList.DataBind()
  End If
End Sub

Private Sub btnSearchType_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSearchType.Click
  If txtTypeNumber.Text.Length = 0 Then Exit Sub

  DataView1.RowFilter = "TypeNr = '" & txtTypeNumber.Text & "'"
  dtList.DataBind()
End Sub

Thanks a lot for your reply! And any suggestions or code optimizations are very welcome!

Regards, Ruffnekk
---
Is it my imagination or do buffalo wings taste just like chicken?

 

[ca8msm]

I've just created a simple example to demonstrate what I think you are trying to do. You just need a new form with a Button named Button1 and something that can be bound to named dtList (I used a GridView control but it doesn't have to be):

    Dim ds As New DataSet
    Dim dt As New DataTable
    Dim dr As DataRow
    Dim dv As New DataView

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

        ' Fill a DataSet with 10 sample records
        CreateRandomRecords()

        ' If it is NOT a postback show the 7th record
        If Not Page.IsPostBack Then
            dv = ds.Tables(0).DefaultView
            dv.RowFilter = "Column1 = '7'"
            dtList.DataSource = dv
            dtList.DataBind()
        End If
    End Sub

    Protected Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button1.Click
        ' The button has been clicked so a postback occurs, it skips the code
        ' to show the 7th record, and then fires this event
        dv = ds.Tables(0).DefaultView
        dv.RowFilter = "Column1 = '2'"
        dtList.DataSource = dv
        dtList.DataBind()
    End Sub

    Sub CreateRandomRecords()
        dt.Columns.Add("Column1")
        For i As Integer = 1 To 10
            dr = dt.NewRow
            dr(0) = i
            dt.Rows.Add(dr)
        Next
        ds.Tables.Add(dt)
    End Sub

Is that what you are trying to do?


____________________________________________________________

Need help finding an answer?

Try the Search Facility or read FAQ222-2244 on how to get better results.

 

[Ruffnekk]

Yes it is, thanks a lot! I got it working with design time added dataset and dataview as well now (and therefore being able to design my DataGrid at design time as well). One of the main problems was that I filled the dataset INSIDE the If Not Page.IsPostBack statement.

Regards, Ruffnekk
---
Is it my imagination or do buffalo wings taste just like chicken?