Built the database...What is next?

[Di7bash]

Hello Everyone,

I just finished building my database and i have to install it on a PC. my problem is how to remove access tool bars and menues so that the only thing that appears when you open the databse is the login screen?
I don't want the user of the database to be able to go to design view and change the design of the forms or the reports. I want the user to see and be able to interact with the login form and the switchboard.
I wanna also know how can i install the databse on the PC. do i just copy it and paste it or is there any way else?

I hope you understand what i want.

Thanks in advance for your much appreciated help.

 

[sdk]

hi

just copy it to where your user community can see it - remember you only want one instance of the database for the users to share, not (or likely not) a seperate database each. There is no need to install as such, unless you are using Runtime.

Most database properties are available through Tools >> Options... - you can setup most your requirements there.

More thorough props can be setup calling the code below, but if that is not to your liking, stick with the options. I am not sure, but I don't think these are avail through macros.

Cheers

S

Function SetStartupProperties()
'NOTE mdlUtilities.DB_TEST_MODE is a const bool
Const DB_Text As Long = 10
Const DB_Boolean As Long = 1
Const frmStartup As String = "frmSubjectsMainForm"

ChangeProperty "StartupForm", DB_Text, frmStartup
ChangeProperty "StartupShowDBWindow", DB_Boolean, False
ChangeProperty "StartupShowStatusBar", DB_Boolean, True
ChangeProperty "AllowBuiltinToolbars", DB_Boolean, mdlUtilities.DB_TEST_MODE
ChangeProperty "AllowFullMenus", DB_Boolean, mdlUtilities.DB_TEST_MODE
ChangeProperty "AllowBreakIntoCode", DB_Boolean, mdlUtilities.DB_TEST_MODE
ChangeProperty "AllowSpecialKeys", DB_Boolean, mdlUtilities.DB_TEST_MODE
ChangeProperty "AllowBypassKey", DB_Boolean, mdlUtilities.DB_TEST_MODE

End Function

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
Dim dbs As Object, prp As Variant
Const conPropNotFoundError = 3270

Set dbs = CurrentDb
On Error GoTo Change_Err
dbs.Properties(strPropName) = varPropValue
ChangeProperty = True

Change_Bye:
Exit Function

Change_Err:
If Err = conPropNotFoundError Then ' Property not found.
Set prp = dbs.CreateProperty(strPropName, _
varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
' Unknown error.
ChangeProperty = False
Resume Change_Bye
End If
End Function

 

[Iashia06]

Hi.

Before installing it on the user's pc, right-click on the database window, and choose startup. Here you can choose what form should be active on startup. You can also choose to hide the database window so that users can't get to the tables, reports, etc.

I hope this helps.

 

[Di7bash]

That was really helpfull
Thanks alot

 

[fneily]

From your question, let me ask - did you Normalize your tables? Set up relationships, maybe referential integrity?