remove specific field without changing field seperator

[arunrr]

Input string ($INPUT) can be...

3,J Smith,Manager,121,207,197,16,0,61.42

or

3,J Smith,Manager,121,197,16,0,61.42

In the first case NF=9; In the second case NF=8.
I need to remove the 5th field if NF=9 and do nothing if NF=8.

I tried the following...

echo $INPUT | awk -F, '{if (NF==9) $5=""}1'

This does remove the field, but changes the field separator to a space from a ",". I need to keep the "," FS. Please help.

thanks,
AR

 

[AnotherAlan]

How about this;

Tested with nawk because I use Solaris;

nawk -F, 'BEGIN{OFS=","}{if (NF==9) $5=""}1' $INPUT > outfile

I'm no expert though, so I'm sure one of the bigger brains may have a cut down version for you.

Hope this helps.
Alan

 

[feherke]

Hi

[tt]$5=""[/tt] only replaces the value of the 5^th field, but it remains there. AR's code seemed to work just because the less evident separators, but Alan's code should display clearly the 5^th field with its new empty value. ( I mean, two consecutive separators after the 4^th field. )

The way I know, has two steps :
[ul]
[li]shift all fields after the 5^th to left with 1[/li]
[li]decrement the field count[/li]
[/ul]
Note that modifying the field count like this is not supported by some [tt]awk[/tt] implementations :

awk -F, -vOFS=',' 'NF==9{for(i=5;i<NF;i++)$i=$(i+1);NF--}1' /input/file

Or another, less elegant but more portable, also in two steps :
[ul]
[li]replace the 5^th field with a ( hopefully unique ) placeholder[/li]
[li]replace the placeholder and the following field separator with nothing[/li]
[/ul]

awk -F, -vOFS=',' 'NF==9{$5="REMOVEME";sub(/REMOVEME,/,"")}1' /input/file

Tested with [tt]gawk[/tt] and [tt]mawk[/tt].

Feherke.

http://free.rootshell.be/~feherke/

 

[arunrr]

Feherke,
Thanks a lot!
AR