Symposium script - does this look alright?

[brewerdude]

I'm pretty sure this script will do what I want, just wanted to run it by this forum before I activated it. Essentially, all I want to do is send the calls to an alternate skillset if a caller is waiting for more than two minutes. My changes are still commented out, but I've bolded them to make it easier to see what I'm trying to do. Any comments and/or suggestions are appreciated.

This is a 4.0 system on an 81C

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

/*==========================================================================
SCRIPT : SLED_Area_Code_Routing

CDN: 6716

DESCRIPTION : This script will route calls to the appropriate IPS SLED
(State, Local, Education) skillset depending on the area
code of the caller. All area codes are defined in the
NPA variables for each region.

HISTORY :

VERSION AUTHOR DATE COMMENTS
mm-dd-yyyy

01 Ian Trollope Sep 29 2004 Creation of script.
02 Ian Trollope Dec 17 2004 Added code to send to IPS_All if on hold for 2 mins


============================================================================*/



GIVE RINGBACK
WAIT 2

IF DATE = Holidays THEN
EXECUTE SCRIPT Holiday_Script
END IF


/* Check to see if during Business hours */
IF (DAY OF WEEK = MondayThruFriday AND TIME OF DAY <> BizHrsIPS_SLED) OR
DAY OF WEEK = Weekend THEN
Execute OutOfOffice
END IF


WHERE NPA EQUALS /* Assign skillset based on Area code of caller */

VALUE East_Area_Code_SLED_1, East_Area_Code_SLED_2, East_Area_Code_SLED_3:
ASSIGN IPS_SLED_East TO skillset_cv

VALUE Central_Area_Code_SLED_1, Central_Area_Code_SLED_2:
ASSIGN IPS_SLED_Central TO skillset_cv

VALUE West_Area_Code_SLED:
ASSIGN IPS_SLED_West TO skillset_cv

DEFAULT:
ASSIGN IPS_SLED_ALL TO skillset_cv
/* ASSIGN TRUE to Assigned_Yet_cv */

END WHERE



/*Begin the queueing the call*/
IF NOT OUT OF SERVICE skillset_cv THEN
QUEUE TO SKILLSET skillset_cv
ELSE
EXECUTE OutOfOffice
END IF

WAIT 2

GIVE RAN FirstRAN

GIVE MUSIC PromoMusic

SECTION RAN_loop

IF (OUT OF SERVICE skillset_cv) THEN /*Check to see if no one in skillset*/
EXECUTE OutOfOffice
END IF

/*Send the call to IPS_SLED_ALL if call waiting for over 2 mins */

/*IF AGE OF CALL >= 120 AND Assigned_Yet_cv = FALSE THEN
ASSIGN IPS_SLED_ALL TO skillset_cv
ASSIGN TRUE to Assigned_Yet_cv

IF NOT OUT OF SERVICE skillset_cv THEN
QUEUE TO SKILLSET skillset_cv WITH PRIORITY 1
ELSE
EXECUTE OutOfOffice
END IF

END IF*/


WAIT 45 /* Wait - listening to music */

IF NOT OUT OF SERVICE skillset_cv THEN
IF NOT QUEUED THEN /* Check if still queued */
QUEUE TO SKILLSET skillset_cv
WAIT 2
END IF
END IF

GIVE RAN SecondRAN

EXECUTE RAN_loop



SECTION OutOfOffice
ROUTE CALL 3123

 

[KillianK]

It looks fine to me, you are just using a Boolean Call Varable, yes/no?

Cheers,

Killian

NextiraOne Ireland

 

[brewerdude]

Yes - I want to queue it to IPS_SLED_All if the call is over 120 secs. However, if the call is on hold for a while, I don't want to keep requeueing it. So once it gets queued, I set a flag for it so it won't get queued again.

Also - a call could get queued to IPS_SLED_All at the onset, if that happens, I set the flag at that point.

 

[DancingDave]

Not sure whether the call will still be queueing to the original skillset after you change the value for skillset_cv and if this may cause errors.

How about queueing the call to a second skillset to avoid any possibility of this?

This would give

/*IF AGE OF CALL >= 120 AND Assigned_Yet_cv = FALSE THEN
ASSIGN IPS_SLED_ALL TO skillset_backup_cv
ASSIGN TRUE to Assigned_Yet_cv

IF NOT OUT OF SERVICE skillset_backup_cv THEN
QUEUE TO SKILLSET skillset_backup_cv WITH PRIORITY 1
ELSE
EXECUTE OutOfOffice
END IF

END IF*/

You'd also need to add extra scripting to check for dequeued calls on this new skillset.

Another alternative would be to queue the call to the back up skillset if the inituial one was out of service