VBScript help - number of monitors attached to a computer 1

[tootiredtocare]

G'day,

Long story short - my manager wants to know the number of screens attached to a desktop and since we have a fleet of about 1000 desktops, I really don't want to have to do this manually.

Is there a way using vbscript (or cscript) to achieve this ??? I've been experimenting a little with the Win32_DesktopMonitor class to see what it does on my desktop but so far I've only got the details for the first monitor attached.

Any help would be appreciated.

 

[Geates]

WMIMonitorID class

strComputer = "."
set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate,authenticationLevel=Pkt}!\\" & strComputer & "\root\wmi") 
set colItems = objWMI.ExecQuery ("SELECT * FROM WMIMonitorID")
msgbox strComputer & " has " & colItems.count & " monitors configured"

-Geates

"I hope I can chill and see the change - stop the bleed inside and feel again. Cut the chain of lies you've been feeding my veins; I've got nothing to say to you!"
-Infected Mushroom

"I do not offer answers, only considerations."
- Geates's Disclaimer

 

[tootiredtocare]

Thanks for the help but it didn't work. I looked up the WMIMonitorID class on Microsoft's website and it says that the minimum supported client for this class is Windows Vista which could be the problem as our lovely backward government department is still running Windows XP.

When I did run the script, I got the following error:

Windows Script Host
Script: MonTest2.vbs
Line: 4
Char: 1
Error: Invalid class
Code: 80041010
Source: SWbemObjectSet

Any other suggestions other than an OS upgrade ?

 

[tootiredtocare]

Had an idea based on what you provided and also tried the following code:

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" _
& strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery _
("Select * from Win32_DesktopMonitor")
wscript.echo colSettings.count


However, the results weren't accurate and I'm unsure why. When I ran this on my PC, it reported 3 when I only had 2. Tried a colleagues and it reported 2 correctly. Ran it on my bosses and it reported 2 when he has only one screen.

 

[tootiredtocare]

Ok worked out the issue with the count from Win32_DesktopMonitor. It would appear to be reporting back the number of display adapter devices showing in the device manager.

Still no closer to solving the original problem though

 

[HughLerwill]

It's not mine but if you don't mind involving Excel try;

dim scode, oxl,owb,omod,nIdx,x

scode="Declare Function GetSystemMetrics Lib ""user32"" (ByVal nIndex As Long) As Long" & vbcrlf

nIdx=clng(80)
scode=scode & "function get_systemmetrics () As Long" & vbcrlf
scode=scode & "get_systemmetrics=GetSystemMetrics(" & nIdx & ")" & vbcrlf
scode=scode & "end function"


set oxl=createobject("excel.application")
set owb=oxl.workbooks.add
set omod=owb.vbproject.vbcomponents.add(1)
omod.codemodule.addfromstring scode
x=oxl.run("get_systemmetrics")
set omod=nothing
owb.saved=true
owb.close
set owb=nothing
oxl.quit
set oxl=nothing
wscript.echo "There is(are) " & cstr(x) & " monitor(s)"

 

[Geates]

oh yeah, I ran on windows 7, my bad.

-Geates

"I hope I can chill and see the change - stop the bleed inside and feel again. Cut the chain of lies you've been feeding my veins; I've got nothing to say to you!"
-Infected Mushroom

"I do not offer answers, only considerations."
- Geates's Disclaimer

 

[tootiredtocare]

Thanks for the assistance. The code from HughLerwill worked, but I did have to go into Excel into the Tools -> Macro -> Security option and tick the "Trust access to Visual Basic Project" box in the Trusted Publishers tab.

I do have a couple of worries with this though:

1) The code supplied by HughLerwill, in its current form, only works on the local PC. I'm unsure if the Excel solution can be tweaked to execute remotely and

2) Say I was to place the script on a remote PC and execute it remotely, I'm guessing it won't work as the "Trust access to Visual Basic Project" box in Excel won't be ticked on the remote PC and it won't retrieve the information

I'll play with the code a bit more and see what I can get it to do

 

[Geates]

The information has to be in the registry somewhere.

-Geates

