shortcut menu with a grid on form 2

[EzLogic]

I have a grid, and in the right click method:

DEFINE POPUP shortcut SHORTCUT RELATIVE FROM MROW(),MCOL()
DEFINE BAR 1 OF shortcut PROMPT "Invoice Details" 
DEFINE BAR 2 OF shortcut PROMPT "Payment Details"
DEFINE BAR 3 OF shortcut PROMPT "Print Invoice"
ON SELECTION BAR 1 OF shortcut Thisform.ViewInvoice()
ON SELECTION BAR 2 OF shortcut Thisform.ViewPayment()
ON SELECTION BAR 3 OF shortcut Thisform.PrintInvoice()
ACTIVATE POPUP shortcut

I can't use Thisform.ViewInvoice() etc..

how to go arround that, i want to keep the method contained in the form and not create a function in my main.prg etc..

Ali Koumaiha
TeknoSoft Inc.
Michigan

 

[EzLogic]

Nevermind, i ended up doing this..

LOCAL lcCursor 
lcCursor = thisform.CurARMast 
IF EMPTY(lcCursor)
	RETURN
ENDIF 
SELECT (lcCursor)
IF EOF()
	RETURN
ENDIF 

DEFINE POPUP shortcut SHORTCUT RELATIVE FROM MROW(),MCOL()
DEFINE BAR 1 OF shortcut PROMPT "Invoice Details" 
DEFINE BAR 2 OF shortcut PROMPT "Payment Details"
DEFINE BAR 3 OF shortcut PROMPT "Print Invoice"
ON SELECTION BAR 1 OF shortcut do InvoiceMenu with 1,lcCursor 
ON SELECTION BAR 2 OF shortcut do InvoiceMenu with 2,lcCursor
ON SELECTION BAR 3 OF shortcut do InvoiceMenu with 3,lcCursor
ACTIVATE POPUP shortcut

Ali Koumaiha
TeknoSoft Inc.
Michigan

 

[Dan Freeman]

To answer your original question, though, replace Thisform with _Screen.Activeform in code that's not inside an object on the form.

 

[Mike Lewis]

Another solution is to store a reference to THISFORM in a private variable:

PRIVATE pcForm
pcForm = thisform
 ....
 ....
ON SELECTION BAR 1 OF shortcut pcForm.ViewInvoice()
 ....

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro articles, tips, training, consultancy

 

[EzLogic]

thanks guys.

worked like a charm.. the other method you guys suggested.

Ali Koumaiha
TeknoSoft Inc.
Michigan