Wildcard search in an array 1

[mcpeekj]

I have a little loop that will search for a string inside of array elements. It works fine when I search for a string that is the entire element. But I need to search for a string inside of the element. How can I do a wildcard search? I've tried using %, * and ?, all to no avail. Doesn't appear I can use like and not like either.

Thoughts?

for j = 0 to alldatarows
	if (alldata(2,j)) = "?string i want?" then
		response.write "mystuff"
	exit for
	end if
next

 

[gmmastros]

for j = 0 to alldatarows
    if InStr(1, alldata(2,j), "string i want", vbTextCompare) > 0 Then
        response.write "mystuff"
        exit for
    end if
next

vbTextCompare will return case insensitive matches.

I was kinda bummed out though. When I first saw this question, I immediately thought of the Filter function. Unfortunately, it only works for 1 dimensional arrays. Since I put in the effort to make it work, I'm gonna post it anyway, because it may be useful later.

<%

    Dim arTemp
    Dim arMatch
    
    ' Make a 1 dimensional array of strings.
    arTemp = Split("Apple,Orange,Grape,Banana", ",")
    
    ' create another array for the results.
    ReDim arMatch(UBound(arTemp))
    
    ' run the filter function. 
    ' In this case....
    ' r is the string to match
    ' True means... return the matches.  False would return elements that do not match.
    ' vbTextCompare so we have a case insensitive search
    
    arMatch = Filter(arTemp, "r", True, vbTextCompare)
    
    ' display the results
    for i = lbound(arMatch) to ubound(arMatch)
      response.Write(armatch(i) & "<br />")
    next

%>

-George

"The great things about standards is that there are so many to choose from." - Fortune Cookie Wisdom

 

[mcpeekj]

Beautiful! Works like a charm.

Thanks George!