Trying to make Excel Row Bold 2

[gbettle]

Howdy all,

I have opened an Excel spreadsheet, which always has just 3 columns. I would like to scan through the rows, evaluate the 3rd column to be > 0, and if not, make the entire row bold.

I thought something like this would in order:

lnLastRow = loXls.Range( "A1").End( xlDown).Row

for loop = 2 to lnLastRow && 1 is the Header row, so skip
lcRow = alltrim( str( loop))
if loXls.Cells( loop, 3).Value = 0
loXls.Range("A" + lcRow + ":C" + lcRow).Style = "Bold"
endif
endfor

loXls.Save

But, it keeps bombing on the loXls.Range("A" + ... line with:

OLE error code 0x8002000e: Invalid number or parameters.

Any ideas why?

Cheers,

Garry

 

[baltman]

loXls = CREATEOBJECT([excel.application])
loXls.visible=.t.
loXls.workbooks.add()
FOR lnRow = 1 TO 25
	loXls.Range("A"+TRANSFORM(lnRow)).VALUE= lnRow
	loXls.Range("B"+TRANSFORM(lnRow)).VALUE= lnRow+2
	loXls.Range("C"+TRANSFORM(lnRow)).VALUE= IIF(MOD(lnRow,3)=0,3,lnRow)
ENDFOR 

lnRow = 0
llColAHasData = .t.
DO WHILE llColAHasData 
	lnRow = lnRow + 1
	
	IF ISNULL(loXls.Range("A"+TRANSFORM(lnRow)).VALUE)
		 llColAHasData = .f.
	ELSE
		IF loXls.Range("C"+TRANSFORM(lnRow)).VALUE = 3
			loXls.Range("A"+TRANSFORM(lnRow)+":C"+TRANSFORM(lnRow)).Font.Bold=.t.
		ENDIF 
	ENDIF 
ENDDO

 

[Mike Lewis]

Garry,

The point to remember that, in Excel, each cell or range has a Font property. This contains all the settings related to fonts and font styles, including Bold. Remember also that Bold is a logical value, not a string.

So, to set range "A1" to bold, you would do this:

loSheet.Range("A1").Font.Bold = .T.

Note that Excel differs from Word in this respect. In Word, you would just say loRange.Bold = .T. -- there's no containing Font object.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

My Visual FoxPro site: www.ml-consult.co.uk

 

[gbettle]

Many thanks Baltman & Mike.

Cheers,

Garry