set app icon with vba code 2

[Pampers]

Hi everyone,
I've got the next code in a closed thread by LarrySteele (Programmer) 20 Oct 06 12:11. He gives a function to set the application icon through code.

Access doesn't expose this property for VBA to use. You'll have to append the property if it's not already available, and you determine if the property's available by trapping for error 3270.

Here's a function I've used in the past:

Function ChangeProperty(strPropName As String, varPropType As String, varPropValue As Variant) As Integer

Dim dbs As DAO.Database
Dim prp As DAO.Property

Set dbs = CurrentDb
On Error GoTo PROC_ERROR

dbs.Properties(strPropName) = varPropValue
ChangeProperty = True

PROC_EXIT:
On Error Resume Next
Set prp = Nothing
Set dbs = Nothing
Exit Function

PROC_ERROR:
If Err.Number = 3270 Then
Set prp = dbs.CreateProperty(strPropName, varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
ChangeProperty = False
Resume PROC_EXIT
End If
End Function


To use this function to change the icon, I would have the following in my startup procedure:

ChangeProperty "AppIcon", dbText, Access.CurrentProject.Path & "Icon1.ico"
HTH,
Larry

I used Larry's code, no error but also no icon appearing. What am I doing wrong. This is the code I use in a form load (login screen).

ChangeProperty "AppIcon", dbText, Access.CurrentProject.Path & "daicon.ico"

Any ideas?




Pampers
Keeping it simple can be complicated

 

[Remou]

You will need a backslash. You will also need to refresh the titlebar.

ChangeProperty "AppIcon", dbText, Access.CurrentProject.Path & "[red]\[/red]daicon.ico

 

[TheAceMan1]

Howdy Pampers . . .

Try this:

[blue]Public Sub SetAppIcon(IconPath As String)
   Dim db As DAO.Database, prp As DAO.Property

On Error GoTo GotErr
   
   Set db = CurrentDb
   
   db.Properties("AppIcon") = IconPath 'Attempt to assign
   Application.RefreshTitleBar 'Update On Screen!

Exit Sub

GotErr:
   If Err.Number = 3270 Then 'property doesn't exist!
      Set prp = db.CreateProperty("AppIcon", dbText, IconPath)
      db.Properties.Append prp 'New property set!
   Else
      MsgBox "Error: " & Err.Number & vbCrLf & Err.Description
   End If
   
   Resume Next

End Sub[/blue]

See Ya! . . . . . .

Be sure to see thread181-473997
Also faq181-2886

 

[Pampers]

Hi guys,
Nice to hear from you again.
Both solutions work fine. Didn't know about the refresh title bar (and yes, forgot the backslash, tx remou).
Last question. If I want to set the icon also for forms and reports (the checkbox in the startup), how can I do that...

Pampers
Keeping it simple can be complicated

 

[Remou]

You will find a list here:

http://msdn2.microsoft.com/en-us/library/aa140020.aspx

 

[Pampers]

Tnx Remou,
Was looking for that page, seen it somewhere, but couldn't find it anymore. It is for MS Access 2000, and misses the checkbox to set the icon for all forms and reports...
Anyway, a pinky for the both.


Pampers
Keeping it simple can be complicated