retaining access optrions in deployed database installation 2

[kimmole]

hi all... i'm having trouble and i'm not totaly sure this is the right forum... but i need help.
i'm deploying an access database via an instalation from cd.
i won't be around when it's installed and i know from past experience that when the install finishes and the program is launched that the preferences i set in the "tools\ options" menu will not be kept, but instead replaced by the users machine settings. in most cases someone needs to manually reconfigure these settings, (not a big job, but hey you know clients.....)in windows nt/98 the registry keys point to a master mdb which i can easily alter from within my installation routine, however i can find no such master file on win xp machines.

how do i force the users version of access to use my defaults?

thanks in advance

 

[payback]

In all my applications, I set these at startup by including in the Autoexec macro the following function.

It sets both Tools/Options and StartUp configuration however you will have to start the application twice to see the effects because Startup settings are not immediately visible the first time.

The Process_Message_Form_Name refers to a dialog form with a text box that I can use throughout my applications for any messages (like a status of processing message).

Private Const Application_Title As String = "YOUR APP NAME"

Global Const Open_Form_Name As String = "frmOpenForm"
Global Const Process_Message_Form_Name = "frmProcessMessage"

Function SetDatabaseOptions()
On Error GoTo Errorhandler

DoCmd.OpenForm Process_Message_Form_Name
Forms(Process_Message_Form_Name)![Description] = "Setting Database Options..."
Forms(Process_Message_Form_Name).Repaint

SetOption "Show Status Bar", True
SetOption "Show Startup Dialog Box", False
SetOption "Show New Object Shortcuts", False
SetOption "Show Hidden Objects", False
SetOption "Show System Objects", False
SetOption "ShowWindowsInTaskBar", False

SetOption "Track Name AutoCorrect Info", False
SetOption "Default Database Directory", "C:\"

SetOption "Confirm Record Changes", True
SetOption "Confirm Document Deletions", True
SetOption "Confirm Action Queries", True

SetOption "Move After Enter", 1
SetOption "Behavior Entering Field", 0
SetOption "Arrow Key Behavior", 1
SetOption "Cursor Stops at First/Last Field", False

SetOption "Default Open Mode for Databases", 0
SetOption "Default Record Locking", 2
SetOption "Run Permissions", 1

SetOption "Underline Hyperlinks", True

CurrentProject.Properties.Add "AppTitle", Application_Title
Application.RefreshTitleBar
CurrentProject.Properties.Add "StartUpForm", Open_Form_Name
CurrentProject.Properties.Add "StartupShowDBWindow", False
CurrentProject.Properties.Add "StartupShowStatusBar", True
CurrentProject.Properties.Add "AllowBuiltinToolbars", True
CurrentProject.Properties.Add "AllowFullMenus", True
CurrentProject.Properties.Add "AllowSpecialKeys", True

CurrentProject.Properties.Add "AppIcon", Application.CurrentProject.Path & "MY SPECIAL ICON"
CurrentProject.Properties.Add "UseAppIconForFrmRpt", True

DoCmd.ShowToolbar "Web", acToolbarNo
DoCmd.ShowToolbar "Menu Bar", acToolbarNo
DoCmd.ShowToolbar "Form View", acToolbarNo
DoCmd.ShowToolbar "Database", acToolbarNo

If IsFormLoaded(Process_Message_Form_Name) Then
DoCmd.Close acForm, Process_Message_Form_Name
End If

Exit Function

Errorhandler:
Call Error_Display_Vars(Err, Application.CurrentObjectName)

End Function


This has been cut out of an existing application (Access XP ADP) therefore some of the specific options might not work immediately for you but it should give you some ideas. The options in MDB's, and Access 2000 and 97 are not exectly the same but the principles are similar.