Symposium and HDX Scripting 2

[81Cadmin]

I was wondering if any of you have any experience using the HDX / Database Integration Wizard included in Symposium 5.0.

The Nortel manual Symposium Database Integration User's Guide doesn't offer much insight into the exact scripting to move information from the Blue database to another. (Such as the provId; they don't tell you how this is specified in a script).

If someone could provide some guidance and/or test scripts which use HDX I would greatly appreciate it. I understand SQL and Symposium scripting well but just green in the HDX area.

Are there any better manuals or reference guides for HDX?

Thanks in advance all...

- 81CAdmin

 

[mikeyb123]

what are you looking to do?

here's a script we played with that queries a database according to the account number keyed in to a variable..

GIVE RINGBACK
WAIT 2

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT Welcome_Msg_1_vs
COLLECT 1 DIGITS INTO cv_choice
END VOICE SESSION

WHERE cv_choice EQUALS
VALUE 1 : EXECUTE HDX_Status_App
DEFAULT : EXECUTE TO_AGENT
END WHERE

SECTION HDX_Status_App

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT PIN_Request_vs
COLLECT 5 DIGITS INTO HDX_PIN_cv
INTER DIGIT TIMER 5
WITH TERMINATING CHARACTER #
END VOICE SESSION

WHERE HDX_PIN_cv EQUALS
VALUE 1234 : EXECUTE HDX_Status_App_2
DEFAULT : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT PIN_Fail_vs END VOICE SESSION
EXECUTE TO_AGENT
END WHERE

SECTION HDX_Status_App_2

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT HDX_welcome_msg
COLLECT 11 DIGITS INTO HDX_Acc_No
INTER DIGIT TIMER 8
WITH TERMINATING CHARACTER #
END VOICE SESSION

ASSIGN 2 TO CV_HDX_PROV_ID
ASSIGN 3 TO HDX_SQL_1
SEND REQUEST CV_HDX_PROV_ID HDX_SQL_1, HDX_Acc_No
GET RESPONSE CV_HDX_PROV_ID HDX_Result, HDX_2_Stat_Ret

ASSIGN 2 TO CV_HDX_PROV_ID
ASSIGN 2 TO HDX_SQL_1
ASSIGN "%TIME%" TO HDX_Time
ASSIGN "%CALLID%" TO HDX_Call_ID
ASSIGN CLID TO HDX_CLID
SEND INFO CV_HDX_PROV_ID HDX_SQL_1, HDX_Acc_No, HDX_Time, HDX_2_Stat_Ret, HDX_Call_ID, HDX_Result, HDX_CLID

IF HDX_Result = "SUCCESS" THEN
WHERE HDX_2_Stat_Ret EQUALS
VALUE "001" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_001 END VOICE SESSION
VALUE "002" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_002 END VOICE SESSION
VALUE "003" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_003 END VOICE SESSION
VALUE "004" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_004 END VOICE SESSION
VALUE "005" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_005 END VOICE SESSION
VALUE "006" : OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_MSG_006 END VOICE SESSION
DEFAULT : LOG "HDX Error" EXECUTE TO_AGENT
END WHERE
ELSE OPEN VOICE SESSION PLAY PROMPT VOICE SEGMENT Status_No_record END VOICE SESSION
END IF

SECTION TO_AGENT

GIVE MUSIC 51
WAIT 60

DISCONNECT

Script Variables:

HDX_PIN_cv Type = DN Value = 9999
HDX_Acc_No Type = DN Value = 9123456789
CV_HDX_PROV_ID Type = Integer Value = 1
HDX_SQL_1 Type = Integer Value = 1
HDX_Result Type = String Value = SUCCESS
HDX_2_Stat_Ret Type = String Value = 0
HDX_Time Type = String Value = test
HDX_Call_ID Type = String Value = ??
HDX_CLID Type = CLID Value = 1234




Server Details:

In the database integration wizard:

from HDX_GOS_TEST
statement 3: SELECT app_sta_cod FROM dbo.gos_app WHERE acc_num_mst='?'


from Test_DSN

statement 1:SELECT HDX_Test.Acct_Status FROM HDX_Test WHERE (((HDX_Test.Acct_No)=?));
starement 2:INSERT INTO HDX_LOG VALUES (?, ?, ?, ?, '?', ?)

On the server, ODBC datasources:

Test_DSN is a access datasource with the mdb local on the server
HDX_GOS_TEST is a sql datasource pointing to sql server


It's not getting any smarter out there. You have to come to terms with stupidity, and make it work for you.

 

[81Cadmin]

Thanks Mikeyb123, This gives better insight into how HDX works.

As for queries I'm new to HDX so for "testing" I have created a SQL database where I'd like to deposit Blue database info into SQL (Agent ID, time, CallID, etc..etc). I haven't had much success thus far but will re-test using your script as a guide.

Thanks again.

 

[81Cadmin]

Would it be possible for you (Mikeyb123) or someone else to write a simple HDX script which outlines how to pass the CALL_ID into a SQL database. I'm sure if I can understand the framework (and steps) of building a simple script then I would have a better understanding of HDX in general. The Symposium Database Integration User's Guide seems to be lacking key instructions in building a working HDX script.

If this isn't something any could provide then I appreciate your guideance so far.

I'm scheduled for a scripting/HDX course in coming months but really wanted to get a head start if I can.

Cheers,

 

[Jamiepockets]

Very basic HDX intergration

give ringback


wait 2
open voice session play prompt with language english voice segment desk5ac

COLLECT 4 DIGITS INTO INF_1_CV INTER DIGIT TIMER 4

END VOICE SESSION
WAIT 2
open voice session play prompt with language english voice segment desk5pin

COLLECT 4 DIGITS INTO INF_2_CV INTER DIGIT TIMER 4

END VOICE SESSION


SEND REQUEST app_id inf_1_cv,inf_2_cv
GET RESPONSE app_id TIMER 6 inf_3_cv

open voice session
PLAY PROMPT NUMBERbydigit inf_3_cv
end voice session

WAIT 2
disconnect