VB Script error 1

[DrSeussFreak]

Ok, so any ideas on how to make this work?

const ForReading = 1
dim strSearchThis
dim objFS
dim objTS
set objFS = Server.CreateObject("Scripting.FileSystemObject")
set objTS = objFS.OpenTextFile(Server.MapPath("D:\oracle\dba_util\scripts\log\tspace.log"), _
                               ForReading)

strSearchThis = objTS.ReadAll
if instr(strSearchThis, "-") > 0 Then
	SendEmail "to", "from", "MARS - Daily Extent Report", objTS
Else
	SendEmail "to", "from", "MARS - Daily Extent Report", "All is ok"
End If

Sub SendEmail(strTo, strFrom, strSubject, strMsg)
    schema = "[URL unfurl="true"]http://schemas.microsoft.com/cdo/configuration/"[/URL]
    SmtpServer = "SMTP Here"

    Set objEmail = CreateObject("CDO.Message")
    objEmail.From = strFrom
    objEmail.To = strTo
    objEmail.Subject = strSubject
    objEmail.Textbody = strMsg
    objEmail.Textbody = objEmail.Textbody & VbCrLf

    objEmail.Configuration.Fields.Item (schema & "sendusing") = 2
    objEmail.Configuration.Fields.Item (schema & "smtpserver") = SmtpServer
    objEmail.Configuration.Fields.Item (schema & "smtpserverport") = 25
    objEmail.Configuration.Fields.Update
    objEmail.Send
End Sub

Error is

D:\oracle\dba_util\scripts\TSpaceChecker.vbs(5, 1) Microsoft VBScript runtime error: Object required: 'Server'

 

[DrSeussFreak]

Ok, so I changed it to

Const ForReading = 1

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("D:\oracle\dba_util\scripts\log\tspace.log", _
    ForReading)

strSearchThis = objTextFile.ReadAll
if instr(strSearchThis, "-") > 0 Then
	SendEmail "to", "from", "MARS - Daily Extent Report - Not Ok", objTextFile.ReadAll
Else
	SendEmail "to", "from", "MARS - Daily Extent Report - OK!", _
							"Ohh, what a wonderful world"
End If

Sub SendEmail(strTo, strFrom, strSubject, strMsg)
    schema = "[URL unfurl="true"]http://schemas.microsoft.com/cdo/configuration/"[/URL]
    SmtpServer = "SMTP Server"

    Set objEmail = CreateObject("CDO.Message")
    objEmail.From = strFrom
    objEmail.To = strTo
    objEmail.Subject = strSubject
    objEmail.Textbody = strMsg
    objEmail.Textbody = objEmail.Textbody & VbCrLf

    objEmail.Configuration.Fields.Item (schema & "sendusing") = 2
    objEmail.Configuration.Fields.Item (schema & "smtpserver") = SmtpServer
    objEmail.Configuration.Fields.Item (schema & "smtpserverport") = 25
    objEmail.Configuration.Fields.Update
    objEmail.Send
End Sub

 

[DrSeussFreak]

it works for when there is no '-' in the file, but when there is a '-' in the log file, I get

D:\oracle\dba_util\scripts>tspacechecker2.vbs
Microsoft (R) Windows Script Host Version 5.6
Copyright (C) Microsoft Corporation 1996-2001. All rights reserved.

D:\oracle\dba_util\scripts\TSpaceChecker2.vbs(9, 2) Microsoft VBScript runtime
error: Input past end of file

 

[guitarzan]

Try this:

if instr(strSearchThis, "-") > 0 Then
    SendEmail "to", "from", "MARS - Daily Extent Report - Not Ok", [COLOR=blue]strSearchThis [/color][s]objTextFile.ReadAll[/s]

 

[DrSeussFreak]

Awesome man, thanks!