Subtract First Record from the Last Record 3

[mmck1964]

I have report grouped by ID number and pulled in a date range of data into the detail section of the report. Below is an example of the data: {date} and {reading}

9/01/2011 18900
9/02/2011 18991
9/03/2011 19025
and so on until---
9/30/2011 20528
10/1/2011 20575

I would like to subtract the 10/1/2011 reading from the 9/01/2011 reading. How can I do this for each grouped ID number?
Thanks

 

[lbass]

If the values are always increasing (and not going up and down), you can use a formula like this:

maximum({table.reading},{table.ID})-minimum({table.reading},{table.ID})

-LB

 

[mmck1964]

In most cases, the values should be increasing, but not always. However, the dates will always be increasing for each value. I would like to see if there is a formula that would find the first date and the last date, then subtract the value associated with the first date from the value associated with the last date.

 

[lbass]

Then create formulas like this:

//{@readings} to be placed in the detail section and suppressed:
whileprintingrecords;
numbervar first;
numbervar last;
if {table.date} = minimum({table.date},{table.ID}) then
first := {table.reading};
if {table.date} = maximum({table.date},{table.ID}) then
last := {table.reading};

//(@displaydiff} to be placed in the group footer:
whileprintingrecords;
numbervar first;
numbervar last;
last-first

//{@reset} to be placed in the ID group header and suppressed:
whileprintingrecords;
numbervar first;
numbervar last;
if not inrepeatedgroupheader then (
first := 0;
last := 0
);

-LB

 

[mmck1964]

AWESOME! Thank you!!!

 

[mmck1964]

Now for another question. Is there a way to take value calculated in the Group Footer (Last - First) and sum all of those values in the Report Footer?

 

[lbass]

Change the group footer {@display} to:

whileprintingrecords;
numbervar first;
numbervar last;
numbervar diff := last-first;
numbervar sumdiff := sumdiff + diff;
diff

Then in the report footer add a formula {@sumdiff}:

whileprintingrecords;
numbervar sumdiff;

-LB

 

[mmck1964]

Simply amazing! Thank you so much.