ActiveX Comp?????

[mission2java]

I created a crystal viewer (in vb) to allow end users to view crystal reports. On anyone's machine who has a copy of crystal reports it works fine. But if I install my package (my viewer) on someone who does not have crystal the report doesnt seem to come up. My application works fine..but its when the end user tries to open a crystal report from the application they get the following error message:

"ActiveX component cant create object. Error #429."

Has anyone ever experienced this? If so what was the fix?

I included all the required dll's for crystal reports and registered craxdrt9.dll and crviewer9.dll...so what could possibly be the problem!!!!???

Thanks,
jon

 

[zemp]

With INNO you can set the flags so that the file is properly registered and place is in the system directory.

Here is an example of a script line I use for a Crystal component.

Source: "C:\Program Files\Seagate Software\Report Designer Component\craxdrt.dll"; DestDir: "{sys}"; Flags: restartreplace sharedfile regserver

Thanks and Good Luck!

zemp

 

[mission2java]

hmm not sure what you meant by it isnt in there.

zemp are you using win 2k and crystal 9?
If anyone is and IS using INO can you post the dependency file or the INO script that is generated for crystal reports to be viewed on any one elses machine besides my own.

Please I have struggled with this problem for 1 month straight.

Jon

 

[zemp]

I am using Win 2k and Crystal 8.5.

The INNO script is created by you. There is nothing that automatically generates it for you. There is a wizard that helps a bit.

I use the PDW to help find the files I need and use that list to help write my script. Then double check my references and componenets to ensure that I don't miss any. Sometimes I do and I have to add them to the script.

The INNO newsgroup archives can give some help with your script as well.

Thanks and Good Luck!

zemp

 

[mission2java]

The wizard does help.

Can you post what yours might look like so I grab the correct files. Ive used the P&D wizard...but Im still getting an error as stated in the beginning of this thread.

Jon

 

[zemp]

Here is an example of a small script file for a project that uses the crystal reports viewer. Hope it helps.

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

[Setup]
AppName=My Program
AppVerName=My Program 1.0.0
DefaultDirName={pf}\My Program
DisableDirPage=yes
DefaultGroupName=My Program
OutputBaseFilename=My Program setup
LicenseFile=D:\Projects\General\Licence agreement.rtf
WizardStyle=modern
; uncomment the following line if you want your installation to run on NT 3.51 too.
; MinVersion=4,3.51

[Tasks]
Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"; MinVersion: 4,4

[Files]
; begin VB system files
Source: "D:\VB Files\stdole2.tlb"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile regtypelib
Source: "D:\VB Files\msvbvm60.dll"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "D:\VB Files\oleaut32.dll"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "D:\VB Files\olepro32.dll"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: "D:\VB Files\asycfilt.dll"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile
Source: "D:\VB Files\comcat.dll"; DestDir: "{sys}"; Flags: restartreplace uninsneveruninstall sharedfile regserver
; end VB system files
; begin main exe and any dll's
Source: "D:\Projects\SPW Labels\VB Code\Myexe.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "D:\Projects\SPW Labels\VB Code\Read Me.htm"; DestDir: "{app}"; Flags: ignoreversion
; end main exe and any dll's
; begin crystal report files
Source: "C:\Program Files\Seagate Software\Shared\sscsdk80.dll"; DestDir: "{sys}"; Flags: restartreplace sharedfile
Source: "C:\Program Files\Seagate Software\Report Designer Component\craxddrt.dll"; DestDir: "{sys}"; Flags: restartreplace sharedfile regserver
Source: "C:\Program Files\Seagate Software\Report Designer Component\craxdrt.dll"; DestDir: "{sys}"; Flags: restartreplace sharedfile regserver
Source: "C:\Program Files\Seagate Software\Viewers\ActiveXViewer\crviewer.dll"; DestDir: "{sys}"; Flags: restartreplace sharedfile regserver
Source: "C:\WINNT\system32\p2smon.dll"; DestDir: "{sys}"; Flags: sharedfile
Source: "C:\WINNT\system32\Crpaig80.dll"; DestDir: "{sys}"
; end crystal report files

; START MDAC
Source: "D:\Downloads\Mdac 2.6\mdac_typ.exe"; DestDir: {tmp}; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0; Flags: ignoreversion
; END MDAC

[Icons]
Name: "{group}\My Program"; Filename: "{app}\Myexe.exe"
Name: "{group}\Read Me"; Filename: "{app}\Read Mel.htm"
Name: "{userdesktop}\My Program"; Filename: "{app}\Myexe.exe"; MinVersion: 4,4; Tasks: desktopicon
Name: "{group}\Uninstall My Program"; Filename: "{uninstallexe}"

[Run]
; START MDAC
Filename: {tmp}\mdac_typ.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0
; END MDAC

Thanks and Good Luck!

zemp

 

[mission2java]

Thanks for posting back.

I am going to make a copy of this thread.

Also I noticed you did something with MDAC...originally I was having the end user run MDAC install seperately.
Can I combine this into ino? If so will the gui install load up for MDAC? I dont want it to load up .. i want my app's application to basically do the install of mdac.

Possible?

Jon

 

[zemp]

The way I have it set up. MDAc is installed silently on the target machine. The end user does not need to do anything and it just looks like part of the install.

Thanks and Good Luck!

zemp

 

[mission2java]

Thats what I want to do...

IS that what the extra /q/t is for?

Jon

 

[zemp]

I assume it is. I copied those MDAC lines right from the INNO website.

Thanks and Good Luck!

zemp

 

[mission2java]

Cheater

Thanks,
Jon

 

[zemp]

Whatever works!!

They have answers to a lot of questions about how to do something with INNO. Take the time to look through the site.

Thanks and Good Luck!

zemp

 

[johnny00]

hey thanks zemp.. I researched the code prior to this post and successfully built an installer, I used everything except the download option.. which is neat, but not necessary for my app.. thank you guys for telling me about INNO, it is a great tool to add to my programming archive