[Regular Expressions] Limit The Search 2

[Dalie]

I use the following script to find folders with a specific name on my PC. However this script searches the whole computer every time. I am quite new to regular expressions. I'd like to modify the script in a way it limits the search to a folder, lets say: c:\temp

I understand the code except the bold lines, maybe someone could explain these lines in plain language... and point me in the direction for finding the solution.

Set objRegEx = CreateObject("VBScript.RegExp")

objRegEx.Global = True   
objRegEx.IgnoreCase = True
objRegEx.Pattern = "ABCD"
[b]
strComputer = "." 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colFolders = objWMIService.ExecQuery("Select * From Win32_Directory")
[/b]
For Each objFolder in colFolders
    strFolder = objFolder.FileName
    Set colMatches = objRegEx.Execute(strFolder)

    If colMatches.Count > 0 Then
        Wscript.Echo objFolder.Name 
    End If
Next

 

[strongm]

Select * from Win32_Directory where name = 'c:\\temp'

 

[Dalie]

Thanks but as soon as I enter your line of code the script doesn't show any results... (I created the folder c:\temp with several folders which contains names abcd). Without the line it does show these folders I created...

 

[HarleyQuinn]

strongm, I always thought that the syntax you provided would just return the C:\Temp folder?

Dalie - How about something like:

Set colFolders = objWMIService.ExecQuery("Select * From Win32_Directory where path = '\\temp\\' and drive = 'C:'")

Hope this helps

HarleyQuinn
---------------------------------
The most overlooked advantage to owning a computer is that if they foul up there's no law against wacking them around a little. - Joe Martin

Get the most out of Tek-Tips, read FAQ222-2244 before posting.

 

[tsuji]

To search subdirectory starting from a base directory, use associator query on win32_subdirectory. This is a hand-held article.

http://www.microsoft.com/technet/scriptcenter/resources/qanda/feb05/hey0218.mspx

It is a recursive search with superior efficiency.

For a specific subdirectory in mind, stop the recursion once it is found, and return with the find.

 

[Dalie]

Thanks HarleyQuinn that totally fixed the problem!

 

[HarleyQuinn]

Glad I could help

HarleyQuinn
---------------------------------
The most overlooked advantage to owning a computer is that if they foul up there's no law against wacking them around a little. - Joe Martin

Get the most out of Tek-Tips, read FAQ222-2244 before posting.

 

[strongm]

I was foolishly addressing

> to find folders with a specific name

rather than

>search to a folder, lets say: c:\temp

Given that I now understand we want to search a specific folder for (sub)folders that match a specific pattern, I'd extend the query further to eliminate necessity to do a pattern match in the later loop (which also means we can get rid of all the RegExp stuff):

[blue]Set colFolders = objWMIService.ExecQuery("Select * From Win32_Directory where path = '\\temp\\' and drive = 'C:' and name LIKE '%ABCD%'")[/blue]

which means that the loop can become something like:

[blue]For Each objFolder In colFolders
        Wscript.Echo objFolder.Name
Next[/blue]

In fact the entire code could be replaced with (if we were feeling a little obtuse):

[blue]strComputer = "."
For Each objFolder In GetObject("winmgmts:\\" & strComputer & "\root\cimv2").ExecQuery("Select * From Win32_Directory where path = '\\temp\\' and drive = 'C:' and name LIKE '%ABCD%'")
        Wscript.echo objFolder.Name
Next[/blue]

 

[HarleyQuinn]

which also means we can get rid of all the RegExp stuff

I never thought I'd see you say that

Though in this case, I agree that's a viable option.

I've often been concerned about using LIKE in the ExecQuery as sometimes it can be a nightmare if you've not further limited search area in the querystring (obviously in your example that's not a problem though ).

HarleyQuinn
---------------------------------
The most overlooked advantage to owning a computer is that if they foul up there's no law against wacking them around a little. - Joe Martin

Get the most out of Tek-Tips, read FAQ222-2244 before posting.

 

[strongm]

>I never thought I'd see you say that

Yeah, I wondered whether I'd get picked up on that ...