"I hope I can chill and see the change - stop the bleed inside and feel again. Cut the chain of lies you've been feeding my veins; I've got nothing to say to you!"
-Infected Mushroom

"I do not offer answers, only considerations."
- Geates's Disclaimer

 

[tootiredtocare]

Thanks for the assistance from Geates and HughLerwill. This is the code I finished up with. I copy it to a remote PC and remotely execute it as an admin and it writes the results to a pre-programmed file

dim scode, oxl,owb,omod,nIdx,x, objWMI, colSettings

Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=Impersonate}!\\"_
& "." & "\root\cimv2")
Set colSettings = objWMI.ExecQuery _
("Select * from Win32_ComputerSystem")

set oShell = wscript.createobject("Wscript.shell")
set objFSO = CreateObject("Scripting.FileSystemObject")

For Each objComputer in colSettings
strName = objComputer.Name
Next

oshell.regwrite _
"HKCU\Software\Microsoft\Office\11.0\Excel\Security\AccessVBOM", "1", "REG_DWORD"

scode="Declare Function GetSystemMetrics Lib ""user32"" (ByVal nIndex As Long) As Long" & vbcrlf

nIdx=clng(80)
scode=scode & "function get_systemmetrics () As Long" & vbcrlf
scode=scode & "get_systemmetrics=GetSystemMetrics(" & nIdx & ")" & vbcrlf
scode=scode & "end function"


set oxl=createobject("excel.application")
set owb=oxl.workbooks.add
set omod=owb.vbproject.vbcomponents.add(1)
omod.codemodule.addfromstring scode
x=oxl.run("get_systemmetrics")
set omod=nothing
owb.saved=true
owb.close
set owb=nothing
oxl.quit
set oxl=nothing

oshell.regwrite _
"HKCU\Software\Microsoft\Office\11.0\Excel\Security\AccessVBOM", "0", "REG_DWORD"

strFileText = strName & ":" & vbTab & cstr(x) & " monitor(s)"

strFileName = "\\server\share\filename.txt"
set oFile=objFSO.OpenTextFile(strFileName,8,True)
oFile.WriteLine(strFileText)
oFile.Close

 

[HughLerwill]

Pleased to hear you have it working.

The regwrite looks Excel v11.0 dependant.

Consider placing the scode into a 'real' Excel.xls file (or an .xlt template file from which you can create further xls s if required) and automate/ call that. That may avoid having to mess with Excel security settings and the dependancy.

 

[HughLerwill]

>its not mine ...
It was from thread329-1423668

 

[tootiredtocare]

I've been experimenting with another script I've been working on and found this just by accident:

If you query Win32_VideoController and say count the number of active resolutions, it will generate the same results (well, it has so far with what I've tested).

Here's the code I've used for a single PC though it could easily be updated for multiple PCs:

Set objShell = CreateObject("WScript.Shell")

strComputer = InputBox("Enter the PC number you wish to run this script on", "Enter the PC number") 

if strComputer = "" then 
   wscript.echo "No PC number supplied. Quitting Program"
   wscript.quit
end if

intMonitorCount = 0

If Ping(strComputer) then
   Dim objWMI : Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=Impersonate}!\\" & strComputer & "\root\cimv2")
   Dim colSettingsVideo : set colSettingsVideo = objWMI.ExecQuery("Select * from Win32_VideoController")

   for each objComputer in colSettingsVideo
      if not isnull(objComputer.VideoModeDescription) then
         intMonitorCount = intMonitorCount + 1
      end if
   next

   if intMonitorCount = 1 then
      wscript.echo "There is ", intMonitorCount, " monitor attached to ", strComputer
   else
      wscript.echo "There are ", intMonitorCount, " monitors attached to ", strComputer
   end if
end if


Function Ping(PC)
   Set objWshScriptExec = objShell.Exec("ping.exe -n 1 " & PC)
   Set objStdOut = objWshScriptExec.StdOut

   awake=False
   Do Until objStdOut.AtEndOfStream
      strLine = objStdOut.ReadLine
      awake = awake Or InStr(LCase(strLine), "bytes=") > 0
   Loop
   Ping = awake
End Function