Resizing a Form

[tmcain]

I need to ensure that when a user resizes my form all the controls are still visible and in proportion.
Is there an easy way to do this?
If you can post examples, I would appreciate it.
Thanks

 

[Jesuspower]

on Form_resize
control.hieght= change hieght relative to form.
control.witdh=
control.top
control.left

hope this helps. sorry for spelling. -God Bless

 

[JustinEzequiel]

haven't tested on all controls and on controls containing other controls (i.e., Frames)

best i could come up with quickly

Option Explicit

Private Enum MVArgs
  MVLEFT
  MVTOP
  MVWIDTH
  MVHEIGHT
End Enum

Private Sub Form_Load()
  Dim oCtrl As Control
  
  ScaleHeight = 100
  ScaleWidth = 100
  
  For Each oCtrl In Controls
    With oCtrl
      .Tag = .Left & ", " & .Top & ", " & .Width & ", " & .Height
    End With
  Next oCtrl
End Sub

Private Sub Form_Resize()
  Dim oCtrl As Control
  Dim sVals() As String
  Dim nSW As Long
  Dim nSH As Long
  
  nSW = ScaleWidth
  nSH = ScaleHeight
  
  If WindowState = vbMinimized Then Exit Sub
  
  For Each oCtrl In Controls
    sVals = Split(oCtrl.Tag, ", ")
    oCtrl.Move Val(sVals(MVLEFT)) * nSW / 100, _
               Val(sVals(MVTOP)) * nSH / 100, _
               Val(sVals(MVWIDTH)) * nSW / 100, _
               Val(sVals(MVHEIGHT)) * nSH / 100
  Next oCtrl
End Sub

 

[Jesuspower]

Put it in Form_Resize -God Bless

 

[tmcain]

Thanks, I'll try this approach.

 

[JustinEzequiel]

Option Explicit

' does not work for Image, Line, and Shape controls

Private mnHeight As Long
Private mnWidth As Long

Private Enum MVArgs
MVLEFT
MVTOP
MVWIDTH
MVHEIGHT
MVFONTSIZE
End Enum

Private Sub Form_Load()
Dim oCtrl As Control

On Error Resume Next

mnHeight = Height
mnWidth = Width

ScaleHeight = 100
ScaleWidth = 100

For Each oCtrl In Controls
With oCtrl
.Tag = .Left & ", " & .Top & ", " & .Width & ", " & .Height & ", " & .FontSize
End With
Next oCtrl

On Error GoTo 0
End Sub

Private Sub Form_Resize()
Dim oCtrl As Control
Dim sVals() As String
Dim nSW As Long
Dim nSH As Long

On Error Resume Next

nSW = ScaleWidth
nSH = ScaleHeight

If WindowState = vbMinimized Then Exit Sub

For Each oCtrl In Controls
With oCtrl
sVals = Split(oCtrl.Tag, ", &quot
Select Case TypeName(oCtrl)
Case "DriveListBox", "ComboBox"
.Left = Val(sVals(MVLEFT)) * nSW / 100
.Top = Val(sVals(MVTOP)) * nSH / 100
.Width = Val(sVals(MVWIDTH)) * nSW / 100
.Height = Val(sVals(MVHEIGHT)) * nSH / 100
Case Else
.Move Val(sVals(MVLEFT)) * nSW / 100, _
Val(sVals(MVTOP)) * nSH / 100, _
Val(sVals(MVWIDTH)) * nSW / 100, _
Val(sVals(MVHEIGHT)) * nSH / 100
End Select
.FontSize = Val(sVals(MVFONTSIZE)) * nSH / 100
End With
Next oCtrl

On Error GoTo 0
End Sub

Private Sub mnuRestore_Click()
WindowState = vbNormal
Height = mnHeight
Width = mnWidth
End Sub