Tek-Tips is the largest IT community on the Internet today!
Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!
-
Congratulations Westi on being selected by the Tek-Tips community for having the most helpful posts in the forums last week. Way to Go!
Script to define more than 200 TN on CS1000E 1
- Thread starter carota
- Start date
bigindian65
Technical User
search on this site - procom - JP and others have many threads of scripts
Mato' Was'aka
Mato' Was'aka
- Thread starter
- #4
i'll post a script tomorrow. post one tn for a i2050 so i can adjust it for your set type.. i perfer pulling my data from a comma delimited.. you'll need an excel with a col for tn key 0 key 1, des? just let me know what needs to be unique for each phone.. you can add names from the script if you want, i usually run a script in ld 95 later
john poole
bellsouth business
columbia,sc
john poole
bellsouth business
columbia,sc
-
1
- #6
Firebird Scrambler
Systems Engineer
Here is my script that I've used that now has 2 new prompts added in. Don't forget to copy the last part of the file as
a new file called VKEYS.INC and put it into your aspect folder along with this one.
; New Internet and 3903 to 3905 phones.was 8th Feb 2010
; NOTE!
; This program will ONLY work with a Windows version of PROCOMM PLUS!.
; This Procomm Script file is for you to configure a new Nortel digital extension
; The " ; " denotes that the data on this program script is ignored when the
; file is run.
; The script will also record for you a LOG file such as "pw01.cap" etc.
; The program will use LD 11 for all the changes & LD 81 to print out the TN's.
; Follow the instructions by Ticking the box's on the screen & locating your source file.
; You might need to change the "Transmit Pacing" depending on the software version!
; A higher number is needed to slow the program down for the older processors.
; Make sure that you enter the file name & click on "ACCEPT" to run in your entries.
; Make sure that you enter the Login Name (or Account name for V04.5x onwards!)&
; the Password & click on the "ACCEPT" button to run in your speed call entries.
; If your system does not use any Login name, then just enter any name or c/r in the box.
; You don't need to be LOGGED into the Meridian, before you run the script!.
; The program will still run on older software versions that don't use Named Login. It's
; best if log in first before the program is started. Just enter any name as mentioned above
; & wait 30 seconds before it will commence the input procedure.
; The data that needs to be used should be entered via Microsofts Excel application, using the columns
; as shown in the example. Once you have entered in the required settings, REMOVE the header
; (1st line of data & save the SOURCE file which should be in a *.CSV Format!
; An example of the source file as viewed in text, is shown below.
; NOTE!. Please check your Excel file before you save it to a *.csv format. Then also check it using
; a program such as "Notepad" for spaces with the CLS such as CFXA ,!. Make sure it's changed to
; i.e. CFXA,. Also add in a space for blank keys.i.e. keys 5 to 11 on the smaller 3903, 1120 or 2002 phones etc
; This should be as follows. , , , etc. NOT ,,,.
; You can use the find & replace options to make mass changes!.
; Examples of the different phone types used on a Succession system Version 5.xx
;TYPE, TN, DES ,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS ,RCO,EFD,HUNT,EHT,AST,IAPG,KEY 0,KEY 1,KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23,
;2001P2,065 0 00 21,2001P2,0,7000,0,2,101,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65001, , , , , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;2002P1,065 0 00 22,2002P1,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65002,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;2002P2,065 0 00 16,2002P2,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65008,ADL 12 907930941008,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
;2004P1,065 0 00 13,2004P1,0,7000,0,4,104,10,1111,CFHA,1,7000,7000,7000,0,0,SCR 65000,ADL 16 9472224,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2004P2,065 0 00 14,2004P2,0,7000,0,4,104,10,1111,CFHA,2,7000,7000,7000,0,0,SCR 65004,ADL 16 9833898,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2007,065 0 00 07,2007,0,7000,0,7,107,10,1111,CFHA USRA,0,7000,7000,7000,0,0,SCR 65007,ADL 16 9273889,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2050PC,065 0 00 15,2050PC,0,7000,0,1,150,10,1111,USRA,1,7000,7000,7000,0,0,SCR 65050,ADL 16 ,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4 7000,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;2033,065 0 00 30,2033,0,7000,1,4,2033,10,1111,FBA HFA CNIA DNDA PUA CFXA USRA,2,7000,7000,7000,0,0,SCR 65033, , , , , , , , , , , , ,CFW 5,RNP,SSU 10,
;1110,065 0 00 01,1110,0,7000,1,4,1110,10,1111,FBA CNIA DNDA PUA CFXA USRA,0,7000,7000,7000,0,0,SCR 65011 0, , , , , , , , , , , , ,CFW 10,RNP,SSU 10,
;1120,065 0 00 02,1120,0,74860,1,5,1120,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA USRA,0,74860,7000,7000,0,0,SCR 65012,SCN 4869 0,SCN 4857 0,MCR 4860 0, , , , , , , , , ,CFW 4 7000,RNP,SSU 10,
;1140,065 0 00 04,1140E,0,7100,1,6,1140,10,1111,FBA CRPA HFA CNIA DNDA VOLA VOUA CFXA,0,7100,7000,7000,0,0,SCR 65014,SSU 10,ADL 16,ADL 20,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16, ,CFW 5,RNP,SSU 10,
;1150,065 0 00 05,1150,0,7100,1,7,1150,10,1111,FBA CRPA HFA CNIA DNDA VOLA VOUA CFXA,0,7100,7000,7000,0,0,SCR 65015,SSU 10,ADL 16,ADL 20,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16, ,CFW 6 912345,RNP,SSU 10,
;2210,065 0 00 10,2210,0,7000,1,4,2210,10,1111,FBA CRPA HFA CNIA DNDA PUA USRA,0,7000,7000,7000,0,0,SCR 65010,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767, ,CFW 7,RNP,SSU 10,
;2211,065 0 00 11,2211,0,7000,1,4,2211,10,1111,FBA CRPA HFA CNIA DNDA PUA CFXA USRA,1,7000,7000,7000,0,0,SCR 65011,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767,MWK 7000,CFW 8,RNP,SSU 10,
;2212,065 0 00 12,2212,0,7000,1,4,2212,10,1111,FBA CRPA HFA CNIA DNDA PUA CFXA USRA,2,7000,7000,7000,0,0,SCR 65012,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767,MWK 7000,CFW 9,RNP,SSU 10,
;3903,008 0 00 03,M3903,0,7000,0,4,103,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65003,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;3904,008 0 00 04,M3904,0,7000,0,6,104,10,1111,AHA,1,7000,7000,7000,0,0,SCR 65004,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;3905,008 0 00 05,M3905,0,7000,0,4,105,10,1111,AHA USRA,2,7000,7000,7000,0,0,SCR 65005,ADL 16,USR,MSB,ADL 16,ADL 16, , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
; Examples of the different phone types used on the older Meridian 1 systems, Version 25.xx
;TYPE, TN, DES ,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS ,HUNT,AST,IAPG,KEY 0,KEY 1,KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23,
;I2002,065 0 00 02,I2002,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65002,ADL 16,ADL 16,ADL 16,ADL 16, , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;I2004,065 0 00 04,I2004,0,7000,0,4,104,10,1111,USRA,1,7000,7000,7000,0,0,SCR 65004,ADL 16 9472224,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;I2050,065 0 00 00,I2050,0,7000,0,4,150,10,1111,CFHA,2,7000,7000,7000,0,0,SCR 65050,ADL 16 9833898,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;3903,008 0 00 03,M3903,0,7000,0,4,103,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65003,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;3904,008 0 00 04,M3904,0,7000,0,6,104,10,1111,AHA,1,7000,7000,7000,0,0,SCR 65004,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;3905,008 0 00 05,M3905,0,7000,0,4,105,10,1111,AHA USRA,2,7000,7000,7000,0,0,SCR 65005,ADL 16,USR,MSB,ADL 16,ADL 16, , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
; If your source file (example below) has lines of data of this length or more, then the script will FAIL with a
; message of Error 1: Value out of range
; Please reduce the data for that line. e.g. a line of data that is too long is..
;1140,066 0 00 25,1140,0,74210,1,6,1421,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA ICRA,2,7000,74210,74210,0,0,SCR 4213 0,SCN 4212 0,SCN 4216 0,SCN 4218 0,SCN 4219 0,SCN 4222,ADL 8 4230,ADL 8 4019,ADL 8 5302,SCN 4211 0,SCN 4791 0,ADL 8, ,CFW 6,RNP,SSU 10 (262 CHARACTERS!)
; Trim the data down to e.g.
;1140,066 0 00 25,1140,0,74210,1,6,1421,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA ICRA,2,7000,74210,74210,0,0,SCR 4213 0,SCN 4212 0,SCN 4216 0,SCN 4218 0,SCN 4219 0,SCN 4222,ADL 8 4230,ADL 8 4019,ADL 8 5302,SCN 4211,SCN 4791,ADL 8, ,CFW 6,RNP,SSU 10
; Please be aware that this script to provide new Internet and 3903 to 3905 phones will NOT do any Add On Modules!
; Also it won't configure the Aries (2006,2008,2216,2616 etc) and Orion (3110,3310,3820) phones. It won't configure the basic Taurus 3901 3902 as they have different key layouts.
; To ensure smooth running of the script, make the TTY that you are using has "SCH" only!.
; This will prevent any system messages from appearing.
#include "vkeys.inc" ; You must have this file "vkeys.inc"
; located within the "Aspect" folder!
STRING F_Time
string s_opdata[33]
proc main
integer i_evt
integer i_rg2_chc = 3
integer i_rg5_chc = 6
integer i_tmp
integer i_ch
integer i_fch_tx_val
integer i_tx_val
integer i_p
long l_tot_no_lin
long l_lin_cnt
long l_prog_bar_op
long l_fi_sz0
long l_cur_fi_sz0
string s_fi_nm
string s_tx_list = "0,5,10,20,30,40,50,80,100,130,180,200,300,400,500"
string s_tx_item = "130"
string s_dir
string s_pwd
string s_userid
string s_time_start
string s_date_start
string s_progress
string s_prog_bar
string s_sce_lin
string s_fi_ext_item = "*.CSV"
;string s_type_list = "CHG,NEW,OUT"
;string s_type_item = "CHG"
string s_list_customer = "0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87"
string s_customer_item = "0"
string s_list_dcno = "1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87,88"
string s_dcno_item = "1"
dialogbox 0 13 17 476 332 11 "Nortel Procomm script file to add new Internet and 3903 to 3905 phones in LD 11. V01.1 29th May 2009"
groupbox 1 10 7 130 40 ""
radiogroup 2 i_rg2_chc
radiobutton 3 19 16 42 11 "NEW"
; radiobutton 4 19 32 42 11 "CHG"
endgroup
groupbox 41 10 46 130 60 ""
text 43 14 54 120 11 "Script CLass of Service defaults used " center
text 44 14 64 120 11 "TLD LNA CNDA MWA DPUA GPUA" center
text 26 14 74 120 11 "FNA HTA SFA CFTA HBTA" center
text 45 14 84 120 11 "Internet Phones Zone Number = 1" center
text 11 14 94 120 11 "TTY you are using = SCH only!" center
radiogroup 5 i_rg5_chc
radiobutton 6 87 16 50 11 "Digital"
; radiobutton 7 87 36 42 11 "IDC"
endgroup
;combobox 10 102 67 32 252 DROPDOWNLIST s_list_customer s_customer_item
; text 16 16 69 86 11 "Customer No Use up to 87" left
; combobox 9 102 88 32 238 DROPDOWNLIST s_list_dcno s_dcno_item
; text 8 17 90 84 9 "DCNO No Use up to 88" left
dirlistbox 12 55 176 85 94 "*.csv" SINGLE s_fi_nm 21 SORT
editbox 23 386 37 73 11 s_userid 11
editbox 13 386 53 74 11 s_pwd 16 MASKED
editbox 37 417 106 38 11 s_date_start 8
editbox 38 417 147 38 11 s_time_start 8
combobox 24 423 168 30 170 DROPDOWNLIST s_tx_list s_tx_item
dirpath 21 9 164 134 11 s_dir
pushbutton 14 16 118 40 13 "Accept"
pushbutton 15 90 118 40 13 "Cancel"
text 29 169 124 294 11 "If you want the program to Time start, then enter the time in 24Hr format in the box below" center
text 47 217 55 166 11 "Switch Password is Case Sensitive for V4.5 onwards" left
text 25 175 170 246 11 "Select the systems Transmit Pacing. User a higher number on older software!." left
text 22 190 38 190 11 "Name or User ID. (No Name = any character key pressed!)" left
text 34 167 147 248 11 "Pressing the (Space Bar) = Auto Start, or enter the start Time = e.g. 16:20:00 " left
text 35 167 211 290 26 " Please remember to check your capture file settings under the following headings's (Options, Data Options, Setup Files, Capture File Options, Control Options) to UNCHECK the box marked (Query for file name when capture is started)!. " left
text 33 168 240 288 16 " Click (OK) & (OK) again before starting this script program. This will make the script capture the information if the delayed Date / Time start function is used!. " left
text 36 169 82 294 11 "If you want the program to Date start, then enter the Date as e.g. 23/12/05 in the box below" center
text 31 169 106 248 11 "Pressing the (Space Bar) = Auto Start, or enter the required Date for it to run" left
text 39 419 138 34 9 "Hr:Mn:Sc" center
text 40 418 96 34 9 "Dy/Mh/Yr" center
text 32 178 19 282 11 "Enter the systems Login Name and Password in the box's below to run the script file" center
groupbox 49 165 3 302 68 ""
groupbox 50 164 71 304 91 ""
groupbox 51 1 155 146 120 ""
groupbox 52 1 2 146 150 ""
text 53 6 220 36 11 "Source file" left
text 54 6 230 36 11 "location" center
text 42 6 240 36 11 "= *.csv" center
text 55 154 268 300 11 "Data that will need configuring! Make sure all all columns are filled in and top row removed!" center
text 64 14 278 444 11 "TYPE,TN,DES,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS,RCO,EFD,HUNT,EHT,AST,IAPG,KEY 0,KEY 1," center
text 65 14 288 444 11 "KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23," center
text 66 2 298 470 11 "Example below = data used! Don't use Aries,Orion,3901,3902 phones or AOM modules etc. Also don't have ,, use , , check afterwards using notepad!" center
text 59 8 308 464 11 "2004P2,065 0 00 00,2004P2,0,7000,0,7,1,10,1111,FBA CRPA HFA CNIA VOLA VOUA CFXA,0,7000,7000,7000,0,0,SCR 65000,ADL 16 9833898," center
text 48 14 318 444 11 "ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10," center
groupbox 46 164 157 304 30 ""
text 56 168 193 290 16 " If you are planning to use the delayed start time / date function, then follow the instruction listed below " left
groupbox 57 164 183 304 78 ""
groupbox 63 10 107 128 34 ""
enddialog
while 1
dlgevent 0 i_evt
switch i_evt
case 0
if i_rg2_chc == 3
if nullstr s_date_start
disable dlgctrl 0 14
elseif nullstr s_time_start
disable dlgctrl 0 14
elseif nullstr s_userid
disable dlgctrl 0 14
elseif nullstr s_pwd
disable dlgctrl 0 14
elseif nullstr s_fi_nm
disable dlgctrl 0 14
else
enable dlgctrl 0 14
endif
endif
if i_rg2_chc == 4
if nullstr s_date_start
disable dlgctrl 0 14
elseif nullstr s_time_start
disable dlgctrl 0 14
elseif nullstr s_userid
disable dlgctrl 0 14
elseif nullstr s_pwd
disable dlgctrl 0 14
elseif nullstr s_fi_nm
disable dlgctrl 0 14
else
enable dlgctrl 0 14
endif
endif
endcase
case 5
if i_rg5_chc == 7
enable dlgctrl 0 8
enable dlgctrl 0 16
endif
if i_rg5_chc == 6
disable dlgctrl 0 8
disable dlgctrl 0 16
endif
endcase
case 13
strlen s_pwd i_tmp
if i_tmp < 4
usermsg "Password `"%s`"`n`nThis must be between 4-16 characters in length & it is case sEnsTivE on V04.50 onwards!" s_pwd
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 14
exitwhile
endcase
case 15
exitwhile
endcase
case 23
strlen s_userid i_tmp
if i_tmp < 1
usermsg "Name or UserID `"%s`"`n`nName can be up to 11 Characters. Otherwise enter a dummy name or press the Space Bar to accept the entry" s_userid
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 28
exitwhile
endcase
case 29
exitwhile
endcase
case 30
dlgupdate 0 24
endcase
case 37
strlen s_date_start i_tmp
if i_tmp < 1
usermsg "Start Date `"%s`"`n`nmust be 6 Numbers in length and with a (/) in between every 2 digits. or you can just press the Space Bar to leave the box blank to Auto Start the Listing program" s_date_start
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 38
strlen s_time_start i_tmp
if i_tmp < 1
usermsg "Start Time `"%s`"`n`nmust be 6 Numbers in length and with a
) in between every 2 digits. or you can just press the Space Bar to leave the box blank to Auto Start the Listing program" s_time_start
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
endswitch
endwhile
dlgdestroy 0 cancel
if i_evt != 14
exit
endif
if not fopen 0 s_fi_nm read
errormsg "Couldn't open file `"%s`"." s_fi_nm
else
cnt_no_fi_lines(i_ch,&l_tot_no_lin,&l_fi_sz0)
STATMSG "Waiting for the Digital set auto start date/time program to run. Make sure that auto capture is set correctly!"
fetch txpace i_fch_tx_val
atoi s_tx_item i_tx_val
strcat s_tx_item " ms"
set txpace i_tx_val
datetimestart(s_time_start,s_date_start)
logi(s_userid)
login(s_pwd)
STATMSG "The Digital set auto start date/time program has now started!"
ld_ovl_11(i_rg2_chc)
dialogbox 1 208 20 312 116 14 "New Internet and 3903 to 3905 phones progress status bar"
text 1 10 8 200 11 s_progress left
editbox 2 10 20 190 11 s_prog_bar
text 3 10 38 300 18 s_fi_nm left
text 4 212 20 58 11 "Transmit Pace ==" left
text 6 10 60 300 34 s_sce_lin left
text 5 276 20 34 11 s_tx_item left
text 7 14 98 270 11 "Make sure that the TTY you are using to run this script file has USER = SCH only!" center
enddialog
l_prog_bar_op = l_fi_sz0/40
while not feof 0
fgetc 0 i_ch
if not feof 0
ftell 0 l_cur_fi_sz0
if l_cur_fi_sz0 % l_prog_bar_op == 0
strcat s_prog_bar "#"
dlgupdate 1 2
endif
if i_ch == '`r'
loopwhile
endif
if i_ch == '`n'
l_lin_cnt++
strputc s_sce_lin i_p 0
if not nullstr s_sce_lin
get_opdata(s_sce_lin)
strfmt s_progress "Line %ld of %ld" l_lin_cnt l_tot_no_lin
dlgupdate 1 1
dlgupdate 1 6
s_sce_lin = ""
i_p = 0
send_opdata()
loopwhile
endif
endif
strputc s_sce_lin i_p i_ch
i_p++
endif
endwhile
; ex_ovl_11(s_customer_item)
ex_ovl_11()
logo ()
set txpace i_fch_tx_val
fclose 0
endif
dlgdestroy 1 cancel
endproc
proc get_opdata ;#####
param string s_sce_lin
strtok s_opdata[0] s_sce_lin "," ;TYPE
strtok s_opdata[1] s_sce_lin "," ;TN
strtok s_opdata[2] s_sce_lin "," ;DES
strtok s_opdata[3] s_sce_lin "," ;Customer Number
strtok s_opdata[4] s_sce_lin "," ;FDN
strtok s_opdata[5] s_sce_lin "," ;TGAR
strtok s_opdata[6] s_sce_lin "," ;NCOS
strtok s_opdata[7] s_sce_lin "," ;RNPG
strtok s_opdata[8] s_sce_lin "," ;SSU
strtok s_opdata[9] s_sce_lin "," ;SCPW
strtok s_opdata[10] s_sce_lin "," ;CLS
strtok s_opdata[11] s_sce_lin "," ;RCO
strtok s_opdata[12] s_sce_lin "," ;EFD
strtok s_opdata[13] s_sce_lin "," ;HUNT
strtok s_opdata[14] s_sce_lin "," ;EHT
strtok s_opdata[15] s_sce_lin "," ;AST
strtok s_opdata[16] s_sce_lin "," ;IAPG
strtok s_opdata[17] s_sce_lin "," ;KEY 0
strtok s_opdata[18] s_sce_lin "," ;KEY 1
strtok s_opdata[19] s_sce_lin "," ;KEY 2
strtok s_opdata[20] s_sce_lin "," ;KEY 3
strtok s_opdata[21] s_sce_lin "," ;KEY 4
strtok s_opdata[22] s_sce_lin "," ;KEY 5
strtok s_opdata[23] s_sce_lin "," ;KEY 6
strtok s_opdata[24] s_sce_lin "," ;KEY 7
strtok s_opdata[25] s_sce_lin "," ;KEY 8
strtok s_opdata[26] s_sce_lin "," ;KEY 9
strtok s_opdata[27] s_sce_lin "," ;KEY 10
strtok s_opdata[28] s_sce_lin "," ;KEY 11
strtok s_opdata[29] s_sce_lin "," ;KEY 16 MWK
strtok s_opdata[30] s_sce_lin "," ;KEY 19 CFW
strtok s_opdata[31] s_sce_lin "," ;KEY 22 RNP
strtok s_opdata[32] s_sce_lin "," ;KEY 23 SSU / SCC etc
endproc
proc send_opdata ;##### Sequence of changes and data input
; waitfor "TYPE"
txdc (s_opdata[0])
waitfor "TN "
txdc (s_opdata[1])
waitfor "DES "
txdc (s_opdata[2])
waitfor "CUST "
txdc (s_opdata[3])
waitfor "FDN "
txdc (s_opdata[4])
waitfor "TGAR "
txdc (s_opdata[5])
waitfor "NCOS "
txdc (s_opdata[6])
waitfor "RNPG "
txdc (s_opdata[7])
waitfor "SSU "
txdc (s_opdata[8])
waitfor "SCPW "
txdc (s_opdata[9])
waitfor "CLS "
transmit "TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA " ; #### Applies to all phones! ####
txdc (s_opdata[10])
waitfor "RCO "
txdc (s_opdata[11])
waitfor "EFD "
txdc (s_opdata[12])
waitfor "HUNT "
txdc (s_opdata[13])
waitfor "EHT "
txdc (s_opdata[14])
waitfor "AST "
txdc (s_opdata[15])
waitfor "IAPG "
txdc (s_opdata[16])
waitfor "KEY "
transmit "0 "
txdc (s_opdata[17])
waitfor "KEY "
transmit "1 "
txdc (s_opdata[18])
waitfor "KEY "
transmit "2 "
txdc (s_opdata[19])
waitfor "KEY "
transmit "3 "
txdc (s_opdata[20])
waitfor "KEY "
transmit "4 "
txdc (s_opdata[21])
waitfor "KEY "
transmit "5 "
txdc (s_opdata[22])
waitfor "KEY "
transmit "6 "
txdc (s_opdata[23])
waitfor "KEY "
transmit "7 "
txdc (s_opdata[24])
waitfor "KEY "
transmit "8 "
txdc (s_opdata[25])
waitfor "KEY "
transmit "9 "
txdc (s_opdata[26])
waitfor "KEY "
transmit "10 "
txdc (s_opdata[27])
waitfor "KEY "
transmit "11 "
txdc (s_opdata[28])
waitfor "KEY "
transmit "16 "
txdc (s_opdata[29])
waitfor "KEY "
transmit "19 "
txdc (s_opdata[30])
waitfor "KEY "
transmit "22 "
txdc (s_opdata[31])
waitfor "KEY "
transmit "23 "
txdc (s_opdata[32])
waitfor "KEY "
pause 1
txdc ("")
waitfor "REQ" forever
txdc ("NEW")
; else
; endif
endproc
proc cnt_no_fi_lines ;#####
param integer i_ch
param long l_tot_no_lin
param long l_fi_sz0
while not feof 0
fgetc 0 i_ch
if not feof 0
if i_ch == '`n'
l_tot_no_lin++
endif
endif
endwhile
ftell 0 l_fi_sz0
rewind 0
endproc
;proc txdt ;#####
;param string s_txs
;integer i_p = 0
;integer i_ch = -1
; strgetc s_txs i_P i_ch
; i_p++
; while i_ch != 0
; computc i_ch
; strgetc s_txs i_P i_ch
; i_P++
; endwhile
;endproc
proc txdc ;#####
param string s_txs
integer i_p = 0
integer i_ch = -1
strgetc s_txs i_P i_ch
i_p++
while i_ch != 0
computc i_ch
strgetc s_txs i_P i_ch
i_P++
endwhile
computc 13
endproc
proc ld_ovl_11 ;#####
param integer i_rg2_chc
Capture On
; In this area, enter in new prompts that have appeared when running this script using examples
; listed below. Different features & software versions will result in prompts that have not been
; spotted before.
WHEN TARGET 1 "OVL111 " CALL OVL111
WHEN TARGET 2 "OVL013 " CALL OVL013
WHEN TARGET 3 "CTYP " CALL CARR_RETURN
WHEN TARGET 4 "KEM " CALL CARR_RETURN
WHEN TARGET 5 "NUID " CALL CARR_RETURN
WHEN TARGET 6 "KBA " CALL CARR_RETURN
WHEN TARGET 7 "NHTN " CALL CARR_RETURN
WHEN TARGET 8 "DBA " CALL CARR_RETURN
WHEN TARGET 9 "ERL " CALL CARR_RETURN
WHEN TARGET 10 "ECL " CALL CARR_RETURN
WHEN TARGET 11 "LDN " CALL CARR_RETURN
WHEN TARGET 12 "XLST " CALL CARR_RETURN
WHEN TARGET 13 "SGRP " CALL CARR_RETURN
WHEN TARGET 14 "SFLT " CALL CARR_RETURN
WHEN TARGET 15 "CAC_MFC " CALL CARR_RETURN
WHEN TARGET 18 "LNRS " CALL CARR_RETURN
WHEN TARGET 19 "LHK " CALL CARR_RETURN
WHEN TARGET 20 "SCI " CALL CARR_RETURN
WHEN TARGET 21 "FCAR " CALL CARR_RETURN ; Release 6 prompt
WHEN TARGET 22 "PLEV " CALL PLEV_0
WHEN TARGET 24 "DANI " CALL CARR_RETURN
WHEN TARGET 25 "ITNA " CALL CARR_RETURN
WHEN TARGET 26 "PRI " CALL CARR_RETURN
WHEN TARGET 27 "MLWU_LANG " CALL CARR_RETURN
WHEN TARGET 28 "MLNG " CALL CARR_RETURN
WHEN TARGET 29 "DNDR " CALL CARR_RETURN
WHEN TARGET 30 " MARP ON" CALL MARP_NO
WHEN TARGET 31 " CPND " CALL CARR_RETURN
WHEN TARGET 32 " VMB " CALL CARR_RETURN
WHEN TARGET 40 "TEN " CALL CARR_RETURN
WHEN TARGET 41 "ECHG " CALL EASY_CHANGE
WHEN TARGET 42 "DATE " CALL CARR_RETURN
WHEN TARGET 43 "PAGE " CALL CARR_RETURN
WHEN TARGET 44 "NACT " CALL CARR_RETURN
WHEN TARGET 45 "ZONE " CALL ZONE_1
WHEN TARGET 46 "SCH0127 " CALL SCH0127
WHEN TARGET 47 "SCH0255 " CALL SCH0255
WHEN TARGET 48 "SCH0341 " CALL SCH0341
WHEN TARGET 49 "SCH0361 " CALL SCH0361
WHEN TARGET 50 "SCH0717 " CALL SCH0717
WHEN TARGET 51 "SCH0733 " CALL SCH0733
WHEN TARGET 55 "SCH1447 " CALL SCH1447
WHEN TARGET 56 "SCH1510 " CALL SCH1510
WHEN TARGET 57 "SCH1893 " CALL SCH1893
WHEN TARGET 58 "SCH3127 " CALL SCH3127
WHEN TARGET 59 "SCH3129 " CALL SCH3129
WHEN TARGET 60 "SCH3902 " CALL SCH3902
WHEN TARGET 61 "SCH5814 " CALL SCH5814
WHEN TARGET 62 "SCH6711 " CALL SCH6711
; WHEN TARGET 63 "SCH3127 " CALL SCH3127
; WHEN TARGET 64 "SCH6711 " CALL SCH6711
WHEN TARGET 81 "SCH8888 " CALL SCH8888
WHEN TARGET 82 "SCH8889 " CALL SCH8889
txdc ("****")
waitfor ">"
txdc ("LD 11") ; Start of access into LD 11
waitfor "REQ"
if i_rg2_chc == 3
txdc ("NEW")
else
txdc ("CHG")
endif
waitfor "TYPE"
STATMSG " Start of Progress status bar and new extensions to be provided in LD 11"
endproc
proc ex_ovl_11 ;##### Print out the sets in LD 81
;param string s_customer_item
pause 3
txdc ("")
txdc ("****")
waitfor ">"
txdc ("LD 81")
waitfor "REQ "
txdc ("LST")
waitfor "CUST "
txdc ("0")
; waitfor "DATE "
; txdc ("")
; waitfor "PAGE "
; txdc ("")
waitfor "DES "
txdc ("")
waitfor "FEAT "
txdc ("SETS")
waitfor "FEAT "
txdc ("")
waitfor "REQ "
txdc ("****")
waitfor ">"
Capture off
endproc
PROC DATETIMESTART
param string s_time_start
param string s_date_start
integer i_tmp
strlen s_date_start i_tmp
if i_tmp >5
strlen s_time_start i_tmp
if i_tmp <2
s_time_start = "00:10:00"
endif
endif
strlen s_time_start i_tmp
if i_tmp >5
strlen s_date_start i_tmp
if i_tmp <2
s_date_start = $DATE
endif
endif
Waituntil s_time_start s_date_start
endproc
Proc TTY_LOGIN
pause 3
txdc ("LOGI")
endproc
proc logi ;#####
param string s_userid
WHEN TARGET 0 "OVL014 " CALL OVL014
WHEN TARGET 1 "OVL428 " CALL OVL428
WHEN TARGET 2 "SCH0510 " CALL OVL014
WHEN TARGET 3 "OVL013 " CALL TTY_LOGIN
WHEN TARGET 5 "OVL111 " CALL OVL111
WHEN TARGET 6 "SCH0510 " CALL SCH0101
WHEN TARGET 7 "SCH101 " CALL SCH0101
transmit "LOGI "
; txdc ("LOGI ")
txdc (s_userid)
waitfor "PASS?"
endproc
proc login ;#####
param string s_pwd
txdc (s_pwd)
waitfor ">"
endproc
proc logo ;#####
txdc ("LOGO") ; Add on this line ";" to allow the program to remain logged in!.
F_Time=$TIME
statmsg "LD 11 New Digital Set script file has now been Completed`n`n at %s" F_TIME
usermsg "LD 11 New Digital Set script file is now Complete`n`n at %s" F_TIME
endproc
PROC PLEV_0
txdc ("0")
ENDPROC
PROC ZONE_1 ; ############# Change to Zone required! ############
txdc ("1")
ENDPROC
PROC CARR_RETURN
txdc ("")
ENDPROC
PROC EASY_CHANGE
pause 1
txdc ("NO")
ENDPROC
Proc OVL013
txdc ("****")
ENDPROC
PROC SCH0127
txdc ("****")
waitfor ">"
USERMSG "SCH0127. Script failed, due to the TN already exists on the system!"
exit
ENDPROC
PROC SCH0255
STATMSG "SCH0255. Illegal Hunt DN.!"
ENDPROC
PROC SCH0341
txdc ("TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA CFHA USRA")
pause 1
txdc ("0")
STATMSG "SCH0341. Unable to match input field with stored mnemonics.! attempting to use typical CLS values!"
ENDPROC
PROC SCH0361
STATMSG "SCH0361. Key number is not valid on this set type.!"
ENDPROC
PROC SCH0717
txdc ("****")
waitfor ">"
USERMSG "SCH0717. Script failed, due to a missing ACD DN in LD 23!"
exit
ENDPROC
PROC SCH0733
STATMSG "SCH0733. Unable to match input field with stored mnemonics.!"
ENDPROC
PROC SCH1447
STATMSG "SCH1447. Key 6 should be set as NUL on this 3905 Set. Redefining this key overrides the user's access to Directory.!"
ENDPROC
PROC SCH1510
txdc ("TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA CFHA USRA")
STATMSG "SCH1510. Invalid CLS input. Typical CLS settings for configuring this set are used.!"
ENDPROC
PROC SCH1893
txdc ("****")
waitfor ">"
USERMSG "SCH1893. Script failed. Corporate Directory not allowed for this set type!"
exit
ENDPROC
PROC SCH3127
txdc ("****")
waitfor ">"
STATMSG "SCH3127. Invalid AST key type. Only ACD, MCR, MCN, SCR and SCN key are supported.!"
ENDPROC
PROC SCH3129
STATMSG "SCH3129. This DN already has AST assigned and this TN is configured with CLS ICRD!"
ENDPROC
PROC SCH3902
STATMSG "SCH3902. Only one input field allowed.!"
ENDPROC
PROC SCH5814
STATMSG "SCH5814. A set cannot have USR key with USRD Class of Service.!"
ENDPROC
PROC SCH6711
txdc ("*")
STATMSG "SCH6711. No trailing blanks/spaces can be entered after the CLID entry.Enter {CR} after the CLID entry!"
ENDPROC
PROC SCH8888
STATMSG "SCH8888. The Station Control Password can only use digits 0-9. Check if SCPW was needed after script file has finished!."
ENDPROC
PROC SCH8889
waitfor "SCPW "
txdc ("")
pause 1
STATMSG "SCH8889. CEPT default does not match the password length defined in LD 15. Check if SCPW was needed after script file has finished!."
ENDPROC
PROC MARP_NO
txdc ("NO")
ENDPROC
PROC OVL014
STATMSG "Please wait 30 seconds as the TTY is already logged in!"
ENDPROC
PROC OVL111
txdc ("****")
waitfor ">"
USERMSG "Script failed, as the TTY user is NOT logged into the system!"
exit
ENDPROC
PROC OVL428
txdc ("****")
USERMSG "Script failed. The Login name & password combination is invalid. Check the password & login name & try again.! On software versions V04.5x onwards, check if the password uses case SeNSiTivItY!"
exit
ENDPROC
PROC SCH0101
pause 2
transmit "****^M"
waitfor ">"
STATMSG "Please wait 30 seconds as the TTY is already logged in!"
ENDPROC
; The information listed below has been taken from the "vkeys.inc" file.
; I have added in one ";" against each line for use with this file!.
; Should your copy of "vkeys.inc" be missing or damaged, then you can copy this
; section listed below with one of the ";" removed for each line!.
;;Definitions of standard virtual key code values
;;**********************************************************************
;;* VKEYS.INC
;;* Copyright (c) 1999 Symantec Corporation
;;*
;;* Definitions of standard virtual key code values. Use these macro
;;* definitions in your ASPECT script files rather than hard-coded
;;* constants to improve maintainability and readability. For more
;;* information, see the keyval and vkey conventions described in the
;;* Windows ASPECT Script Language reference manual.
;;**********************************************************************
;#ifndef _INC_VKEYS ; if file not already included
;#define _INC_VKEYS ; prevent further inclusion
;;**********************************************************************
;;* Macro definitions of standard virtual key code values
;;**********************************************************************
;#define VK_LBUTTON 0x01 ; Left mouse button
;#define VK_RBUTTON 0x02 ; Right mouse button
;#define VK_CANCEL 0x03 ; Ctrl-Break
;#define VK_MBUTTON 0x04 ; Middle mouse button
;; 0x05-0x07 ; Undefined
;#define VK_BACK 0x08 ; Backspace key
;#define VK_TAB 0x09 ; Tab key
;; 0x0A-0x0B ; Undefined
;#define VK_CLEAR 0x0C ; Clear key or Keypad 5 with Num lock off
;#define VK_RETURN 0x0D ; Enter or Return key
;; 0x0E-0x0F ; Undefined
;#define VK_SHIFT 0x10 ; Shift key
;#define VK_CONTROL 0x11 ; Control or Ctrl key
;#define VK_MENU 0x12 ; Menu or Alt key
;#define VK_PAUSE 0x13 ; Pause key
;#define VK_CAPITAL 0x14 ; Capital or Caps Lock key
;; 0x15-0x19 ; Reserved for Kanji Systems
;; 0x1A ; Undefined
;#define VK_ESCAPE 0x1B ; Esc or Escape key
;; 0x1C-0x1F ; Reserved for Kanji Systems
;#define VK_SPACE 0x20 ; Spacebar
;#define VK_PRIOR 0x21 ; Page Up key
;#define VK_NEXT 0x22 ; Page Down key
;#define VK_END 0x23 ; End key
;#define VK_HOME 0x24 ; Home key
;#define VK_LEFT 0x25 ; Left arrow key
;#define VK_UP 0x26 ; Up Arrow key
;#define VK_RIGHT 0x27 ; Right Arrow key
;#define VK_DOWN 0x28 ; Down Arrow key
;#define VK_SELECT 0x29 ; Select key
;#define VK_PRINT 0x2A ; Keyboard (OEM) specific
;#define VK_EXECUTE 0x2B ; Execute key
;#define VK_SNAPSHOT 0x2C ; Print Screen key
;#define VK_INSERT 0x2D ; Insert key
;#define VK_DELETE 0x2E ; Delete key
;#define VK_HELP 0x2F ; Help key
;#define VK_0 0x30 ; 0 key
;#define VK_1 0x31 ; 1 key
;#define VK_2 0x32 ; 2 key
;#define VK_3 0x33 ; 3 key
;#define VK_4 0x34 ; 4 key
;#define VK_5 0x35 ; 5 key
;#define VK_6 0x36 ; 6 key
;#define VK_7 0x37 ; 7 key
;#define VK_8 0x38 ; 8 key
;#define VK_9 0x39 ; 9 key
;; 0x3A-0x40 ; Undefined
;#define VK_A 0x41 ; A key
;#define VK_B 0x42 ; B key
;#define VK_C 0x43 ; C key
;#define VK_D 0x44 ; D key
;#define VK_E 0x45 ; E key
;#define VK_F 0x46 ; F key
;#define VK_G 0x47 ; G key
;#define VK_H 0x48 ; H key
;#define VK_I 0x49 ; I key
;#define VK_J 0x4A ; J key
;#define VK_K 0x4B ; K key
;#define VK_L 0x4C ; L key
;#define VK_M 0x4D ; M key
;#define VK_N 0x4E ; N key
;#define VK_O 0x4F ; O key
;#define VK_P 0x50 ; P key
;#define VK_Q 0x51 ; Q key
;#define VK_R 0x52 ; R key
;#define VK_S 0x53 ; S key
;#define VK_T 0x54 ; T key
;#define VK_U 0x55 ; U key
;#define VK_V 0x56 ; V key
;#define VK_W 0x57 ; W key
;#define VK_X 0x58 ; X key
;#define VK_Y 0x59 ; Y key
;#define VK_Z 0x5A ; Z key
;#define VK_WINDOWSL 0x5B ; Windows key (left)
;#define VK_WINDOWSR 0x5C ; Windows key (right)
;#define VK_APPLICATION 0x5D ; Application key
;; 0x5E-0x5F ; Undefined
;#define VK_NUMPAD0 0x60 ; Numeric Keypad 0
;#define VK_NUMPAD1 0x61 ; Numeric Keypad 1
;#define VK_NUMPAD2 0x62 ; Numeric Keypad 2
;#define VK_NUMPAD3 0x63 ; Numeric Keypad 3
;#define VK_NUMPAD4 0x64 ; Numeric Keypad 4
;#define VK_NUMPAD5 0x65 ; Numeric Keypad 5
;#define VK_NUMPAD6 0x66 ; Numeric Keypad 6
;#define VK_NUMPAD7 0x67 ; Numeric Keypad 7
;#define VK_NUMPAD8 0x68 ; Numeric Keypad 8
;#define VK_NUMPAD9 0x69 ; Numeric Keypad 9
;#define VK_MULTIPLY 0x6A ; Multiply key
;#define VK_ADD 0x6B ; Add key
;#define VK_SEPARATOR 0x6C ; Separator key
;#define VK_SUBTRACT 0x6D ; Subtract key
;#define VK_DECIMAL 0x6E ; Decimal key
;#define VK_DIVIDE 0x6F ; Divide key
;#define VK_F1 0x70 ; Function key F1
;#define VK_F2 0x71 ; Function key F2
;#define VK_F3 0x72 ; Function key F3
;#define VK_F4 0x73 ; Function key F4
;#define VK_F5 0x74 ; Function key F5
;#define VK_F6 0x75 ; Function key F6
;#define VK_F7 0x76 ; Function key F7
;#define VK_F8 0x77 ; Function key F8
;#define VK_F9 0x78 ; Function key F9
;#define VK_F10 0x79 ; Function key F10
;#define VK_F11 0x7A ; Function key F11
;#define VK_F12 0x7B ; Function key F12
;#define VK_F13 0x7C ; Function key F13
;#define VK_F14 0x7D ; Function key F14
;#define VK_F15 0x7E ; Function key F15
;#define VK_F16 0x7F ; Function key F16
;#define VK_F17 0x80 ; Function key F17
;#define VK_F18 0x81 ; Function key F18
;#define VK_F19 0x82 ; Function key F19
;#define VK_F20 0x83 ; Function key F20
;#define VK_F21 0x84 ; Function key F21
;#define VK_F22 0x85 ; Function key F22
;#define VK_F23 0x86 ; Function key F23
;#define VK_F24 0x87 ; Function key F24
;; 0x88-0x8F ; Unassigned
;#define VK_NUMLOCK 0x90 ; Num Lock key
;#define VK_OEM_SCROLL 0x91 ; Scroll Lock key
;; 0x92-0xB9 ; Unassigned
;; 0xBA-0xC0 ; Keyboard (OEM) specific
;; 0xC1-0xDA ; Unassigned
;; 0xDB-0xE4 ; Keyboard (OEM) specific
;; 0xE5 ; Unassigned
;; 0xE6 ; Keyboard (OEM) specific
;; 0xE7-0xE8 ; Unassigned
;; 0xE9-0xF5 ; Keyboard (OEM) specific
;; 0xF6-0xFE ; Unassigned
;;**********************************************************************
;;* Useful macros for testing and forming key values from keyboard
;;* shift states and virtual key code values.
;;**********************************************************************
;#define KV_SHIFT 0x01 ; Shift key pressed
;#define KV_CTRL 0x02 ; Ctrl key pressed
;#define KV_ALT 0x04 ; Alt key pressed
;#define KV_EXT 0x08 ; Extended key flag
;#define KV_CAPSLOCK 0x10 ; Caps Lock key toggled on
;#define MAKE_KV(skeys,vkey) (((skeys) << 8) | (vkey))
;#define KV_VKEY(keyval) ((keyval) & 0xFF)
;#define KV_SKEYS(keyval) ((keyval) >> 8)
;#define KV_SHIFTKEY(keyval) (KV_SKEYS(keyval) & KV_SHIFT)
;#define KV_CTRLKEY(keyval) (KV_SKEYS(keyval) & KV_CTRL)
;#define KV_ALTKEY(keyval) (KV_SKEYS(keyval) & KV_ALT)
;#define KV_EXTKEY(keyval) (KV_SKEYS(keyval) & KV_EXT)
;#endif ; _INC_VKEYS
All the best
Firebird Scrambler
Meridian Programmer in the UK
If it's working, then leave it alone!.
a new file called VKEYS.INC and put it into your aspect folder along with this one.
; New Internet and 3903 to 3905 phones.was 8th Feb 2010
; NOTE!
; This program will ONLY work with a Windows version of PROCOMM PLUS!.
; This Procomm Script file is for you to configure a new Nortel digital extension
; The " ; " denotes that the data on this program script is ignored when the
; file is run.
; The script will also record for you a LOG file such as "pw01.cap" etc.
; The program will use LD 11 for all the changes & LD 81 to print out the TN's.
; Follow the instructions by Ticking the box's on the screen & locating your source file.
; You might need to change the "Transmit Pacing" depending on the software version!
; A higher number is needed to slow the program down for the older processors.
; Make sure that you enter the file name & click on "ACCEPT" to run in your entries.
; Make sure that you enter the Login Name (or Account name for V04.5x onwards!)&
; the Password & click on the "ACCEPT" button to run in your speed call entries.
; If your system does not use any Login name, then just enter any name or c/r in the box.
; You don't need to be LOGGED into the Meridian, before you run the script!.
; The program will still run on older software versions that don't use Named Login. It's
; best if log in first before the program is started. Just enter any name as mentioned above
; & wait 30 seconds before it will commence the input procedure.
; The data that needs to be used should be entered via Microsofts Excel application, using the columns
; as shown in the example. Once you have entered in the required settings, REMOVE the header
; (1st line of data & save the SOURCE file which should be in a *.CSV Format!
; An example of the source file as viewed in text, is shown below.
; NOTE!. Please check your Excel file before you save it to a *.csv format. Then also check it using
; a program such as "Notepad" for spaces with the CLS such as CFXA ,!. Make sure it's changed to
; i.e. CFXA,. Also add in a space for blank keys.i.e. keys 5 to 11 on the smaller 3903, 1120 or 2002 phones etc
; This should be as follows. , , , etc. NOT ,,,.
; You can use the find & replace options to make mass changes!.
; Examples of the different phone types used on a Succession system Version 5.xx
;TYPE, TN, DES ,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS ,RCO,EFD,HUNT,EHT,AST,IAPG,KEY 0,KEY 1,KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23,
;2001P2,065 0 00 21,2001P2,0,7000,0,2,101,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65001, , , , , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;2002P1,065 0 00 22,2002P1,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65002,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;2002P2,065 0 00 16,2002P2,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65008,ADL 12 907930941008,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
;2004P1,065 0 00 13,2004P1,0,7000,0,4,104,10,1111,CFHA,1,7000,7000,7000,0,0,SCR 65000,ADL 16 9472224,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2004P2,065 0 00 14,2004P2,0,7000,0,4,104,10,1111,CFHA,2,7000,7000,7000,0,0,SCR 65004,ADL 16 9833898,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2007,065 0 00 07,2007,0,7000,0,7,107,10,1111,CFHA USRA,0,7000,7000,7000,0,0,SCR 65007,ADL 16 9273889,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;2050PC,065 0 00 15,2050PC,0,7000,0,1,150,10,1111,USRA,1,7000,7000,7000,0,0,SCR 65050,ADL 16 ,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4 7000,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;2033,065 0 00 30,2033,0,7000,1,4,2033,10,1111,FBA HFA CNIA DNDA PUA CFXA USRA,2,7000,7000,7000,0,0,SCR 65033, , , , , , , , , , , , ,CFW 5,RNP,SSU 10,
;1110,065 0 00 01,1110,0,7000,1,4,1110,10,1111,FBA CNIA DNDA PUA CFXA USRA,0,7000,7000,7000,0,0,SCR 65011 0, , , , , , , , , , , , ,CFW 10,RNP,SSU 10,
;1120,065 0 00 02,1120,0,74860,1,5,1120,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA USRA,0,74860,7000,7000,0,0,SCR 65012,SCN 4869 0,SCN 4857 0,MCR 4860 0, , , , , , , , , ,CFW 4 7000,RNP,SSU 10,
;1140,065 0 00 04,1140E,0,7100,1,6,1140,10,1111,FBA CRPA HFA CNIA DNDA VOLA VOUA CFXA,0,7100,7000,7000,0,0,SCR 65014,SSU 10,ADL 16,ADL 20,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16, ,CFW 5,RNP,SSU 10,
;1150,065 0 00 05,1150,0,7100,1,7,1150,10,1111,FBA CRPA HFA CNIA DNDA VOLA VOUA CFXA,0,7100,7000,7000,0,0,SCR 65015,SSU 10,ADL 16,ADL 20,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16, ,CFW 6 912345,RNP,SSU 10,
;2210,065 0 00 10,2210,0,7000,1,4,2210,10,1111,FBA CRPA HFA CNIA DNDA PUA USRA,0,7000,7000,7000,0,0,SCR 65010,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767, ,CFW 7,RNP,SSU 10,
;2211,065 0 00 11,2211,0,7000,1,4,2211,10,1111,FBA CRPA HFA CNIA DNDA PUA CFXA USRA,1,7000,7000,7000,0,0,SCR 65011,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767,MWK 7000,CFW 8,RNP,SSU 10,
;2212,065 0 00 12,2212,0,7000,1,4,2212,10,1111,FBA CRPA HFA CNIA DNDA PUA CFXA USRA,2,7000,7000,7000,0,0,SCR 65012,ADL 8 7000,USR,ADL 4,ADL 6,ADL 8,ADL 4,ADL 5,ADL 6,ADL 7,ADL 4,ADL 8 76767,MWK 7000,CFW 9,RNP,SSU 10,
;3903,008 0 00 03,M3903,0,7000,0,4,103,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65003,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;3904,008 0 00 04,M3904,0,7000,0,6,104,10,1111,AHA,1,7000,7000,7000,0,0,SCR 65004,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;3905,008 0 00 05,M3905,0,7000,0,4,105,10,1111,AHA USRA,2,7000,7000,7000,0,0,SCR 65005,ADL 16,USR,MSB,ADL 16,ADL 16, , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
; Examples of the different phone types used on the older Meridian 1 systems, Version 25.xx
;TYPE, TN, DES ,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS ,HUNT,AST,IAPG,KEY 0,KEY 1,KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23,
;I2002,065 0 00 02,I2002,0,7000,0,2,102,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65002,ADL 16,ADL 16,ADL 16,ADL 16, , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;I2004,065 0 00 04,I2004,0,7000,0,4,104,10,1111,USRA,1,7000,7000,7000,0,0,SCR 65004,ADL 16 9472224,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;I2050,065 0 00 00,I2050,0,7000,0,4,150,10,1111,CFHA,2,7000,7000,7000,0,0,SCR 65050,ADL 16 9833898,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10,
;3903,008 0 00 03,M3903,0,7000,0,4,103,10,1111,AHA,0,7000,7000,7000,0,0,SCR 65003,ADL 16,ADL 16,ADL 16, , , , , , , , ,MWK 7000,CFW 6,RNP,SSU 10,
;3904,008 0 00 04,M3904,0,7000,0,6,104,10,1111,AHA,1,7000,7000,7000,0,0,SCR 65004,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 6,RNP,SSU 10,
;3905,008 0 00 05,M3905,0,7000,0,4,105,10,1111,AHA USRA,2,7000,7000,7000,0,0,SCR 65005,ADL 16,USR,MSB,ADL 16,ADL 16, , , , , , ,MWK 7000,CFW 4,RNP,SSU 10,
; If your source file (example below) has lines of data of this length or more, then the script will FAIL with a
; message of Error 1: Value out of range
; Please reduce the data for that line. e.g. a line of data that is too long is..
;1140,066 0 00 25,1140,0,74210,1,6,1421,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA ICRA,2,7000,74210,74210,0,0,SCR 4213 0,SCN 4212 0,SCN 4216 0,SCN 4218 0,SCN 4219 0,SCN 4222,ADL 8 4230,ADL 8 4019,ADL 8 5302,SCN 4211 0,SCN 4791 0,ADL 8, ,CFW 6,RNP,SSU 10 (262 CHARACTERS!)
; Trim the data down to e.g.
;1140,066 0 00 25,1140,0,74210,1,6,1421,10,1111,FBA CRPA HFA CNIA DNDA PUA VOLA VOUA CFXA ICRA,2,7000,74210,74210,0,0,SCR 4213 0,SCN 4212 0,SCN 4216 0,SCN 4218 0,SCN 4219 0,SCN 4222,ADL 8 4230,ADL 8 4019,ADL 8 5302,SCN 4211,SCN 4791,ADL 8, ,CFW 6,RNP,SSU 10
; Please be aware that this script to provide new Internet and 3903 to 3905 phones will NOT do any Add On Modules!
; Also it won't configure the Aries (2006,2008,2216,2616 etc) and Orion (3110,3310,3820) phones. It won't configure the basic Taurus 3901 3902 as they have different key layouts.
; To ensure smooth running of the script, make the TTY that you are using has "SCH" only!.
; This will prevent any system messages from appearing.
#include "vkeys.inc" ; You must have this file "vkeys.inc"
; located within the "Aspect" folder!
STRING F_Time
string s_opdata[33]
proc main
integer i_evt
integer i_rg2_chc = 3
integer i_rg5_chc = 6
integer i_tmp
integer i_ch
integer i_fch_tx_val
integer i_tx_val
integer i_p
long l_tot_no_lin
long l_lin_cnt
long l_prog_bar_op
long l_fi_sz0
long l_cur_fi_sz0
string s_fi_nm
string s_tx_list = "0,5,10,20,30,40,50,80,100,130,180,200,300,400,500"
string s_tx_item = "130"
string s_dir
string s_pwd
string s_userid
string s_time_start
string s_date_start
string s_progress
string s_prog_bar
string s_sce_lin
string s_fi_ext_item = "*.CSV"
;string s_type_list = "CHG,NEW,OUT"
;string s_type_item = "CHG"
string s_list_customer = "0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87"
string s_customer_item = "0"
string s_list_dcno = "1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87,88"
string s_dcno_item = "1"
dialogbox 0 13 17 476 332 11 "Nortel Procomm script file to add new Internet and 3903 to 3905 phones in LD 11. V01.1 29th May 2009"
groupbox 1 10 7 130 40 ""
radiogroup 2 i_rg2_chc
radiobutton 3 19 16 42 11 "NEW"
; radiobutton 4 19 32 42 11 "CHG"
endgroup
groupbox 41 10 46 130 60 ""
text 43 14 54 120 11 "Script CLass of Service defaults used " center
text 44 14 64 120 11 "TLD LNA CNDA MWA DPUA GPUA" center
text 26 14 74 120 11 "FNA HTA SFA CFTA HBTA" center
text 45 14 84 120 11 "Internet Phones Zone Number = 1" center
text 11 14 94 120 11 "TTY you are using = SCH only!" center
radiogroup 5 i_rg5_chc
radiobutton 6 87 16 50 11 "Digital"
; radiobutton 7 87 36 42 11 "IDC"
endgroup
;combobox 10 102 67 32 252 DROPDOWNLIST s_list_customer s_customer_item
; text 16 16 69 86 11 "Customer No Use up to 87" left
; combobox 9 102 88 32 238 DROPDOWNLIST s_list_dcno s_dcno_item
; text 8 17 90 84 9 "DCNO No Use up to 88" left
dirlistbox 12 55 176 85 94 "*.csv" SINGLE s_fi_nm 21 SORT
editbox 23 386 37 73 11 s_userid 11
editbox 13 386 53 74 11 s_pwd 16 MASKED
editbox 37 417 106 38 11 s_date_start 8
editbox 38 417 147 38 11 s_time_start 8
combobox 24 423 168 30 170 DROPDOWNLIST s_tx_list s_tx_item
dirpath 21 9 164 134 11 s_dir
pushbutton 14 16 118 40 13 "Accept"
pushbutton 15 90 118 40 13 "Cancel"
text 29 169 124 294 11 "If you want the program to Time start, then enter the time in 24Hr format in the box below" center
text 47 217 55 166 11 "Switch Password is Case Sensitive for V4.5 onwards" left
text 25 175 170 246 11 "Select the systems Transmit Pacing. User a higher number on older software!." left
text 22 190 38 190 11 "Name or User ID. (No Name = any character key pressed!)" left
text 34 167 147 248 11 "Pressing the (Space Bar) = Auto Start, or enter the start Time = e.g. 16:20:00 " left
text 35 167 211 290 26 " Please remember to check your capture file settings under the following headings's (Options, Data Options, Setup Files, Capture File Options, Control Options) to UNCHECK the box marked (Query for file name when capture is started)!. " left
text 33 168 240 288 16 " Click (OK) & (OK) again before starting this script program. This will make the script capture the information if the delayed Date / Time start function is used!. " left
text 36 169 82 294 11 "If you want the program to Date start, then enter the Date as e.g. 23/12/05 in the box below" center
text 31 169 106 248 11 "Pressing the (Space Bar) = Auto Start, or enter the required Date for it to run" left
text 39 419 138 34 9 "Hr:Mn:Sc" center
text 40 418 96 34 9 "Dy/Mh/Yr" center
text 32 178 19 282 11 "Enter the systems Login Name and Password in the box's below to run the script file" center
groupbox 49 165 3 302 68 ""
groupbox 50 164 71 304 91 ""
groupbox 51 1 155 146 120 ""
groupbox 52 1 2 146 150 ""
text 53 6 220 36 11 "Source file" left
text 54 6 230 36 11 "location" center
text 42 6 240 36 11 "= *.csv" center
text 55 154 268 300 11 "Data that will need configuring! Make sure all all columns are filled in and top row removed!" center
text 64 14 278 444 11 "TYPE,TN,DES,CUST,FDN,TGAR,NCOS,RNPG,SSU,SCPW,CLS,RCO,EFD,HUNT,EHT,AST,IAPG,KEY 0,KEY 1," center
text 65 14 288 444 11 "KEY 2,KEY 3,KEY 4,KEY 5,KEY 6,KEY 7,KEY 8,KEY 9,KEY 10,KEY 11,KEY 16,KEY 19,KEY 22,KEY 23," center
text 66 2 298 470 11 "Example below = data used! Don't use Aries,Orion,3901,3902 phones or AOM modules etc. Also don't have ,, use , , check afterwards using notepad!" center
text 59 8 308 464 11 "2004P2,065 0 00 00,2004P2,0,7000,0,7,1,10,1111,FBA CRPA HFA CNIA VOLA VOUA CFXA,0,7000,7000,7000,0,0,SCR 65000,ADL 16 9833898," center
text 48 14 318 444 11 "ADL 16,ADL 16,ADL 16,ADL 16,ADL 16,ADL 4,ADL 4,ADL 4,ADL 4,ADL 16,MWK 7000,CFW 12,RNP,SSU 10," center
groupbox 46 164 157 304 30 ""
text 56 168 193 290 16 " If you are planning to use the delayed start time / date function, then follow the instruction listed below " left
groupbox 57 164 183 304 78 ""
groupbox 63 10 107 128 34 ""
enddialog
while 1
dlgevent 0 i_evt
switch i_evt
case 0
if i_rg2_chc == 3
if nullstr s_date_start
disable dlgctrl 0 14
elseif nullstr s_time_start
disable dlgctrl 0 14
elseif nullstr s_userid
disable dlgctrl 0 14
elseif nullstr s_pwd
disable dlgctrl 0 14
elseif nullstr s_fi_nm
disable dlgctrl 0 14
else
enable dlgctrl 0 14
endif
endif
if i_rg2_chc == 4
if nullstr s_date_start
disable dlgctrl 0 14
elseif nullstr s_time_start
disable dlgctrl 0 14
elseif nullstr s_userid
disable dlgctrl 0 14
elseif nullstr s_pwd
disable dlgctrl 0 14
elseif nullstr s_fi_nm
disable dlgctrl 0 14
else
enable dlgctrl 0 14
endif
endif
endcase
case 5
if i_rg5_chc == 7
enable dlgctrl 0 8
enable dlgctrl 0 16
endif
if i_rg5_chc == 6
disable dlgctrl 0 8
disable dlgctrl 0 16
endif
endcase
case 13
strlen s_pwd i_tmp
if i_tmp < 4
usermsg "Password `"%s`"`n`nThis must be between 4-16 characters in length & it is case sEnsTivE on V04.50 onwards!" s_pwd
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 14
exitwhile
endcase
case 15
exitwhile
endcase
case 23
strlen s_userid i_tmp
if i_tmp < 1
usermsg "Name or UserID `"%s`"`n`nName can be up to 11 Characters. Otherwise enter a dummy name or press the Space Bar to accept the entry" s_userid
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 28
exitwhile
endcase
case 29
exitwhile
endcase
case 30
dlgupdate 0 24
endcase
case 37
strlen s_date_start i_tmp
if i_tmp < 1
usermsg "Start Date `"%s`"`n`nmust be 6 Numbers in length and with a (/) in between every 2 digits. or you can just press the Space Bar to leave the box blank to Auto Start the Listing program" s_date_start
sendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
case 38
strlen s_time_start i_tmp
if i_tmp < 1
usermsg "Start Time `"%s`"`n`nmust be 6 Numbers in length and with a
) in between every 2 digits. or you can just press the Space Bar to leave the box blank to Auto Start the Listing program" s_time_startsendvkey MAKE_KV(KV_SHIFT,VK_TAB)
endif
endcase
endswitch
endwhile
dlgdestroy 0 cancel
if i_evt != 14
exit
endif
if not fopen 0 s_fi_nm read
errormsg "Couldn't open file `"%s`"." s_fi_nm
else
cnt_no_fi_lines(i_ch,&l_tot_no_lin,&l_fi_sz0)
STATMSG "Waiting for the Digital set auto start date/time program to run. Make sure that auto capture is set correctly!"
fetch txpace i_fch_tx_val
atoi s_tx_item i_tx_val
strcat s_tx_item " ms"
set txpace i_tx_val
datetimestart(s_time_start,s_date_start)
logi(s_userid)
login(s_pwd)
STATMSG "The Digital set auto start date/time program has now started!"
ld_ovl_11(i_rg2_chc)
dialogbox 1 208 20 312 116 14 "New Internet and 3903 to 3905 phones progress status bar"
text 1 10 8 200 11 s_progress left
editbox 2 10 20 190 11 s_prog_bar
text 3 10 38 300 18 s_fi_nm left
text 4 212 20 58 11 "Transmit Pace ==" left
text 6 10 60 300 34 s_sce_lin left
text 5 276 20 34 11 s_tx_item left
text 7 14 98 270 11 "Make sure that the TTY you are using to run this script file has USER = SCH only!" center
enddialog
l_prog_bar_op = l_fi_sz0/40
while not feof 0
fgetc 0 i_ch
if not feof 0
ftell 0 l_cur_fi_sz0
if l_cur_fi_sz0 % l_prog_bar_op == 0
strcat s_prog_bar "#"
dlgupdate 1 2
endif
if i_ch == '`r'
loopwhile
endif
if i_ch == '`n'
l_lin_cnt++
strputc s_sce_lin i_p 0
if not nullstr s_sce_lin
get_opdata(s_sce_lin)
strfmt s_progress "Line %ld of %ld" l_lin_cnt l_tot_no_lin
dlgupdate 1 1
dlgupdate 1 6
s_sce_lin = ""
i_p = 0
send_opdata()
loopwhile
endif
endif
strputc s_sce_lin i_p i_ch
i_p++
endif
endwhile
; ex_ovl_11(s_customer_item)
ex_ovl_11()
logo ()
set txpace i_fch_tx_val
fclose 0
endif
dlgdestroy 1 cancel
endproc
proc get_opdata ;#####
param string s_sce_lin
strtok s_opdata[0] s_sce_lin "," ;TYPE
strtok s_opdata[1] s_sce_lin "," ;TN
strtok s_opdata[2] s_sce_lin "," ;DES
strtok s_opdata[3] s_sce_lin "," ;Customer Number
strtok s_opdata[4] s_sce_lin "," ;FDN
strtok s_opdata[5] s_sce_lin "," ;TGAR
strtok s_opdata[6] s_sce_lin "," ;NCOS
strtok s_opdata[7] s_sce_lin "," ;RNPG
strtok s_opdata[8] s_sce_lin "," ;SSU
strtok s_opdata[9] s_sce_lin "," ;SCPW
strtok s_opdata[10] s_sce_lin "," ;CLS
strtok s_opdata[11] s_sce_lin "," ;RCO
strtok s_opdata[12] s_sce_lin "," ;EFD
strtok s_opdata[13] s_sce_lin "," ;HUNT
strtok s_opdata[14] s_sce_lin "," ;EHT
strtok s_opdata[15] s_sce_lin "," ;AST
strtok s_opdata[16] s_sce_lin "," ;IAPG
strtok s_opdata[17] s_sce_lin "," ;KEY 0
strtok s_opdata[18] s_sce_lin "," ;KEY 1
strtok s_opdata[19] s_sce_lin "," ;KEY 2
strtok s_opdata[20] s_sce_lin "," ;KEY 3
strtok s_opdata[21] s_sce_lin "," ;KEY 4
strtok s_opdata[22] s_sce_lin "," ;KEY 5
strtok s_opdata[23] s_sce_lin "," ;KEY 6
strtok s_opdata[24] s_sce_lin "," ;KEY 7
strtok s_opdata[25] s_sce_lin "," ;KEY 8
strtok s_opdata[26] s_sce_lin "," ;KEY 9
strtok s_opdata[27] s_sce_lin "," ;KEY 10
strtok s_opdata[28] s_sce_lin "," ;KEY 11
strtok s_opdata[29] s_sce_lin "," ;KEY 16 MWK
strtok s_opdata[30] s_sce_lin "," ;KEY 19 CFW
strtok s_opdata[31] s_sce_lin "," ;KEY 22 RNP
strtok s_opdata[32] s_sce_lin "," ;KEY 23 SSU / SCC etc
endproc
proc send_opdata ;##### Sequence of changes and data input
; waitfor "TYPE"
txdc (s_opdata[0])
waitfor "TN "
txdc (s_opdata[1])
waitfor "DES "
txdc (s_opdata[2])
waitfor "CUST "
txdc (s_opdata[3])
waitfor "FDN "
txdc (s_opdata[4])
waitfor "TGAR "
txdc (s_opdata[5])
waitfor "NCOS "
txdc (s_opdata[6])
waitfor "RNPG "
txdc (s_opdata[7])
waitfor "SSU "
txdc (s_opdata[8])
waitfor "SCPW "
txdc (s_opdata[9])
waitfor "CLS "
transmit "TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA " ; #### Applies to all phones! ####
txdc (s_opdata[10])
waitfor "RCO "
txdc (s_opdata[11])
waitfor "EFD "
txdc (s_opdata[12])
waitfor "HUNT "
txdc (s_opdata[13])
waitfor "EHT "
txdc (s_opdata[14])
waitfor "AST "
txdc (s_opdata[15])
waitfor "IAPG "
txdc (s_opdata[16])
waitfor "KEY "
transmit "0 "
txdc (s_opdata[17])
waitfor "KEY "
transmit "1 "
txdc (s_opdata[18])
waitfor "KEY "
transmit "2 "
txdc (s_opdata[19])
waitfor "KEY "
transmit "3 "
txdc (s_opdata[20])
waitfor "KEY "
transmit "4 "
txdc (s_opdata[21])
waitfor "KEY "
transmit "5 "
txdc (s_opdata[22])
waitfor "KEY "
transmit "6 "
txdc (s_opdata[23])
waitfor "KEY "
transmit "7 "
txdc (s_opdata[24])
waitfor "KEY "
transmit "8 "
txdc (s_opdata[25])
waitfor "KEY "
transmit "9 "
txdc (s_opdata[26])
waitfor "KEY "
transmit "10 "
txdc (s_opdata[27])
waitfor "KEY "
transmit "11 "
txdc (s_opdata[28])
waitfor "KEY "
transmit "16 "
txdc (s_opdata[29])
waitfor "KEY "
transmit "19 "
txdc (s_opdata[30])
waitfor "KEY "
transmit "22 "
txdc (s_opdata[31])
waitfor "KEY "
transmit "23 "
txdc (s_opdata[32])
waitfor "KEY "
pause 1
txdc ("")
waitfor "REQ" forever
txdc ("NEW")
; else
; endif
endproc
proc cnt_no_fi_lines ;#####
param integer i_ch
param long l_tot_no_lin
param long l_fi_sz0
while not feof 0
fgetc 0 i_ch
if not feof 0
if i_ch == '`n'
l_tot_no_lin++
endif
endif
endwhile
ftell 0 l_fi_sz0
rewind 0
endproc
;proc txdt ;#####
;param string s_txs
;integer i_p = 0
;integer i_ch = -1
; strgetc s_txs i_P i_ch
; i_p++
; while i_ch != 0
; computc i_ch
; strgetc s_txs i_P i_ch
; i_P++
; endwhile
;endproc
proc txdc ;#####
param string s_txs
integer i_p = 0
integer i_ch = -1
strgetc s_txs i_P i_ch
i_p++
while i_ch != 0
computc i_ch
strgetc s_txs i_P i_ch
i_P++
endwhile
computc 13
endproc
proc ld_ovl_11 ;#####
param integer i_rg2_chc
Capture On
; In this area, enter in new prompts that have appeared when running this script using examples
; listed below. Different features & software versions will result in prompts that have not been
; spotted before.
WHEN TARGET 1 "OVL111 " CALL OVL111
WHEN TARGET 2 "OVL013 " CALL OVL013
WHEN TARGET 3 "CTYP " CALL CARR_RETURN
WHEN TARGET 4 "KEM " CALL CARR_RETURN
WHEN TARGET 5 "NUID " CALL CARR_RETURN
WHEN TARGET 6 "KBA " CALL CARR_RETURN
WHEN TARGET 7 "NHTN " CALL CARR_RETURN
WHEN TARGET 8 "DBA " CALL CARR_RETURN
WHEN TARGET 9 "ERL " CALL CARR_RETURN
WHEN TARGET 10 "ECL " CALL CARR_RETURN
WHEN TARGET 11 "LDN " CALL CARR_RETURN
WHEN TARGET 12 "XLST " CALL CARR_RETURN
WHEN TARGET 13 "SGRP " CALL CARR_RETURN
WHEN TARGET 14 "SFLT " CALL CARR_RETURN
WHEN TARGET 15 "CAC_MFC " CALL CARR_RETURN
WHEN TARGET 18 "LNRS " CALL CARR_RETURN
WHEN TARGET 19 "LHK " CALL CARR_RETURN
WHEN TARGET 20 "SCI " CALL CARR_RETURN
WHEN TARGET 21 "FCAR " CALL CARR_RETURN ; Release 6 prompt
WHEN TARGET 22 "PLEV " CALL PLEV_0
WHEN TARGET 24 "DANI " CALL CARR_RETURN
WHEN TARGET 25 "ITNA " CALL CARR_RETURN
WHEN TARGET 26 "PRI " CALL CARR_RETURN
WHEN TARGET 27 "MLWU_LANG " CALL CARR_RETURN
WHEN TARGET 28 "MLNG " CALL CARR_RETURN
WHEN TARGET 29 "DNDR " CALL CARR_RETURN
WHEN TARGET 30 " MARP ON" CALL MARP_NO
WHEN TARGET 31 " CPND " CALL CARR_RETURN
WHEN TARGET 32 " VMB " CALL CARR_RETURN
WHEN TARGET 40 "TEN " CALL CARR_RETURN
WHEN TARGET 41 "ECHG " CALL EASY_CHANGE
WHEN TARGET 42 "DATE " CALL CARR_RETURN
WHEN TARGET 43 "PAGE " CALL CARR_RETURN
WHEN TARGET 44 "NACT " CALL CARR_RETURN
WHEN TARGET 45 "ZONE " CALL ZONE_1
WHEN TARGET 46 "SCH0127 " CALL SCH0127
WHEN TARGET 47 "SCH0255 " CALL SCH0255
WHEN TARGET 48 "SCH0341 " CALL SCH0341
WHEN TARGET 49 "SCH0361 " CALL SCH0361
WHEN TARGET 50 "SCH0717 " CALL SCH0717
WHEN TARGET 51 "SCH0733 " CALL SCH0733
WHEN TARGET 55 "SCH1447 " CALL SCH1447
WHEN TARGET 56 "SCH1510 " CALL SCH1510
WHEN TARGET 57 "SCH1893 " CALL SCH1893
WHEN TARGET 58 "SCH3127 " CALL SCH3127
WHEN TARGET 59 "SCH3129 " CALL SCH3129
WHEN TARGET 60 "SCH3902 " CALL SCH3902
WHEN TARGET 61 "SCH5814 " CALL SCH5814
WHEN TARGET 62 "SCH6711 " CALL SCH6711
; WHEN TARGET 63 "SCH3127 " CALL SCH3127
; WHEN TARGET 64 "SCH6711 " CALL SCH6711
WHEN TARGET 81 "SCH8888 " CALL SCH8888
WHEN TARGET 82 "SCH8889 " CALL SCH8889
txdc ("****")
waitfor ">"
txdc ("LD 11") ; Start of access into LD 11
waitfor "REQ"
if i_rg2_chc == 3
txdc ("NEW")
else
txdc ("CHG")
endif
waitfor "TYPE"
STATMSG " Start of Progress status bar and new extensions to be provided in LD 11"
endproc
proc ex_ovl_11 ;##### Print out the sets in LD 81
;param string s_customer_item
pause 3
txdc ("")
txdc ("****")
waitfor ">"
txdc ("LD 81")
waitfor "REQ "
txdc ("LST")
waitfor "CUST "
txdc ("0")
; waitfor "DATE "
; txdc ("")
; waitfor "PAGE "
; txdc ("")
waitfor "DES "
txdc ("")
waitfor "FEAT "
txdc ("SETS")
waitfor "FEAT "
txdc ("")
waitfor "REQ "
txdc ("****")
waitfor ">"
Capture off
endproc
PROC DATETIMESTART
param string s_time_start
param string s_date_start
integer i_tmp
strlen s_date_start i_tmp
if i_tmp >5
strlen s_time_start i_tmp
if i_tmp <2
s_time_start = "00:10:00"
endif
endif
strlen s_time_start i_tmp
if i_tmp >5
strlen s_date_start i_tmp
if i_tmp <2
s_date_start = $DATE
endif
endif
Waituntil s_time_start s_date_start
endproc
Proc TTY_LOGIN
pause 3
txdc ("LOGI")
endproc
proc logi ;#####
param string s_userid
WHEN TARGET 0 "OVL014 " CALL OVL014
WHEN TARGET 1 "OVL428 " CALL OVL428
WHEN TARGET 2 "SCH0510 " CALL OVL014
WHEN TARGET 3 "OVL013 " CALL TTY_LOGIN
WHEN TARGET 5 "OVL111 " CALL OVL111
WHEN TARGET 6 "SCH0510 " CALL SCH0101
WHEN TARGET 7 "SCH101 " CALL SCH0101
transmit "LOGI "
; txdc ("LOGI ")
txdc (s_userid)
waitfor "PASS?"
endproc
proc login ;#####
param string s_pwd
txdc (s_pwd)
waitfor ">"
endproc
proc logo ;#####
txdc ("LOGO") ; Add on this line ";" to allow the program to remain logged in!.
F_Time=$TIME
statmsg "LD 11 New Digital Set script file has now been Completed`n`n at %s" F_TIME
usermsg "LD 11 New Digital Set script file is now Complete`n`n at %s" F_TIME
endproc
PROC PLEV_0
txdc ("0")
ENDPROC
PROC ZONE_1 ; ############# Change to Zone required! ############
txdc ("1")
ENDPROC
PROC CARR_RETURN
txdc ("")
ENDPROC
PROC EASY_CHANGE
pause 1
txdc ("NO")
ENDPROC
Proc OVL013
txdc ("****")
ENDPROC
PROC SCH0127
txdc ("****")
waitfor ">"
USERMSG "SCH0127. Script failed, due to the TN already exists on the system!"
exit
ENDPROC
PROC SCH0255
STATMSG "SCH0255. Illegal Hunt DN.!"
ENDPROC
PROC SCH0341
txdc ("TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA CFHA USRA")
pause 1
txdc ("0")
STATMSG "SCH0341. Unable to match input field with stored mnemonics.! attempting to use typical CLS values!"
ENDPROC
PROC SCH0361
STATMSG "SCH0361. Key number is not valid on this set type.!"
ENDPROC
PROC SCH0717
txdc ("****")
waitfor ">"
USERMSG "SCH0717. Script failed, due to a missing ACD DN in LD 23!"
exit
ENDPROC
PROC SCH0733
STATMSG "SCH0733. Unable to match input field with stored mnemonics.!"
ENDPROC
PROC SCH1447
STATMSG "SCH1447. Key 6 should be set as NUL on this 3905 Set. Redefining this key overrides the user's access to Directory.!"
ENDPROC
PROC SCH1510
txdc ("TLD FNA HTA SFA CFTA HBTA LNA CNDA MWA DPUA GPUA CFHA USRA")
STATMSG "SCH1510. Invalid CLS input. Typical CLS settings for configuring this set are used.!"
ENDPROC
PROC SCH1893
txdc ("****")
waitfor ">"
USERMSG "SCH1893. Script failed. Corporate Directory not allowed for this set type!"
exit
ENDPROC
PROC SCH3127
txdc ("****")
waitfor ">"
STATMSG "SCH3127. Invalid AST key type. Only ACD, MCR, MCN, SCR and SCN key are supported.!"
ENDPROC
PROC SCH3129
STATMSG "SCH3129. This DN already has AST assigned and this TN is configured with CLS ICRD!"
ENDPROC
PROC SCH3902
STATMSG "SCH3902. Only one input field allowed.!"
ENDPROC
PROC SCH5814
STATMSG "SCH5814. A set cannot have USR key with USRD Class of Service.!"
ENDPROC
PROC SCH6711
txdc ("*")
STATMSG "SCH6711. No trailing blanks/spaces can be entered after the CLID entry.Enter {CR} after the CLID entry!"
ENDPROC
PROC SCH8888
STATMSG "SCH8888. The Station Control Password can only use digits 0-9. Check if SCPW was needed after script file has finished!."
ENDPROC
PROC SCH8889
waitfor "SCPW "
txdc ("")
pause 1
STATMSG "SCH8889. CEPT default does not match the password length defined in LD 15. Check if SCPW was needed after script file has finished!."
ENDPROC
PROC MARP_NO
txdc ("NO")
ENDPROC
PROC OVL014
STATMSG "Please wait 30 seconds as the TTY is already logged in!"
ENDPROC
PROC OVL111
txdc ("****")
waitfor ">"
USERMSG "Script failed, as the TTY user is NOT logged into the system!"
exit
ENDPROC
PROC OVL428
txdc ("****")
USERMSG "Script failed. The Login name & password combination is invalid. Check the password & login name & try again.! On software versions V04.5x onwards, check if the password uses case SeNSiTivItY!"
exit
ENDPROC
PROC SCH0101
pause 2
transmit "****^M"
waitfor ">"
STATMSG "Please wait 30 seconds as the TTY is already logged in!"
ENDPROC
; The information listed below has been taken from the "vkeys.inc" file.
; I have added in one ";" against each line for use with this file!.
; Should your copy of "vkeys.inc" be missing or damaged, then you can copy this
; section listed below with one of the ";" removed for each line!.
;;Definitions of standard virtual key code values
;;**********************************************************************
;;* VKEYS.INC
;;* Copyright (c) 1999 Symantec Corporation
;;*
;;* Definitions of standard virtual key code values. Use these macro
;;* definitions in your ASPECT script files rather than hard-coded
;;* constants to improve maintainability and readability. For more
;;* information, see the keyval and vkey conventions described in the
;;* Windows ASPECT Script Language reference manual.
;;**********************************************************************
;#ifndef _INC_VKEYS ; if file not already included
;#define _INC_VKEYS ; prevent further inclusion
;;**********************************************************************
;;* Macro definitions of standard virtual key code values
;;**********************************************************************
;#define VK_LBUTTON 0x01 ; Left mouse button
;#define VK_RBUTTON 0x02 ; Right mouse button
;#define VK_CANCEL 0x03 ; Ctrl-Break
;#define VK_MBUTTON 0x04 ; Middle mouse button
;; 0x05-0x07 ; Undefined
;#define VK_BACK 0x08 ; Backspace key
;#define VK_TAB 0x09 ; Tab key
;; 0x0A-0x0B ; Undefined
;#define VK_CLEAR 0x0C ; Clear key or Keypad 5 with Num lock off
;#define VK_RETURN 0x0D ; Enter or Return key
;; 0x0E-0x0F ; Undefined
;#define VK_SHIFT 0x10 ; Shift key
;#define VK_CONTROL 0x11 ; Control or Ctrl key
;#define VK_MENU 0x12 ; Menu or Alt key
;#define VK_PAUSE 0x13 ; Pause key
;#define VK_CAPITAL 0x14 ; Capital or Caps Lock key
;; 0x15-0x19 ; Reserved for Kanji Systems
;; 0x1A ; Undefined
;#define VK_ESCAPE 0x1B ; Esc or Escape key
;; 0x1C-0x1F ; Reserved for Kanji Systems
;#define VK_SPACE 0x20 ; Spacebar
;#define VK_PRIOR 0x21 ; Page Up key
;#define VK_NEXT 0x22 ; Page Down key
;#define VK_END 0x23 ; End key
;#define VK_HOME 0x24 ; Home key
;#define VK_LEFT 0x25 ; Left arrow key
;#define VK_UP 0x26 ; Up Arrow key
;#define VK_RIGHT 0x27 ; Right Arrow key
;#define VK_DOWN 0x28 ; Down Arrow key
;#define VK_SELECT 0x29 ; Select key
;#define VK_PRINT 0x2A ; Keyboard (OEM) specific
;#define VK_EXECUTE 0x2B ; Execute key
;#define VK_SNAPSHOT 0x2C ; Print Screen key
;#define VK_INSERT 0x2D ; Insert key
;#define VK_DELETE 0x2E ; Delete key
;#define VK_HELP 0x2F ; Help key
;#define VK_0 0x30 ; 0 key
;#define VK_1 0x31 ; 1 key
;#define VK_2 0x32 ; 2 key
;#define VK_3 0x33 ; 3 key
;#define VK_4 0x34 ; 4 key
;#define VK_5 0x35 ; 5 key
;#define VK_6 0x36 ; 6 key
;#define VK_7 0x37 ; 7 key
;#define VK_8 0x38 ; 8 key
;#define VK_9 0x39 ; 9 key
;; 0x3A-0x40 ; Undefined
;#define VK_A 0x41 ; A key
;#define VK_B 0x42 ; B key
;#define VK_C 0x43 ; C key
;#define VK_D 0x44 ; D key
;#define VK_E 0x45 ; E key
;#define VK_F 0x46 ; F key
;#define VK_G 0x47 ; G key
;#define VK_H 0x48 ; H key
;#define VK_I 0x49 ; I key
;#define VK_J 0x4A ; J key
;#define VK_K 0x4B ; K key
;#define VK_L 0x4C ; L key
;#define VK_M 0x4D ; M key
;#define VK_N 0x4E ; N key
;#define VK_O 0x4F ; O key
;#define VK_P 0x50 ; P key
;#define VK_Q 0x51 ; Q key
;#define VK_R 0x52 ; R key
;#define VK_S 0x53 ; S key
;#define VK_T 0x54 ; T key
;#define VK_U 0x55 ; U key
;#define VK_V 0x56 ; V key
;#define VK_W 0x57 ; W key
;#define VK_X 0x58 ; X key
;#define VK_Y 0x59 ; Y key
;#define VK_Z 0x5A ; Z key
;#define VK_WINDOWSL 0x5B ; Windows key (left)
;#define VK_WINDOWSR 0x5C ; Windows key (right)
;#define VK_APPLICATION 0x5D ; Application key
;; 0x5E-0x5F ; Undefined
;#define VK_NUMPAD0 0x60 ; Numeric Keypad 0
;#define VK_NUMPAD1 0x61 ; Numeric Keypad 1
;#define VK_NUMPAD2 0x62 ; Numeric Keypad 2
;#define VK_NUMPAD3 0x63 ; Numeric Keypad 3
;#define VK_NUMPAD4 0x64 ; Numeric Keypad 4
;#define VK_NUMPAD5 0x65 ; Numeric Keypad 5
;#define VK_NUMPAD6 0x66 ; Numeric Keypad 6
;#define VK_NUMPAD7 0x67 ; Numeric Keypad 7
;#define VK_NUMPAD8 0x68 ; Numeric Keypad 8
;#define VK_NUMPAD9 0x69 ; Numeric Keypad 9
;#define VK_MULTIPLY 0x6A ; Multiply key
;#define VK_ADD 0x6B ; Add key
;#define VK_SEPARATOR 0x6C ; Separator key
;#define VK_SUBTRACT 0x6D ; Subtract key
;#define VK_DECIMAL 0x6E ; Decimal key
;#define VK_DIVIDE 0x6F ; Divide key
;#define VK_F1 0x70 ; Function key F1
;#define VK_F2 0x71 ; Function key F2
;#define VK_F3 0x72 ; Function key F3
;#define VK_F4 0x73 ; Function key F4
;#define VK_F5 0x74 ; Function key F5
;#define VK_F6 0x75 ; Function key F6
;#define VK_F7 0x76 ; Function key F7
;#define VK_F8 0x77 ; Function key F8
;#define VK_F9 0x78 ; Function key F9
;#define VK_F10 0x79 ; Function key F10
;#define VK_F11 0x7A ; Function key F11
;#define VK_F12 0x7B ; Function key F12
;#define VK_F13 0x7C ; Function key F13
;#define VK_F14 0x7D ; Function key F14
;#define VK_F15 0x7E ; Function key F15
;#define VK_F16 0x7F ; Function key F16
;#define VK_F17 0x80 ; Function key F17
;#define VK_F18 0x81 ; Function key F18
;#define VK_F19 0x82 ; Function key F19
;#define VK_F20 0x83 ; Function key F20
;#define VK_F21 0x84 ; Function key F21
;#define VK_F22 0x85 ; Function key F22
;#define VK_F23 0x86 ; Function key F23
;#define VK_F24 0x87 ; Function key F24
;; 0x88-0x8F ; Unassigned
;#define VK_NUMLOCK 0x90 ; Num Lock key
;#define VK_OEM_SCROLL 0x91 ; Scroll Lock key
;; 0x92-0xB9 ; Unassigned
;; 0xBA-0xC0 ; Keyboard (OEM) specific
;; 0xC1-0xDA ; Unassigned
;; 0xDB-0xE4 ; Keyboard (OEM) specific
;; 0xE5 ; Unassigned
;; 0xE6 ; Keyboard (OEM) specific
;; 0xE7-0xE8 ; Unassigned
;; 0xE9-0xF5 ; Keyboard (OEM) specific
;; 0xF6-0xFE ; Unassigned
;;**********************************************************************
;;* Useful macros for testing and forming key values from keyboard
;;* shift states and virtual key code values.
;;**********************************************************************
;#define KV_SHIFT 0x01 ; Shift key pressed
;#define KV_CTRL 0x02 ; Ctrl key pressed
;#define KV_ALT 0x04 ; Alt key pressed
;#define KV_EXT 0x08 ; Extended key flag
;#define KV_CAPSLOCK 0x10 ; Caps Lock key toggled on
;#define MAKE_KV(skeys,vkey) (((skeys) << 8) | (vkey))
;#define KV_VKEY(keyval) ((keyval) & 0xFF)
;#define KV_SKEYS(keyval) ((keyval) >> 8)
;#define KV_SHIFTKEY(keyval) (KV_SKEYS(keyval) & KV_SHIFT)
;#define KV_CTRLKEY(keyval) (KV_SKEYS(keyval) & KV_CTRL)
;#define KV_ALTKEY(keyval) (KV_SKEYS(keyval) & KV_ALT)
;#define KV_EXTKEY(keyval) (KV_SKEYS(keyval) & KV_EXT)
;#endif ; _INC_VKEYS
All the best
Firebird Scrambler
Meridian Programmer in the UK
If it's working, then leave it alone!.
Firebird Scrambler
Systems Engineer
Lol John. Many thanks for the reply. I've just used this script to input in 57 new 1120 phones onto a new release 6 CS1000e system. The funny thing was that I entered in the wrong set type of 1120, so had to out them quickly using a new source file taken from LD 83.
I was quickly able via notepad to alter the original source file to change 1120 to 1220 and put them back in again.
This was all done via remote access without any problems.
Best of luck
David
All the best
Firebird Scrambler
Meridian Programmer in the UK
If it's working, then leave it alone!.
I was quickly able via notepad to alter the original source file to change 1120 to 1220 and put them back in again.
This was all done via remote access without any problems.
Best of luck
David
All the best
Firebird Scrambler
Meridian Programmer in the UK
If it's working, then leave it alone!.
here's a script that requires
very little detail..
i used this one to add acd sets
from a wud file..
john poole
bellsouth business
columbia,sc
very little detail..
i used this one to add acd sets
from a wud file..
Code:
proc main
string tn
string des
string key0
string key1
string key2
string key3
string key4
string key5
string key6
string key8
string key9
string key10
string key11
string key12
string key13
string key14
string key15
integer count
string szline
fopen 0 "acdsets.wud" read
while not feof 0
SZLINE = "1"
fgets 0 szline
strtok tn szline "," 1
strtok des szline "," 1
strtok key0 szline "," 1
strtok key1 szline "," 1
strtok key2 szline "," 1
strtok key3 szline "," 1
strtok key4 szline "," 1
strtok key5 szline "," 1
strtok key6 szline "," 1
strtok key8 szline "," 1
strtok key9 szline "," 1
strtok key10 szline "," 1
strtok key11 szline "," 1
strtok key12 szline "," 1
strtok key13 szline "," 1
strtok key14 szline "," 1
strtok key15 szline "," 1
transmit "new^M"
waitfor "TYPE: "
transmit "2616^M"
; waitfor "TN "
transmit tn
mspause 1
transmit "^M"
waitfor "DES "
transmit des
mspause 1
transmit "^M"
waitfor "CUST "
transmit "0^M"
waitfor "AOM "
transmit "^M"
waitfor "ERL "
transmit "^M"
waitfor "FDN "
transmit "^M"
waitfor "TGAR "
transmit "6^M"
waitfor "LDN "
transmit "^M"
waitfor "NCOS "
transmit "1^M"
waitfor "RNPG "
transmit "^M"
waitfor "SSU "
transmit "^M"
waitfor "SCPW "
transmit "^M"
waitfor "SGRP "
transmit "^M"
waitfor "CLS "
transmit "agn ddga ira lna cnda cdca cnia dnda hfd cdma tdd mwa lmpx smwa mwa rmma^M"
waitfor "RCO "
transmit "^M"
waitfor "HUNT "
transmit "^M"
waitfor "LNRS "
transmit "^M"
waitfor "SCI "
transmit "^M"
waitfor "LPK "
transmit "1^M"
waitfor "PLEV "
transmit "^M"
waitfor "FCAR "
transmit "^M"
waitfor "DANI "
transmit "^M"
waitfor "SPID "
transmit "^M"
waitfor "AST "
transmit "^M"
waitfor "IAPG "
transmit "^M"
waitfor "PRI "
transmit "^M"
waitfor "MLWU_LANG "
transmit "^M"
waitfor "DNDR "
transmit "^M"
waitfor "key"
transmit "0 "
mspause 2
transmit key0
mspause 1
transmit "^M"
waitfor "key"
transmit "1 "
mspause 2
transmit key1
mspause 1
transmit "^M"
waitfor " CPND "
transmit "^M"
mspause 1
transmit "^M"
waitfor "key"
transmit "2 "
mspause 2
transmit key2
mspause 1
transmit "^M"
waitfor "key"
transmit "3 "
mspause 2
transmit key3
mspause 1
transmit "^M"
waitfor "key"
transmit "4 "
mspause 2
transmit key4
mspause 1
transmit "^M"
waitfor "key"
transmit "5 "
mspause 1
transmit key5
mspause 1
transmit "^M"
waitfor "key"
transmit "6 "
mspause 2
transmit key6
mspause 1
transmit "^M"
waitfor "key"
transmit "8 "
mspause 2
transmit key8
mspause 1
transmit "^M"
waitfor "key"
transmit "9 "
mspause 1
transmit key9
mspause 1
transmit "^M"
waitfor "key"
transmit "10 "
mspause 2
transmit key10
mspause 1
transmit "^M"
waitfor "key"
transmit "11 "
mspause 2
transmit key11
mspause 1
transmit "^M"
waitfor "key"
transmit "12 "
mspause 2
transmit key12
mspause 1
transmit "^M"
waitfor "key"
transmit "13 "
mspause 2
transmit key13
mspause 1
transmit "^M"
waitfor "key"
transmit "14 "
mspause 1
transmit key14
mspause 1
transmit "^M"
waitfor "key"
transmit "^M"
waitfor "REQ: "
count += 2
endwhile
fclose 0
fclose 1
call main
endprocjohn poole
bellsouth business
columbia,sc
- Status
Similar threads
