Arcserve 2000 Reports - where's the database?

[PWD]

I need to create a report that is just a bit different from the standard reports you can get from ArcServe 2000 - I need backup info of files and disk space per drive per server but on one line per server and all on one page!!. I assume the standard reports must use a database to create them from. I may be dumb but I can find that database so I can use it in Microsoft Access. Does anyone know what it's called and where it's hiding. I've contacted Computer Associates but they only tell me to use their reports.

 

[speshalyst]

HI,

The ARcserve database is not just one file... like a *.edb
or *.dat..

it is a collection of files..
I believe ARCserve surfs thru several of these files in the
ARcserve\database folder to generate the reports..

i really do not know how u r planning to get ACCEss to work with these files..

however this folder is the arcserve db ..

cheers
speshalyst So it Shall be Written!
So it Shall be Done!!

 

[mspope]

The standard installation of ARCserve uses a Velosis database (Formerly Raima, now Birdstep). You can get an ODBC plug-in or a report creator for this DB but it'll cost you some ca$h. I don't have any links you'll have to hunt around the web for them.

Another alternative it to use a Microsoft SQL server as your database - an installation option. Then you can do everything you need. (I think you can convert your existing install to MS SQL but I'm not sure.)

Barring the first two alternatives, your final option is to process the job log files. The collection of text logs files in the ARCserve/logs directory. You'll need a scriptable text editor or good programming language knowledge.

 

[PWD]

Wow, thanks guys. Guess I wasn't being dumb, after all. I had managed to import the log file in to Access but it didn't give me all the info I need. I'm gonna go sufin' and see what's out there. Thank again.

Des.

 

[mspope]

Let me know if you find anything.

 

[darren77uk]

Hi guys I am having a similar problem, I want to pull of a report from ArcServe which relates to successful, incomplete and failed backups, is there anyway I can do this centrally, there are over 300 servers running ArcServe, different versions etc, I want to produce a trend graph for the performance of the backups. I would be really thankful if someone can assist me, at the moment it is being done manually and is very time consuming.

I look forward to hearing from someone.

Cheers,
Darren

 

[PWD]

I didn't find anything, unfortunately; ArcServe seems to be tied in with Crystal reports. I just gave up.

Des.

 

[darren77uk]

So basically its impossible to do a report on the trends of the machines? What kinda report are you trying to generate and from how many machines?

 

[mcse924]

There is a 3rd party product called Arcserve Distiller which may do what you are seeking (no, I do not work for these guys). I have tried the FREE demo and it does an excellent job of creating more logical, cohesive job reports than plain old Arcserve reports. Of course, if you like it, you must pony up some $$$.

check it out at

http://www.arclog.com/index.htm

Carpe diem, procrastination is the thief of time...

 

[darren77uk]

Does it collate reports from different machines or is it reports from one specific machine? I want 1 report that gives info about all 300 servers that we run ArcServe on and produce a trend. Is this possible with what you are using?

 

[mspope]

This would be allot of work to deploy across 300 servers, but here's the solution I came up with for my site.

I run a single ARCserve 2000 server with 5 different jobs into a 4 head 26 slot library on Windows XP Pro. I came up with the following batch program to find the jobs log number. I then pass the information to a kedit script to parse the log file. After that I use BLAT to e-mail the results to me. I've included the portion here that gets the log file name. Due to batch enhancements in XP this script may need modifying to run in 2K. It won't work in on NT 4.0 without modification.

You call the script from pre/post option in your job script using the job description. For example, I have a job with a description of "J1-Daily Differential". In it's post job options I call the script:
E:\batch_jobs\Arclog.bat J1-Daily

(My other jobs all have unique descriptions).

The batch job searches the 00000001.qsd directory for the job file containing the description. The name of the file found matches the job number in the queue. Using this, the activity log is searched for the last "Job starting" entry matching JOB={job number}. From this line it gets the log file number.

P.S. You will need to change QueueDir and ArcLogDir below.

==Arclog.bat================================================
@Echo off
SetLocal

:: Mark-Simon Pope - 2003
:: Setup variables

Set SearchString=%1

Set curdir=%~dp0

Set QueueDir=E:\ARCserve\00000001.qsd\*.job
Set ArcLogDir=e:\ARCserve\log
Set WorkDir=%CurDir%

Set ActivityLog=%ARCLogDir%\arcserve.log

Set TempFile=%workdir%\arctemp.txt
Set TempFile2=%workdir%\arctemp2.txt


:: Find the queue file that contains the job descripton
:: This will give us the job number.

for /F "tokens=1-2 delims=." %%a in ('FindStr /M "%SearchString%" %QueueDir%') Do (
Set QueueNumber=%%b
)

:: Parse the filename out of the full pathname

Set QueueNumber=%QueueNumber:\= %

For %%a in (%QueueNumber%) Do (
Set QueueNumber=%%a
)

:: Remove leading zeros

:loop
IF "%QueueNumber:~0,1%"=="0" (
set QueueNumber=%QueueNumber:~1%
goto loop
)

:: Search the activity log for all "JOB=x" and filter out only start entries

set SearchString=JOB=%QueueNumber%)
Find "%SearchString%" %ActivityLog% > %TempFile%
Find "Start Backup Operation" %Tempfile% > %TempFile2%

