vbscript - terminal server user profile path 2

[MatrixReloaded]

Can anyone help me with the code for extracting the terminal server user profile path please?
I can get the normal profile path but not the terminal server one.

MsgBox ("Logon Name: " & UserObj.Name & vbCrLf & _
"Full Name: " & UserObj.Fullname & vbCrLf & _
"Profile: " & UserObj.Profile & vbCrLf & _
"Description: " & UserObj.Description & vbCrLf & _
"LoginScript: " & UserObj.LoginScript & vbCrLf & _
"LastLogin: " & UserObj.LastLogin & vbCrLf & _
"WTSProfile: " & UserObj.?????)

Thanks

 

[jonscott8]

If you have Windows 2K3 Active Directory, see

http://msdn.microsoft.com/library/default.asp?url=/library/en-us/termserv/termserv/iadstsuserex.asp

http://www.microsoft.com/technet/treeview/default.asp?url=/technet/ScriptCenter/user/ScrUG60.asp

However, Windows 2K Active Directory does NOT expose to ADSI the Terminal Service User properties. See

http://www.winscriptingsolutions.com/Articles/Index.cfm?ArticleID=22353

Here's a solution I used a while back,

Download the tscmd utility from

http://www.systemtools.com/free_frame.htm

Use the following script modified to fit your configuration

sOutFile = "C:\termserv.txt"
sTSCmdPath = "C:\tscmd.exe"
sServer = "YourServer"
sADPath ="DC=Your,DC=Domain,DC=Com"

bCscript = (InStr(1,WScript.FullName,"CSCRIPT.EXE",1)>0)
Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFile = oFSO.CreateTextFile(sOutfile,True)
Set oDomain = GetObject("LDAP://CN=Users," & sADPath)
oDomain.Filter = Array("User")
For Each oUser in oDomain
  If bCscript Then Wscript.StdOut.Write oUser.samAccountName
  sExec = "cmd /c " & sTSCmdPath & " " & sServer & " """
  sExec = sExec  & oUser.samAccountName & """ TerminalServerProfilePath"
  Set oExec = oShell.Exec(sExec)
  Do While oExec.Status = 0
    WScript.Sleep 250
  Loop
  If bCscript Then Wscript.StdOut.WriteLine vbTab & oExec.Status
  oFile.Write oUser.samAccountName & vbTab & oExec.StdOut.ReadAll
Next
oFile.Close
Set oFile = Nothing
Set oFSO = Nothing
Set oShell = Nothing

I would also recommend running it thru Cscript to avoid the flicker each time the tscmd is executed

cscript "C:\yourscript.vbs"

Jon Hawkins