use variables in xsl ? 1

tyris · Jul 11, 2001

hi all,
i do have an xml document this way :

Code:

<document name=&quot;Marketing&quot;>
	<tables count=&quot;1&quot;>
		<table name=&quot;AllDocuments&quot;>
			<columnHeaders count=&quot;3&quot;>
			     <columnHeader text=&quot;Site&quot;/>
			     <columnHeader text=&quot;Status&quot;/>
			     <columnHeader text=&quot;Account&quot;/>
			</columnHeaders>
			<rows count=&quot;134&quot;>
				<row>
				      <column>Paris</column>
				      <column>Project Completed</column>
				      <column>Microsoft (France)</column>
				</row>
				<row>
				      <column>Paris</column>
				      <column>Project Completed</column>
				      <column>Lionbridge Nortel</column>

				</row>
			</rows>
		</table>
	</tables>
</document>

what i'd like is :
display each row "talking" about the Account. i thought i could make a <xsl:if test="columnHeaders='Account'"> then give the number of the row (incremented at each columnHeaders i found)
and then for each <column> use a second variable incremented, test if this one is equal to the one for columnHeaders and if yes, display it.

i don't know how it could be done. is there a way :
1. to use variable and increment them
2. test them with and other variable Best regards X-),
Elise

dianal · Jul 12, 2001

Hello,
I would suggest that you redesign your xml.
See thread426-101326 for example how to assure relations between your data. Then you'll be able to do your task.
If you still have problems post again.
I'll try to provide example.

XSLT is not procedural language.
You can use <xsl:variable> in two ways - one is set a value, then only get value. You cannot do a loop in such way.
When getting a value of a variable you can test value of other variable also.

<xsl:variable name="bookCount" select="count(//book)"/>
<xsl:variable name="bookTotal" select="sum(//book/price)"/>
<xsl:variable name="bookAverage" select="$bookTotal div $bookCount"/>

<xsl:if test="(price - $bookAverage) > 15"/>

D.

tyris · Jul 12, 2001

thanks, i have made some works, i'm now at this step :
i try to do this :

[declare a variable called x]


<xsl:template match="document/tables/table/columnHeaders/columnHeader">
<xsl:if test="@text[.='Project']">
[make x = position()]
</xsl:if>

</xsl:template>


<xsl:template match="/">
<xsl:for-each select="document/tables/table/rows/row">
<xsl:for-each select="column">
[if position() = the x i have initialise before then display]

</xsl:for-each>
</xsl:for-each>

the problem is that it seems that in the last part (<xsl:template match="/">) x is unknown. what is the way to :
1. define a variable
2. give this variable a value in one template
3. red this value in an other template

the problem is that it seems that in the last part (<xsl:template match="/">) x is unknown. what is the way to :
1. define a variable
2. give this variable a value in one template
3. red this value in an other template

sorry for my english, i'm french Best regards X-),
Elise

dianal · Jul 13, 2001

Hello,
Variables serve as additional tool. They are local to place where they are defined. So you cannot do procedural tasks with them as with other programming languages.
There are other techniques <xsl

aram>, <xsl:with

aram>, <xsl:call-template> that provide ways to set values outside of a template, and use them inside.
I'll try to provide more info on them in my next message.

I assume that there will be other answers except mine, but let's try to show you simpler way of getting the task done.

I suppose that you can control how your xml file look.
I suggest that you use the following xml:

<document name="Marketing">
<tables count="1">
<table name="AllDocuments">
<columnHeaders count="3">
<columnHeader id="1">Site</columnHeader>
<columnHeader id="2">Status</columnHeader>
<columnHeader id="3">Account</columnHeader>
</columnHeaders>
<rows count="134">
<row>
<column id="1">Paris</column>
<column id="2">Project Completed</column>
<column id="3">Microsoft (France)</column>
</row>
<row>
<column id="1">Paris</column>
<column id="2">Project Completed</column>
<column id="3">Lionbridge Nortel</column>
</row>
</rows>
</table>
</tables>
</document>

