Syntax Error Help 1

[mmelisi]

Hi.

Having a tough time understanding why I am getting the following syntax error. I am using Microsoft Cobol Compiler v2.2.

Invalid SELECT sentence. C:\temp\test.txt
Unrecognizable element is ignored C:\temp\test.txt

Here is the small program I am trying to get a clean compile on....this is the only error I have left. Any help would be appreciated!

Thanks.
Gino.

IDENTIFICATION DIVISION.
PROGRAM-ID. SCROCCUR.
AUTHOR. Gino Fremani.
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT IN-FILE ASSIGN 'C:\TEMP\TEST.TXT'.

DATA DIVISION.
FILE SECTION.
FD IN-FILE
LABEL RECORDS ARE STANDARD.
01 INPUT-REC.
05 ID-IN PIC XXXX.
05 NAME-IN PIC X(20).
WORKING-STORAGE SECTION.
01 INDICATORS.
05 EOF-IND PIC XXX VALUE "NO ".
01 RESPONSES.
05 SCR-RESP-WS PIC X VALUE SPACES.
05 CUR PIC 99 VALUE 4.
05 CT PIC 9 VALUE 0.
SCREEN SECTION.
01 DATA-SCREEN.
05 HDR-INFO.
10 VALUE "DATA SCREEN" BLANK SCREEN
LINE 01 COLUMN NUMBER is PLUS 30.
10 VALUE "ID #" LINE 03 COLUMN NUMBER IS PLUS 12.
10 VALUE "NAME" LINE 03 COLUMN NUMBER IS PLUS 17.
05 INFO-SCR-IN.
10 ID-ON-SCR-IN LINE 04 COLUMN NUMBER IS PLUS 12
PIC XXXX FROM ID-IN.
10 NAME-ON-SCR-IN LINE 04 COLUMN NUMBER IS PLUS 17
PIC X(20) FROM NAME-IN.
05 RESP-INFO.
10 VALUE "C - TO CONTINUE"
LINE 16 COLUMN NUMBER IS PLUS 30.
10 VALUE "Q - TO QUIT"
LINE 17 COLUMN NUMBER IS PLUS 30.
10 VALUE "ENTER CHOICE:"
LINE 19 COLUMN NUMBER IS PLUS 30.
10 RESPONSE-SCR
LINE 19 COLUMN NUMBER IS PLUS 45
PIC X TO SCR-RESP-WS.
PROCEDURE DIVISION.
MAINLINE.
PERFORM A-100-INITIALIZE.
PERFORM B-100-PROCESS.
PERFORM C-100-TERMINATE.
STOP RUN.
A-100-INITIALIZE.
OPEN INPUT IN-FILE.
B-100-PROCESS.
READ IN-FILE
AT END
MOVE "YES" TO EOF-IND.
PERFORM B-200-LOOP
UNTIL EOF-IND = "YES" OR SCR-RESP-WS = "Q".
B-200-LOOP.
MOVE 4 TO CUR.
MOVE 0 TO CT.
DISPLAY HDR-INFO.
PERFORM B-300-SETUP
UNTIL CT > 4 OR EOF-IND = "YES" OR SCR-RESP-WS = "Q".
DISPLAY RESP-INFO.
ACCEPT RESP-INFO.
B-300-SETUP.
ADD 1 TO CUR.
ADD 1 TO CT.
DISPLAY INFO-SCR-IN.
READ IN-FILE
AT END
MOVE "YES" TO EOF-IND.
C-100-TERMINATE.
CLOSE IN-FILE.

 

[Glenn9999]

Double quotes (") instead of single quotes ('). My first thought.

 

[joeih]

Try double quotes instead of single

"C:\TEMP\TEST.TXT".

JH

http://www.payrollpc.com

 

[mmelisi]

Thanks to both replies, but double vs single quote made no difference...I tried this prior to posting.

 

[Glenn9999]

Might this particular compiler be looking for a "TO" in there?

 SELECT StudentFile ASSIGN TO "STUDENTS.DAT"
		ORGANIZATION IS LINE SEQUENTIAL.

 

[webrabbit]

Are you sure it's Microsoft? That's pretty old. They haven't published a COBOL compiler for about 20 years. I know I have the manual somewhere, but I can't locate it right now. Perhaps you need the keyword DISK before the literal.

 

[mmelisi]

The "TO" Statement does not seem to fix the problem as does the DISK addition. Believe it or not, it is Microsoft 2.20 from the fabulous 80's!

Thanks for the suggestions.

 

[mmelisi]

Thanks to webrabbit for pointing me in the right direction. The DISK addition did work, but I had to remove the literal after it and include it in the file ID syntax. I clipped the code below for reference....

Thanks to Glen and Joe as well.

============================================================
IDENTIFICATION DIVISION.
PROGRAM-ID. SCROCCUR.
AUTHOR. Gino Fremani.
ENVIRONMENT DIVISION.
CONFIGURATION SECTION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT IN-FILE ASSIGN TO DISK.

DATA DIVISION.
FILE SECTION.
FD IN-FILE
DATA RECORD IS INPUT-REC
LABEL RECORDS ARE STANDARD
VALUE OF FILE-ID IS "C:\TEMP\TEST.TXT".
01 INPUT-REC.
05 ID-IN PIC XXXX.
05 NAME-IN PIC X(20).