Accessing document/pdf file from menu pad..

[MAliShah]

hi all,
I want to attach a document/pdf file as FAQ with my application. How can I access it from menu pad.
Thanks in Advance

 

[mm0000]

Add the following code to a program and addd it to your menu pad. Repalce 'Filename' with the actual file name and 'Filedirectory' with the directory in which the file is located.

lnVal=shellexec('Filename','FileDirectory','Open','')

do case
   case lnVal = 2
        =messagebox('File Open failed - Bad Association',16,'Error Message')
   case lnVal = 29
        =messagebox('File Open failed - Failure to load Application',16,'Error Message')
   case lnVal = 30
        =messagebox('File Open failed - Application is busy',16,'Error Message')
   case lnVal = 31
        =messagebox('File Open failed - The file you have tried to open has no Application Association',16,'Error Message')
endcase 

FUNCTION ShellExec
LPARAMETERS lcFileName, lcWorkDir, lcOperation, pcParameters
LOCAL pp, lcParam
pp = pCount()          
if pp>3                    
  lcParam = pcParameters   
else                       
  lcParam = ''
endif
lcWorkDir=IIF(type("lcWorkDir")="C",lcWorkDir,"")
lcOperation=IIF(type("lcOperation")="C",lcOperation,"Open")
DECLARE INTEGER ShellExecute ;    
    IN SHELL32.DLL ;    
    INTEGER nWinHandle,;
    STRING cOperation,;    
    STRING cFileName,;    
    STRING cParameters,;
    STRING cDirectory,;    
    INTEGER nShowWindow
RETURN ShellExecute(0,lcOperation,lcFilename,lcParam,lcWorkDir,1)
*ENDFUNC  ShellExecute

 

[MAliShah]

Thanks. The code worked. A big star for u