awk -- get last field 1

[gaspence]

Is there a way I can use 'awk' to return the last field of a query. For instance, lets say I have a file named 'abc def.txt' (Note: there is a white space between 'abc' and 'def.txt'). When I run the following command it does not return the complete file name for files with spaces in their name...

ls -lTp | awk '{print $6, $7, $9, $10}'

So the result for filename 'abc def.txt' would be...

12 Jan 2005 abc

Whereas a file named '123.txt' lists as...

12 Jan 2005 123.txt

Thanks all.

gaspence

 

[futurelet]

ls -lTp | awk '{print $6, $7, $9, substr($0,X)}'

where X is the column in which the filename starts.

 

[PHV]

ls -lTp | awk '{s=$0;sub(".*"$10,$10,s);print $6, $7, $9, s}'

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ222-2244

 

[futurelet]

PHV, your solution fails when the filename is [tt]"foo foo"[/tt].

 

[PHV]

Good point futurelet.
ls -lTp | awk '{s=$0;sub(".*"$9" *"$10,$10,s);print $6, $7, $9, s}'

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ222-2244

 

[futurelet]

PHV, your new solution fails with this line:
[tt]
-rw-r--r-- 3 oilc aaaaa 945 12 Jan xxx 2005 foo 2005 foo
[/tt]

This looks like an opportunity for me to use the function "shatter".

BEGIN { ORS="" }
{ shatter($0,f,"[ \t]+")
  print $6, $7, $9 " "
  for (i=19;i in f;i++)
    print f[i]
  print "\n"
}
# Unlike split(), builds array that contains the
# matching as well as the nonmatching substrings.
function shatter( s, array, re,    M )
{ delete array;   M = sprintf( "%c", 1 )
  if ( gsub( re, M "&" M, s  ) )
    return split( s, array, M )
  array[1] = s;   return 1
}

 

[vgersh99]

FYI AWK Compatibility:
you only 'delete array' in one swoop with either 'gawk' or POSIX awk [/usr/xpg4/bin/awk] (at least on Solaris).

vlad
+----------------------------+
| #include<disclaimer.h> |
+----------------------------+

 

[futurelet]

you only 'delete array' in one swoop with either 'gawk' or POSIX awk [/usr/xpg4/bin/awk] (at least on Solaris).

Solaris seems quite brain-damaged.

[tt]delete array[/tt] works in mawk.

What is most important, it works in Brian Kernighan's "One True Awk". However, that use of "delete" is really not essential, is it? Wouldn't this do the same thing?

split( "", array )

 

[vgersh99]

good point, futurelet!

vlad
+----------------------------+
| #include<disclaimer.h> |
+----------------------------+

 

[kHz]

Solaris seems quite brain-damaged

I agree!

 

[futurelet]

Vlad, taking into account your point that not all awks have a proper "delete", and since you agree that "split" can do the job, I'm changing the function. (And I realized that the "delete array" isn't needed if the "gsub" succeeds.)

# Unlike split(), builds array that contains the
# matching as well as the nonmatching substrings.
function shatter( s, array, re,    M )
{ M = sprintf( "%c", 1 )
  if ( gsub( re, M "&" M, s  ) )
    return split( s, array, M )
  split( "", array);   array[1] = s
  return 1
}

I think "shatter" is a rather nifty tool. I'm going to seize every chance to use it!

 

[gaspence]

Thanks everybody, fantastic. PHV's solution worked best for my case.

 

[Ygor]

I know it's not awk, but...

ls -l | tr -s ' ' | cut -d ' ' -f6,7,9-

 

[futurelet]

tr -s ' '

Doesnt' this change the filename

foo    bar.txt

to

foo bar.txt

?

 

[dchoulette]

Just empty the unwanted fields then print:

ls -lTp | awk '{$1="";$2="";$3="";$4="";$5="";$8=""; print}'

--------------------

Denis

 

[gaspence]

Thanks for the tips on emptying the fields and using 'ls' to return a result. But as "futurelet" mentioned, double(+) spaced filenames are still coming out as a single spaced name...

foo     bar ## has 5 spaces
prints as...
foo bar ## has one space

 

[futurelet]

double(+) spaced filenames are still coming out as a single spaced name...

Yes. That is precisely why I rejected the method of emptying the fields. When an assignment is made to a field, $0 is rebuilt by joining the fields with OFS between.

 

[futurelet]

This seeemingly simple problem turned out to be rather thorny.

My previous solution was correct, but perhaps too verbose. In this one, we first build a regular expression that matches everything up to the filename.

BEGIN { OFS="[^ \\t]+[ \\t]+"
  $0 = "";   $10 = ""
  regexp = $0;   OFS = FS
}

{ match( $0, regexp )
  fname = substr( $0, RSTART + RLENGTH )
  print $6, $7, $9, fname
}

 

[gaspence]

Thanks 'futurelet', and everyone else for the great answers and suggestions. I have learned a few new handy tricks just from this brief thread. You folks are another one of the reasons I love Unix ;- }

I'll be clicking the google ads in hope of supporting this fine site.

gaspence