Style /BOX with a <div>

[nobyrnes]

Hey,
I am trying to set all the styles in my stylesheet, however I cannt set the /Box or title2, title3 etc?

This is what I am trying.
Tried /box=[label='<div id="boxname">blah</div>'

I am using Proc template and tagattr for the rest, but I cannot find the box or titles.

Thanks....
N

 

[ChrisW75]

The titles styles are defined by "style SystemTitle"
Box I think comes under the "style Header" or perhaps "style RowHeader"

I set up a full template a while back which I use, and it seems to cover all the items in the reports I've produced. Try this as a starting point and see if it helps...

ods path sashelp.tmplmst(update) ;

/* Documentation on this process can be found at:- */
/* [URL unfurl="true"]http://support.sas.com/rnd/base/topics/templateFAQ/ODS91.pdf#pagemode=bookmarks[/URL] */

proc template;
   define style styles.myhtml;
      parent=styles.default;
      style SystemTitle from SystemTitle /
         font_face = "Arial, Helvetica, Sans Serif"
         font_size = 4
         font_weight = bold
         font_style = roman
         foreground = #000000
         background = #FFFFFF;

      style SystemFooter from SystemFooter /
         font_face = "Arial, Helvetica, Sans Serif"
         font_size = 3
         font_weight = bold
         font_style = italic
         foreground = #000000
         background = #FFFFFF;

      style SysTitleAndFooterContainer from SysTitleAndFooterContainer /
         font_face = "Arial, Helvetica, Sans Serif"
         font_size = 3
         font_weight = bold
         font_style = italic
         foreground = #FFFFFF
         background = #FFFFFF
         borderwidth = 0
         ;

       style Body from Body /
         font = ("Arial, Helvetica, Sans Serif")
         font_size = 2
         font_weight = medium
         font_style = roman
         foreground = #000000
         background = #FFFFFF
         leftmargin = 8px
         rightmargin = 8px;

      style RowHeader from RowHeader/
         font = ("Arial, Helvetica, Sans Serif")
         font_size = 2
         font_weight = bold
         font_style = roman
         foreground = #000000
         background = #99CCFF;

      style Header from Header /
         font = ("Arial, Helvetica, Sans Serif")
         font_size = 2
         font_weight = bold
         font_style = roman
         foreground = #000000
         background = #99CCFF;

      style Data from Data /
         font = ("Arial, Helvetica, Sans Serif")
         font_size = 2
         font_weight = medium
         font_style = roman
         foreground = #000000
         background = #FFFFFF
         bordercolor = #000000
         borderwidth = 1px;

      style dataemphasis from dataemphasis /
         borderwidth = 3px
         bordercolor = #000000
         background = #99CCFF
         foreground = #000000
         font_style = Roman
         font_weight = BOLD
         font_size = 2
         font = ("Arial, Helvetica, Sans Serif");


       style Table from Table /
         font = ("Arial, Helvetica, Sans Serif")
         font_size = 2
         font_weight = medium
         font_style = roman
         foreground = #000000
         background = #000000
         borderwidth = 2px
         bordercolor = #000000
         cellspacing = 1px
        ;
   end;

run;

Chris
Business Analyst, Code Monkey, Data Wrangler.
SAS Guru.