Script: Mass Defragger 1

[hgate73]

I'm posting a few scripts I use as a system administrator in Kuwait. These are to perform mundane tasks on a /lot/ of computers at once. Every one of my scripts reads through a "names.txt" file with a FOR loop and executes that command for each PC. Without further ado!

:: Purpose:         Defrags all computers listed in the names file
:: Requirements:    1. Run this script with network admin privileges
::                  2. psexec.exe from Microsoft must be in any of these locations:
::                      a) the directory you run this script from
::                      b) in the PATH variable
::                      c) c:\windows\system32\    (preferred)
::                  3. Put the names of your computers, one per line, in a file called "names.txt" in the same directory as this script
::
:: Version:         1.1 Improved script by adding functionality to read a list of computer names from a text file
::                      instead of hard-coded in the script. Uses a FOR loop to iterate through the file.
:: History:         1.0 Initial write

:: Prep
@echo off
title Mass Defragger
set VERSION=1.1
set NAMES_FILE=names.txt
set TIMEOUT=5
cls

:: User notice
color 0c
echo.
echo  *********************************************************
echo  *                                                       *
echo  *                   MASS DEFRAGMENTER                   *
echo  * ----------------------------------------------------- *
echo  *                                                       *
echo  * RULES for a safe and happy mass defragging:           *
echo  *                                                       *
echo  * 1. Run this script with NETWORK ADMIN rights.         *
echo  * 2. Edit this script BEFORE RUNNING IT to put in your  *
echo  *    own system names.                                  *
echo  * 3. Run this script from the desktop, NOT a network    *
echo  *    path.                                              *
echo  * 4. "psexec.exe" from Microsoft must be in either:     *
echo  *     a. the same directory as this script              *
echo  *     b. C:\WINDOWS\system32\                           *
echo  *     c: the system PATH variable                       *
echo  * 5. A file named "names.txt" must be in             *
echo  *     the same directory of this script. List the names *
echo  *     of the computers you want defragged, one name per *
echo  *     line.                                             *
echo  *                                                       *
echo  *********************************************************
echo.
echo.
pause
color 07
cls

:: HIROSHIMA!
title Mass Defragging -- Timeout %TIMEOUT% seconds
cls
echo.
echo Performing mass defragmentation, with a %TIMEOUT% second connection timeout.
echo Please wait...
echo.

FOR /F %%i in (%NAMES_FILE%) do psexec -a 0 -belownormal -n %TIMEOUT% -d \\%%i defrag c: -f

title Mass Defragger --  Complete
echo.
echo Mass Defragger -- Complete
echo.
pause
title %USERNAME%

I was previously posting under "GeneralDzur" but hgate73 is my new username.

 

[kjv1611]

Can this only be run on a domain, or will it also work on a Workgroup?

 

[hgate73]

It would work in a workgroup too, you'd just need to put the names of your computers (one per line) in the "names" file that's specified at the beginning of the script.

Note that whatever account you run it from has to have administrator rights on /every/ machine it connects to for it to work.

I was previously posting under "GeneralDzur" but hgate73 is my new username.

 

[kjv1611]

Hmm, here's another question. If you have a machine listed in the file, but that machine is powered off, does it cause an error in the script, or does it just skip it?

Also, if the machine is "asleep", will this script wake it up?

 

[hgate73]

No, the script will just time out after a set time (I think I set the timeout to 5 seconds) and move on to the next machine.

You will need Psexec.exe from Microsoft though.

I was previously posting under "GeneralDzur" but hgate73 is my new username.

 

[kjv1611]

Thanks for the info. I'll definitely have to give some if not all these scripts a test run.

 

[hgate73]

Please do, and let me know how they work out for you. It's always good to learn about errors that I didn't know where there

I was previously posting under "GeneralDzur" but hgate73 is my new username.