2003 Migration : Million dollar question

[patstone]

I am Migrating from Win2k/Exch2k on Domain A to Win2k3/Exch2k3 on Domain B

1.Use ADMT to migrate user account including SID history

2.Use Exchange Migration Wizard to migrate mailbox

3.All users in both domains have different secondary email addresses

4. To get mail flow between Domain A and Domain B I created two SMTP connectors with an address space of the secondary email addresses of each domain.

5. When I Migrate a user and mailbox and try to reply to "old" messages in the mailbox I get a NDR saying "The message could not be delivered because the recipient's destination email system is unknown or invalid".

6. When I check the Email properties of the user I'm trying to email I see that there is no information regarding email addresses.

 

[clancyfan]

Is the 'old' email message destined for an internal or external address?

 

[xmsre]

When you reply to old messages, it tries to send to the old Ex 5.5 DN. To resolve the issue, you need to add a custom X500 address to the user in AD.

http://support.microsoft.com/default.aspx?scid=kb;en-us;275134

For a user or two, that's fine. For thousands of users, you'll want a script. Something like:



' Quick and dirty script to add the old Exchange 5.5 DN as an X500 address to members of a nested group after they are
' exmerged to E2K/E2k3
' Author - fullbrij@comcast.com
' Creation date - 2/13/2004
'
'
' --------------------------------------------- SCRIPT CONFIGURATION --------------------------------------------------
'
'
' strGroupDN is the DN of the group you wish to apply the changes to. You can copy and paste the DN from ADSIEDIT
' strX500Container is the X500 container of the user
'
' If you need anything more complex than mailnickname as the prefix then you must modify the script
'
'
strAddrPrefix = "X500:"
strGroupDN = "CN=Test Group,OU=Information Technology,OU=Users,OU=Corporate Office,DC=child,DC=mycompany,DC=com"
strX500Container = "/o=organization/ou=site/cn=Recipients/cn="
'
'
' ----------------------------------------------- END CONFIGURATION ---------------------------------------------------
'
'
' create the dictionary and start stamping
set dicSeenGroupMember = CreateObject("Scripting.Dictionary")
StampMembers "LDAP://" & strGroupDN, dicSeenGroupMember
'
Function StampMembers (strGroupADsPath, dicSeenGroupMember)
'
set objGroup = GetObject(strGroupADsPath)
'
for each objMember In objGroup.Members
'
' if the member is a user then stamp it
'
if objMember.Class = "user" then
' add the X500 address to proxyaddresses
objMember.PutEx 3, "ProxyAddresses", Array(strAddrPrefix & strX500Container & objMember.mailnickname)
objMember.SetInfo
end if
'
' if it is a group then expand the group recursively
if objMember.Class = "group" then
'
if dicSeenGroupMember.Exists(objMember.ADsPath) then
' do nothing to avoid looping if we already stamped it
else
' add it to the dictionary and stamp it
dicSeenGroupMember.Add objMember.ADsPath, 1
StampMembers objMember.ADsPath, dicSeenGroupMember
end if
'
end if
'
next
'
End Function

 

[patstone]

Clancyfan : The 'old' email message is destined for an internal address, 'old' email messages to external address work fine

xmsre: Your KB is in relation to Exchange 5.5 .. Will this work for Exch2k -> Exch2k3 ?

 

[patstone]

Ok, added a X500 address and that worked, just have to test the script now

Thanks for your help

 

[xmsre]

If you changed sites.