Creating Control during runtime

[Haheehi]

How do i create a command button dunring runtime

I tried:
dim myCmd as commandbutton
set myCmd = new commandbutton



But i get an error. [sig][/sig]

 

[biba]

to create a control array called cmdBtn (you have to have one control button on the form at design time)
do this:

Dim j As Integer

For j = 1 to 9
Load cmdBtn(j)
Next j

I hope this helps.

Billie

 

[biba]

I forgot to tell you that you have to make space when you load them.

Dim leftPos As Integer, j As Integer
Dim buttonWidth As Integer

'Get the size and position of the first command button
leftPos = cmdBtn(0).Left 'this is the one you created at
' design time
buttonWidth = cmdBtn(0).Width

'Position the other buttons and make them visible. You need
'this because when they are loaded at run time their visible
'property is set to false

For j = 1 To 9
Load cmdBtn(j)
leftPos = leftPos + buttonWidth + 30
cmdBtn(j).Left = leftPos
cmdBtn(j).Visible = True
Next j

Good luck

 

[JpPhysics]

What if I wanted to load a label instead. I tried this, but it didn't work for labels.

 

[JohnYingling]

You must have a label with INDEX=0 at design time i.e. a Control Array of one label. Then you can load new versions.

http://www.VBResizer.com

Generate Forms/Controls Resizing/Tabbing Class

http://www.VBCompare.com

Compare Code (Text)

http://www.VBSortGen.com

Generate Sort Class in VB or VBScript

 

[JustinEzequiel]

or you could try something like...

Option Explicit

Private WithEvents moMyLabel As Label

Private Sub Command1_Click()
  Set moMyLabel = Controls.Add("VB.Label", "moMyLabel")
  moMyLabel.AutoSize = True
  moMyLabel.Caption = "Click here!"
  moMyLabel.Move (ScaleWidth - moMyLabel.Width) / 2, 0
  moMyLabel.Visible = True
End Sub

Private Sub moMyLabel_Click()
  MsgBox "You clicked me!"
End Sub