Changing DB Properties by code in Access 2002

[Shake412]

in Access 97 I used to be able to programmatically view and change any DB property, such as “AppTitle” or “AppIcon” using the properties collection of the database object. I don’t appear to be able to do this with the ADO equivalent connection object.

What is the Access 2002/ADO equivalent to the following:-

Set db = CurrentProject.Connection
db.Properties(strPropName) = varPropValue

Thanks

 

[LittleSmudge]

It's very simple - but it took a lot of working out
In the line where you had

Dim db As Database

you replace it with

Dim db As Object

Then recompile and Run !


Here is the full code that I have just snatched from an active Access 2000 db in use here

Sub SetStartupProperties()
    ChangeProperty "StartupForm", dbtext, "frmStartUp"
    ChangeProperty "StartupShowDBWindow", dbboolean, True   
    ChangeProperty "StartupShowStatusBar", dbboolean, True
    ChangeProperty "AllowBuiltinToolbars", dbboolean, True 
    ChangeProperty "AllowFullMenus", dbboolean, True   
    ChangeProperty "AllowBreakIntoCode", dbboolean, True   
    ChangeProperty "AllowSpecialKeys", dbboolean, True
    ChangeProperty "AllowBypassKey", dbboolean, True      
    MsgBox "DB Properties Have Been Created..."

End Sub

' enable 'SHIFT' key on startup for developer's
Function SetBypassForDeveloper()
    ChangeProperty "AllowBypassKey", dbboolean, True
End Function

' disable 'SHIFT' key on startup for other user's
Function SetBypassForOthers()
    ChangeProperty "AllowBypassKey", dbboolean, False
End Function

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo Change_Err
    dbs.Properties(strPropName) = varPropValue
    ChangeProperty = True

Change_Bye:
    Exit Function

Change_Err:
    If Err = conPropNotFoundError Then ' Property not found.
        Set prp = dbs.CreateProperty(strPropName, _
            varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ' Unknown error.
        ChangeProperty = False
        Resume Change_Bye
    End If
End Function

'ope-that-'elps




G LS
spsinkNOJUNK@yahoo.co.uk
Remove the NOJUNK to use.

 

[VBslammer]

Actually, Access versions 2000 and up do not reference the DAO library by default, which is what is causing your problem.

Just reference the DAO library (Tools-->References-->Check Microsoft DAO 3.6 Object Library) and your Access 97 code will run fine. This functionality has not changed.

VBSlammer

Unemployed in Houston, Texas

 

[Shake412]

Cheers for that, it works a treat.