:: The last entry in the temp file will have our log date and Log number

For /F "Tokens=1-3" %%a in (%TempFile2%) Do (
Set LogDate=%%a
Set LogNumber=%%c
)

:: Remove the temporary files

Del %tempfile%
Del %TempFile2%

:: build the proper filename from the log number

Set LogNumber=000000%LogNumber%
Set LogNumber=%LogNumber:~-7%
Set LogFile=%ARClogdir%\J%LogNumber%.log

Echo The log file for this job is %LogFile% dated %LogDate%

:Eof
EndLocal
==Arclog.bat================================================

 

[darren77uk]

So I would have to run this on each machine or just one machine to pull the logs? I use a XP machine but the servers are a combination of NT/2000. So as you are saying I would need to modify the batch file.

 

[mcse924]

Regarding Arcserve Distiller, you should TRY IT for FREE and see if it fits what you want to do.

They are coming out with an "Enterprise" version but not sure how that works or when. Check out the site...

Carpe diem, procrastination is the thief of time...

 

[mspope]

You could run it remotely if you change QueueDir=\\{machinename}\ARCserve$\00000001.qsd\*.job
and ArcLogDir=\\{MachineName}\ARCserve$\log

But the script processes the activity log - and that could lead to allot of network traffic.

Actually, It didn't much work to run on NT 4.0 - this version works but it can only give you the log number not the complete log name: (I didn't have much time to fiddle with it to get a complete log name).

==ArclogNT4.bat============================================
@Echo off
SetLocal

:: Mark-Simon Pope - 2003
:: Setup variables

Set SearchString=%1

Set curdir=%~dp0

Set QueueDir=\\{MachineName}\ARCserve$\00000001.qsd\*.job
Set ArcLogDir=\\{MachineName}\ARCserve$\log
Set WorkDir=%CurDir%

Set ActivityLog=%ARCLogDir%\arcserve.log

Set TempFile=%workdir%\arctemp.txt
Set TempFile2=%workdir%\arctemp2.txt


:: Find the queue file that contains the job descripton
:: This will give us the job number.

FindStr /M "%SearchString%" %QueueDir% > %TempFile%
for /F "tokens=1-2 delims=." %%a in ('Type %TempFile%') Do (
Set QueueNumber=%%b
)

:: Parse the filename out of the full pathname

Set QueueNumber=%QueueNumber:\= %

For %%a in (%QueueNumber%) Do (
Set QueueNumber=%%a
)


:: Remove leading zeros

:loop
IF "%QueueNumber:~0,1%"=="0" (
set QueueNumber=%QueueNumber:~1%
goto loop
)

:: Search the activity log for all "JOB=x" and filter out only start entries

set SearchString=JOB=%QueueNumber%)
Find "%SearchString%" %ActivityLog% > %TempFile%
Find "Start Backup Operation" %Tempfile% > %TempFile2%

:: The last entry in the temp file will have our log date and Log number

For /F "Tokens=1-3" %%a in (%TempFile2%) Do (
Set LogDate=%%a
Set LogNumber=%%c
)

:: Remove the temporary files

Del %tempfile%
Del %TempFile2%

Echo The log file number for this job is %LogNumber%

:Eof
EndLocal