In such way in each row you will have clear indication to which column header it belongs.

Then you could use one of the following templates to diplay a table with column headers and rows:

1) one template with "for-each" style
<xsl:stylesheet version="1.0" xmlns:xsl="

http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<table border="1">
<tr>
<th/>
<xsl:for-each select="//columnHeader">
<th>
<xsl:value-of select="."/>
</th>
</xsl:for-each>
</tr>
<xsl:for-each select="//row">
<tr>
<td>
<xsl:value-of select="position()"/>
</td>
<xsl:for-each select="column">
<td>
<xsl:if test="@id = 2">
<xsl:attribute name="bgcolor">yellow</xsl:attribute>
</xsl:if>
<xsl:value-of select="."/>
</td>
</xsl:for-each>
</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

2) many templates without "for-each"

<xsl:stylesheet version="1.0" xmlns:xsl="

http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<table border="1">
<tr>
<th/>
<xsl:apply-templates select="//columnHeader"/>
</tr>
<xsl:apply-templates select="//row"/>
</table>
</body>
</html>
</xsl:template>

<xsl:template match="columnHeader">
<th>
<xsl:value-of select="."/>
</th>
</xsl:template>

<xsl:template match="row">
<tr>
<td>
<xsl:value-of select="position()"/>
</td>
<xsl:apply-templates select="column"/>
</tr>
</xsl:template>

<xsl:template match="column">
<td>
<xsl:choose>
<xsl:when test="@id = 2">
<font color="red">
<xsl:value-of select="."/>
</font>
</xsl:when>
<xsl

therwise>
<xsl:value-of select="."/>
</xsl

therwise>
</xsl:choose>
</td>
</xsl:template>

</xsl:stylesheet>

3) Even more templates without "for-each", without if
<xsl:stylesheet version="1.0" xmlns:xsl="

http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<table border="1">
<tr>
<th/>
<xsl:apply-templates select="//columnHeader"/>
</tr>
<xsl:apply-templates select="//row"/>
</table>
</body>
</html>
</xsl:template>

<xsl:template match="columnHeader">
<th>
<xsl:value-of select="."/>
</th>
</xsl:template>

<xsl:template match="row">
<tr>
<td>
<xsl:value-of select="position()"/>
</td>
<xsl:apply-templates select="column"/>
</tr>
</xsl:template>

<xsl:template match="column">
<td>
<xsl:value-of select="."/>
</td>
</xsl:template>

<xsl:template match="column[@id=2]">
<td>
<xsl:attribute name="bgcolor">yellow</xsl:attribute>
<xsl:value-of select="."/>
</td>
</xsl:template>

</xsl:stylesheet>

Wish you success!
I'll try to post more info on other ways also.
D.

tyris · Jul 13, 2001

great, i think you gave me many possibilities, i thong i can do something good now thanks Best regards X-),
Elise

tyris · Jul 13, 2001

great, i think you gave me many possibilities, i think i can do something good now thanks Best regards X-),
Elise

Guest_imported · Jul 15, 2001

I'm trying to dynamically set the url for the action parameter in a form tag using xsl stylesheets to process genrated xml output from my application to produce html that is sent to the client.

I have a database servlet that I'd like to run on different servers, but I'd like not to have to rewrite all the form tags in the xsl files that process the xml to generate the html.

I've tried to use xsl:element to build the form tag with the url coming in as a <server_url>

http://.

. . </server_url> xml tag. However, SAX chokes on this and seems to think there is not a terminator for an xsl:template tag, which is not the case. I've also tried it with a variable, but run into problems with the parser because of special characters.

Suggestions?

Tek-Tips is the largest IT community on the Internet today!

Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!

use variables in xsl ? 1

tyris

Programmer

dianal

Instructor

tyris

Programmer

dianal

Instructor

tyris

Programmer

tyris

Programmer

Guest_imported

New member

Similar threads

Part and Inventory Search

Sponsor