Using "$/ = undef" and <STDIN> together

[SparceMatrix]

Using "$/ = undef" and <STDIN> together

In a PERL script I need to open a text file to be read all at once and not line by line. I have been advised that the way to do this is to set $/ = undef, and this has worked nicely so far. But now I have to provide some input by way of <STDIN> and when this variable is undefined the input cycle for <STDIN> appears to hang and it won't apply my input properly either.

How do I make the code below work?

#!/usr/bin/perl

$/ = undef;

print "Enter first number: ";

# $one = <STDIN>;
chomp($one = <STDIN>);

print "Enter second number: ";

# $two = <STDIN>;
chomp($two = <STDIN>);

$result = $one * $two;

print "Your numbers were " . $one . " and " . $two .".\n";
print "The result is $result.\n";

Is there some way I can apply the "$/ = undef" in an "open(<MYFILE>, "MyFile.txt")" statement and not make it global?

 

[rharsh]

There are quite a few ways to do what you're looking for. The easiest is probably to wait to modify $/ until you're going to use it. Then set it back to the newline character when you're done.

# Get user input
print "Enter something: "
my $input = <STDIN>;

# Slurp the file
$/ = undef;
open FH, "< somefile.txt" or die;
$/ = "\n";

# Get more input
print "Enter something else: "
my $input2 = <STDIN>;

 

[ishnid]

That method won't be portable, as the default value of $/ changes with your OS. The best way to do this is to use `local':

# Get user input
print "Enter something: "
my $input = <STDIN>;

my $file_contents;

{
   local $/; # slurp mode until the end of this block

   open FH, "< somefile.txt" or die;
   $file_contents = <FH>;
   close FH;
}

# Get more input
print "Enter something else: "
my $input2 = <STDIN>;

 

[KevinADC]

or more compactly:

open FH, '<file.txt' or die "Can't open file.txt: $!";
$text = do{local $/; <FH>};
close FH;

only affects the reading of the one file same as ishnids example.

 

[SparceMatrix]

How does "local $/" make it undefined, or change it the way I need it?

 

[KevinADC]

local makes it local to just the do{} block, writing it as:

local $/;

is the same as:

local $/ = undef;

if you need to change the value of $/ just redefine it as needed:

do {local $/ = " "; <FH>};

but you want to use "local" and wrap it in a block of some sort so it only affects the block of code and not the entire script, unless that's what you want to do or it's not important.